*DECK     CSESCT
USETEXT TEXTCS
USETEXT TEXTSS
USETEXT TXTSMCS 
USETEXT TXTAPSS 
      PROC CSESCT;
# TITLE - SEND COMMAND TEXT                                            #
      BEGIN 
# 
**    CSESCT - SEND COMMAND TEXT. 
* 
*     D.K. ENDO    82/03/15 
* 
*     THIS PROCEDURE FORMATS THE INCOMING COMMAND TEXT INTO A HOP/LG SM 
*     AND SENDS IT OUT TO THE OUTGOING TRAFFIC QUEUE. 
* 
*     PROC CSESCT 
* 
*     ENTRY        1. COMMAND TEXT ENTRY FROM EVENT QUEUE 
* 
*     EXIT         2. HOP/LG ENTRY IN OUTGOING TRAFFIC QUEUE
* 
# 
# 
****  PROC CSESCT - XREF LIST BEGINS. 
# 
      XREF
        BEGIN 
        PROC MOVEI;          # MOVES A BLOCK OF CM WORDS               #
        PROC SSTAQE;         # ADD QUEUE ENTRY                         #
        END 
# 
****
# 
      ITEM I;                # LOOP INDUCTION VARIABLE                 #
      CONTROL EJECT;
#                                                                      #
#                            CSESCT CODE BEGINS HERE                   #
#                                                                      #
# 
*     FORMAT THE WORD COUNT BUFFER AND APPLICATION BLOCK HEADER FOR A 
*     HOP/LG SM.  MOVE THE COMMAND TEXT TO THE HOP/LG SM. SENT THE SM 
*     TO THE OUTGOING TRAFFIC QUEUE.
# 
  
  
      WCB$WORD[1] = 0;
      WCB$SMID[1] = SMID"HOPLG";
      WCB$WC[1] = WCB$WC[0] + 2;  # ALLOW FOR ZERO-BYTE TERMINATOR     #
  
  
      ABHWORD[1] = 0; 
      ABHABT[1] = APPCMD; 
      ABHACT[1] = CT60TRANS;
      ABHTLC[1] = WCB$WC[1] - 2;
  
  
      SPMWD[1] = 0; 
      PFCSFC[1] = HOPLG;
      MOVEI(WCB$WC[0]-1,LOC(SPMSG0[0]),LOC(SPMSG1[1])); 
      SPMSG2[1] = CTM$CLOCK[0]; 
  
  
      SSTAQE(P<OTQ>,WCBUF[1],ABH[1],CSSM[1]); 
      OTQ$WORD[OTQL-1] = 0;  # INSURE ZERO-BYTE TERMINATOR WORD        #
  
  
      RETURN;                # **** RETURN ****                        #
      END # CSESCT #
      TERM