*DECK HCRACCU 
USETEXT ACNB
USETEXT AHEADER 
USETEXT AT
USETEXT NIPDEF
USETEXT PARAMS
USETEXT PT
USETEXT SUPMSG
PROC HCRACCU; 
STARTIMS; 
 #
*1DC  HCRACCU 
*     1. PROC NAME           AUTHOR              DATE 
*        HCRACCU             C. BITTNER          81/12/01 
* 
*     2. FUNCTIONAL DESCRIPTION 
*        FORMAT AND SEND CONNECTION ACCEPTED MESSAGE (CR/ACC/U) 
*        TO NVF 
* 
*     3. METHOD 
*        ALLOCATE A BUFFER FOR MESSAGE
*        SET UP APPLICATION BLOCK HEADER
*        FORMAT CR/ACC/U TEXT 
*        QUEUE MESSAGE ON NVF-S ACB 
* 
*     4. ENTRY PARAMETERS 
*        PARAMS1 - ACNB ADDR OF APPL WHICH ACCEPTED CONNECTION
* 
*     5. EXIT PARAMETERS
*        NONE 
* 
*     6. COMDECKS CALLED AND SYMPL TEXTS USED 
*        ACNB 
*        AHEADER
*        AT 
*        NIPDEF 
*        PARAMS 
*        PT 
*        SUPMSG 
* 
*     7. ROUTINES AND OVERLAYS CALLED 
*        BLINK - QUEUE MESSAGE ON APPL-S ACB
*        MGETS - ALLOCATE EMPTY BUFFER
*        OSHCAPP - SCHEDULE APPLICATION 
*        XTRACE - RECORD PROCEDURE CALL 
* 
*     8. DAYFILE MESSAGES AND OTHER IMPORTANT INFORMATION 
*        THIS PROCEDURE IS CALLED BY SECONDARY OVERLAY
*        SENDACC VIA HCSTTP.
* 
 #
STOPIMS;
  
# 
      EXTERNAL VARIABLES
# 
 XREF 
   BEGIN
   PROC BLINK;               # QUEUE SM ON APP-S ACB                   #
   PROC MGETS;               # ALLOCATE EMPTY BUFFER                   #
   PROC OSCHAPP;             # SCHEDULE APPLICATION                    #
   PROC XTRACE;              # RECORD PROCEDURE CALL                   #
   END
  
# 
      INTERNAL VARIABLES
# 
      ITEM BUFADDR;          # SM BUFFER ADDRESS                       #
  
  
#**********************************************************************#
  
      BEGIN 
  
      CONTROL IFEQ DEBUG,1; 
        XTRACE("HCRAC") ; 
      CONTROL FI; 
  
#  GET BUFFER TO HOLD CR/ACC/U MESSAGE                                 #
  
      MGETS(LCRACC + BLKHSIZE + ABHSIZE,BUFADDR,TRUE);
  
#  SET UP APPLICATION BLOCK HEADER                                     #
  
      P<AHEADER> = BUFADDR + BLKHSIZE;  # ADDR TO HOLD ABH             #
      ABHABT[0] = APPCMD;  # BLOCK TYPE                                #
      ABHACT[0] = CT60TRANS;  # CHARACTER TYPE                         #
      ABHTLC[0] = LCRACC;  # TEXT LENGTH                               #
  
#  SET UP CR/ACC/U TEXT      #
  
      P<SUPMSG> = BUFADDR + BLKHSIZE + ABHSIZE;  # BASE SM             #
      P<SMNVF> = P<SUPMSG>;  # BASE CR/ACC/U                           #
      PFCSFC[0] = CRACC;     # SET FUNCTION CODE                       #
      P<ACNB> = PARAMS1;  # BASE APPLICATION CONNECTION BLOCK          #
      CRAACN[0] = ACNBACN[0];  # APPLICATION CONNECTION NUMBER         #
      CRDT[0] = ACNBDT[0];   # DEVICE TYPE                             #
      CRVCB[0] = ACNBVCBO[0];  # VCB ORDINAL                           #
  
#  QUEUE CR/ACC/U ON APPL-S ACB                                        #
  
      ACNBLIM[0] = FALSE;  # CLEAR CONN IN LIMBO FLAG                  #
      BLINK(BUFADDR,ATACBA[NVFAN]);      # QUEUE MSG ON APP-S ACB      #
      OSCHAPP(ATACBA[NVFAN]);      # SCHEDULE APPLICATION              #
      RETURN ;               # RETURN TO CALLING PROGRAM               #
      END 
TERM