*DECK HCRTRMN 
USETEXT NIPDEF
USETEXT AHEADER 
USETEXT AT
USETEXT PARAMS
USETEXT PT
USETEXT SUPMSG
  
  
PRGM HCRTRMN; 
STARTIMS; 
 #
*1DC  HCRTRMN 
* 
*     1. PROC NAME           AUTHOR              DATE 
*        HCRTRMN             C. BITTNER          82/02/01 
* 
*     2. FUNCTIONAL DESCRIPTION 
*        SEND CR/TRM/N  TO NVF
* 
*     3. METHOD USED
*        USING THE BUFFER FROM CR/TRM/R 
*          FORMAT THE APPLICATION HEADER
*          FORMAT THE CR/TRM/N MESSAGE
*          QUEUE THE CR/TRM/N MESSAGE ON NVF-S ACB
* 
*     4. ENTRY PARAMETERS 
*        PARAMS1 - ADDRESS OF SM BUFFER (CR/TRM/R)
* 
*     5. EXIT PARAMETERS
*        NONE 
* 
*     6. COMDECKS CALLED AND SYMPL TEXTS USED 
*        NIPDEF          AHEADER          AT
*        PARAMS          PT               SUPMSG
* 
*     7. ROUTINES CALLED
*        BLINK - QUEUE MESSAGE ON APPL-S ACB
*        OSCHAPP - SCHEDULE APPLICATION 
*        XTRACE - TRACE PROCEDURE CALL
* 
*     8. DAYFILE MESSAGES AND OTHER IMPORTANT INFORMATION 
*        THIS IS A SECONDARY OVERLAY CALLED BY HCSTTP.
*        W A R N I N G - THIS PROGRAM CANNOT EXCEED THE SECONDARY 
*CALL OSSIZE
* 
 #
STOPIMS;
  
# 
      EXTERNAL VARIABLES
# 
 XREF 
   BEGIN
   PROC BLINK;               # QUEUE MSG ON APPL-S ACB                 #
   PROC OSCHAPP;             # SCHEDULE APPLICATION                    #
   PROC XTRACE;              # TRACE PROCEDURE CALL                    #
   LABEL RJMAIN;             # RETURN ADDRESS IN OVLCALL               #
   END
  
# 
      INTERNAL VARIABLES
# 
      ITEM SMBUF;            # ADDRESS OF SM BUFFER                    #
  
#**********************************************************************#
  
      BEGIN 
  
      CONTROL IFEQ DEBUG,1; 
        XTRACE("HCRTR");
      CONTROL FI; 
  
      SMBUF = PARAMS1;
  
#  SET UP APPLICATION HEADER                                           #
  
      P<AHEADER> = SMBUF + AIPHSIZE;            # BASE APPL HEADER     #
      ABHTLC[0] = LCRTRMN;  # LENGTH OF CR/TRM/N                       #
      P<SUPMSG> = P<AHEADER> + ABHSIZE;  # FWA OF CR/TRM/R             #
  
#  FORMAT CR/TRM/N                                                     #
  
      RC[0] = 0;             # CLEAR REASON CODE FIELD                 #
      RB[0] = TRUE;          # SET NORMAL RESPONSE BIT                 #
  
#  QUEUE CR/TRM/N ON NVF-S ACB                                         #
  
      BLINK(SMBUF,ATACBA[NVFAN]);  # LINK MSG ON NVF-S ACB             #
      OSCHAPP(ATACBA[NVFAN]);  # SCHEDULE APPLICATION                  #
      GOTO RJMAIN;           # RETURN TO CALLING PROGRAM               #
      END 
TERM