*DECK HCONEND 
USETEXT AHEADER 
USETEXT AT
USETEXT NIPDEF
USETEXT PARAMS
USETEXT PT
USETEXT SUPMSG
PRGM HCONEND; 
STARTIMS; 
 #
*1DC  HCONEND 
*     1. PROC NAME           AUTHOR              DATE 
*        HCONEND             C. BITTNER          81/12/01 
* 
*     2. FUNCTIONAL DESCRIPTION 
*        FORMAT AND SEND CON/END/N TO APPLICATION 
* 
*     3. METHOD 
*        USE BUFFER FOR CON/END/R 
*        SET UP APPLICATION BLOCK HEADER
*        SET UP CON/END/N TEXT
*        QUEUE MESSAGE ON APPLICATION-S ACB 
* 
*     4. ENTRY PARAMETERS 
*        PARAMS1 - SM BUFFER ADDRESS (CON/END/R)
*        PARAMS2 - APPLICATION NUMBER OF APPL ENDING CONNECTION 
* 
*     5. EXIT PARAMETERS
*        NONE 
* 
*     6. COMDECKS CALLED AND SYMPL TEXTS USED 
*        AHEADER
*        AT 
*        NIPDEF 
*        PARAMS 
*        PT 
*        SUPMSG 
*        OSSIZE 
* 
*     7. ROUTINES AND OVERLAYS CALLED 
*        BLINK - QUEUE MESSAGE ON APPL-S ACB
*        OSCHAPP - SCHEDULE APPLICATION 
*        XTRACE - RECORD PROCEDURE CALL 
* 
*     8. DAYFILE MESSAGES AND OTHER IMPORTANT INFORMATION 
*        THIS IS A SECONDARY OVERLAY CALLED BY HCSTTP.
*        W A R N I N G - THIS PROGRAM CANNOT EXCEED THE SECONDARY 
*CALL OSSIZE
* 
 #
STOPIMS;
  
  
# 
      EXTERNAL VARIABLES
# 
 XREF 
   BEGIN
   PROC BLINK;               # QUEUE MSG ON APPL-S ACB                 #
   PROC OSCHAPP;             # SCHEDULE APPLICATION                    #
   PROC XTRACE;              # RECORD PROCEDURE CALL                   #
   LABEL RJMAIN;             # RETURN ADDRESS IN OVLCALL               #
   END
  
# 
      INTERNAL VARIABLES
# 
      ITEM AN;               # APPLICATION NUMBER                      #
      ITEM BUFADDR;          # SM BUFFER                               #
  
#**********************************************************************#
  
      BEGIN 
  
      CONTROL IFEQ DEBUG,1; 
        XTRACE("HCONE") ; 
      CONTROL FI; 
  
#  SET UP APPLICATION HEADER                                           #
  
      BUFADDR = PARAMS1;  # ADDRESS OF SM BUFFER                       #
      P<AHEADER> = BUFADDR + BLKHSIZE;  # ADDR OF ABH                  #
      ABHTLC[0] = LCONENN;  # TEXT LENGTH                              #
  
#  SET UP CON/END/N MESSAGE  #
  
      P<SUPMSG> = BUFADDR + BLKHSIZE + ABHSIZE;  # BASE SM             #
      RB[0] = TRUE;          # SET NORMAL RESPONSE BIT                 #
      CONLCF[0] = PARAMS5 ; 
      CONNFF[0] = PARAMS8 ; 
  
#  QUEUE CON/END/N ON APPL-S ACB                                       #
  
      AN = PARAMS2;          # APPLICATION NUMBER OF APPL ENDING CONN  #
      BLINK(BUFADDR,ATACBA[AN]);  # QUEUE MSG ON APPL-S ACB            #
      OSCHAPP(ATACBA[AN]);  # SCHEDULE APPLICATION                     #
      GOTO RJMAIN;           # RETURN TO CALLING PROGRAM               #
      END 
TERM