*DECK     CSSDPE
USETEXT TEXTCS
USETEXT TEXTSS
USETEXT TXTAPSS 
USETEXT TXTSMCS 
      PROC CSSDPE;
# TITLE CSSDPE - DISPATCH PROTOCOL EVENT QUEUE ENTRIES.                #
      BEGIN # CSSDPE #
# 
**    CSSDPE - DISPATCH PROTOCOL EVENT QUEUE ENTRIES. 
* 
*     D.K. ENDO    82/03/08 
* 
*     THIS PROCEDURE ROUTES ENTRIES IN THE PROTOCOL EVENT QUEUE TO THE
*     APPROPRIATE PROC IN ORDER TO TAKE ACTION ON EACH ONE. 
* 
*     PROC CSSDPE 
* 
*     ENTRY   1. THE PROTOCOL QUEUE CONTAINS ONE OR MORE ENTRIES
* 
*     EXIT    1. THE PROTOCOL EVENT QUEUE IS EMPTY. 
*             2. ENTRIES MADE IN THE APPROPRIATE QUEUES.
* 
# 
# 
****  PROC CSSDPE - XREF LIST.
# 
      XREF
        BEGIN 
        PROC CSSANO;         # AQUIRE NEW OPERATOR                     #
        PROC CSSICT;         # INITIATE CS TERMINATION                 #
        PROC CSSTNO;         # TERMINATE AN OPERATOR                   #
        PROC CSSUPL;         # UPDATE PAGE LENGTH                      #
        PROC SSTRQE;         # REMOVE QUEUE ENTRY                      #
        END 
# 
****
# 
      ITEM I;                # LOOP INDUCTION VARIABLE                 #
      CONTROL EJECT;
#                                                                      #
#                            CSSDPE CODE BEGINS HERE                   #
#                                                                      #
      FOR I=0 WHILE PEQL NQ 0 
      DO
        BEGIN 
# 
*     REMOVE EACH ENTRY IN THE PROTOCOL EVENT QUEUE AND CALL THE
*     APPROPRIATE PROCEDURE TO PROCESS THE ENTRY. 
# 
        SSTRQE(P<PEQ>,WCBUF[0],ABH[0],CSSM[0]); 
  
        IF WCB$SMID[0] EQ SMID"HOPSTRT" OR
           WCB$SMID[0] EQ SMID"CONREQ"
        THEN
          BEGIN 
          CSSANO; 
          END 
        ELSE IF WCB$SMID[0] EQ SMID"TCHTCH" 
        THEN
          BEGIN 
          CSSUPL; 
          END 
        ELSE IF WCB$SMID[0] EQ SMID"CONCB" OR 
                WCB$SMID[0] EQ SMID"FCINA" OR 
                WCB$SMID[0] EQ SMID"CONCBW" 
        THEN
          BEGIN 
          CSSTNO; 
          END 
        ELSE IF WCB$SMID[0] EQ SMID"SHUINS" 
        THEN
          BEGIN 
          CSSICT; 
          END 
        END 
  
      RETURN;                # **** RETURN ****                        #
  
      END #CSSDPE # 
      TERM