*DECK HCRRAPR 
USETEXT NIPDEF
USETEXT SUPMSG
USETEXT AHEADER 
USETEXT PARAMS
USETEXT PT
USETEXT AT
USETEXT NHEADER 
USETEXT ACNB
PROC HCRRAPR ;        # SEND CR/RAP/R TO NVF                           #
STARTIMS; 
 #
*1DC  HCRRAPR 
* 
*     1. PROC NAME           AUTHOR              DATE 
*        HCRRAPR             A. BEN-ARTZI        82/05/06 
* 
*     2. FUNCTIONAL DESCRIPTION 
*        SEND CR/RAP/R TO NVF BASED ON ICN/AP/R FROM CCP
* 
*     3. METHOD USED
*        RE-FORMAT THE ICN/AP/R TO BE A CR/RAP/R BUFFER 
*        SET APPLICATION HEADER 
*        QUEUE TO NVF-S ACB 
* 
*     4. ENTRY PARAMETERS 
*        PARAMS1 - ADDRESS OF ICN/AP/R BUFFER 
*        PARAMS2 - APPLICATION CONNECTION NUMBER
* 
*     5. EXIT PARAMETERS
*        NONE 
* 
*     6. COMDECKS CALLED AND SYMPL TEXTS USED 
*        NIPDEF     SUPMSG     AHEADER     PARAMS 
*        PT     AT
* 
*     7. ROUTINES AND OVERLAYS CALLED 
*        XTRACE - TRACE PROCEDURE CALL
*        BLINK - LINK DATA BLOCK TO DATA RING 
*        OSCHAPP - SCHEDULE APPLICATION 
* 
*     8. DAYFILE MESSAGES AND OTHER IMPORTANT INFORMATION 
*        THIS PROCEDURE IS CALLED BY PRIMARY OVERLAY STRTCON
*        VIA HCSTTP.
* 
 #
STOPIMS;
# 
      EXTERNAL VARIABLE 
# 
 XREF 
   BEGIN
   PROC XTRACE ;           # DEBUG TRACE CALLS                         #
   PROC BLINK  ;           # LINK MESSAGE TO APPLICATION               #
   PROC OSCHAPP;           # SCHEDULE APPLICATION                      #
   END
# 
      INTERNAL VARIABLES
# 
#**********************************************************************#
      BEGIN 
      CONTROL IFEQ DEBUG,1  ; 
        XTRACE("CRRAP") ; 
      CONTROL FI            ; 
# 
      CHANGE HEADER TO APPLICATION HEADER 
# 
      P<AHEADER> = PARAMS1 + BLKHSIZE ; 
      ABHABT[0]  =  APPCMD ;
      ABHACT[0]  =  CT60TRANS ; 
      P<NHEADER> = P<AHEADER>;
      ABHTLC[0] = (2 * CC[0] + 14)/15;
      ABHABN[0]  = 0 ;
      ABHADR[0]  = 0 ;
      ABHDBC[0]  = 0 ;
# 
      SET UP NEW FIELDS IN MESSAGE
# 
      P<SUPMSG> = P<AHEADER> + ABHSIZE ;
      P<SMNIP > = P<SUPMSG> ; 
      P<SMNVF > = P<SUPMSG> ; 
      PFCSFC[0]  = CRRAP ;
      ICNCN [0]  =  0    ;      # ZERO NETWORK CONNECTION FIELD        #
      CRACN [0]  =  PARAMS2 ;   # AND SET APPLICATION CONNECTION NUMBER#
# 
      AND SEND IT TO NVF
# 
      BLINK (PARAMS1,ATACBA[NVFAN]) ;  # QUEUE TO NVF"S ACB            #
      OSCHAPP (ATACBA[NVFAN])       ; 
      RETURN ;
      END 
TERM