*DECK HSINITR 
USETEXT NIPDEF
USETEXT AHEADER 
USETEXT AT
USETEXT PARAMS
USETEXT PT
USETEXT SUPMSG
  
PRGM HSINITR; 
STARTIMS; 
 #
*1DC  HSINITR 
* 
*     1. PROC NAME           AUTHOR              DATE 
*        HSINITR             C. BITTNER          81/09/28 
* 
*     2. FUNCTIONAL DESCRIPTION 
*        SENT FC/INIT/R TO APPLICATION TO INDICATE CONNECTION 
*        INITIALIZED
* 
*     3. METHOD USED
*        SET UP APPLICATION BLOCK HEADER
*        SET UP FC/INIT/R MESSAGE 
*        QUEUE MESSAGE ON APPLICATION-S ACB 
* 
*     4. ENTRY PARAMETERS 
*        PARAMS1 - APPLICATION CONNECTION NO. FOR INITIALIZED CONNECTION
*        PARAMS2 - APPLICATION NUMBER 
* 
*     5. EXIT PARAMETERS
*        NONE 
* 
*     6. COMDECKS CALLED AND SYMPL TEXTS USED 
*        NIPDEF 
*        AHEADER
*        AT 
*        PARAMS 
*        PT 
*        SUPMSG 
* 
*     7. ROUTINES CALLED
*        BLINK - LINK DATA BLOCK TO DATA RING 
*        MGETS - ALLOCATE EMPTY BUFFER
*        OSCHAPP - SCHEDULE APPLICATION 
*        XTRACE - TRACE PROCEDURE CALL
* 
*     8. DAYFILE MESSAGES AND OTHER IMPORTANT INFORMATION 
*        THIS IS A SECONDARY OVERLAY CALLED BY HBSTTP.
*        W A R N I N G - THIS PROGRAM CANNOT EXCEED THE SECONDARY 
*CALL OSSIZE
* 
 #
STOPIMS;
  
# 
      EXTERNAL VARIABLES
# 
  
 XREF 
   BEGIN
   PROC BLINK;               # LINK DATA BLOCK TO DATA RING            #
   PROC MGETS;               # ALLOCATE EMTPY BUFFER                   #
   PROC OSCHAPP;             # SCHEDULE APPLICATION                    #
   PROC XTRACE;              # TRACE PROCEDURE CALL                    #
   LABEL RJMAIN;             # RETURN ADDRESS IN OVLCALL               #
   END
  
# 
      INTERNAL VARIABLES
# 
  
      ITEM BUFADDR;          # BUFFER ADDRESS TO HOLD FC/INIT/R        #
      ITEM AN;               # APPLICATION NUMBER                      #
  
#**********************************************************************#
  
      BEGIN 
  
      CONTROL IFEQ DEBUG,1; 
        XTRACE("HSINI") ; 
      CONTROL FI; 
  
      AN = PARAMS2;          # APPLICATION NUMBER                      #
  
#  GET BUFFER TO HOLD FC/INIT/R                                        #
  
      MGETS(LFCINIT + BLKHSIZE + ABHSIZE, BUFADDR, TRUE); 
  
  
#  SET UP APPLICATION BLOCK HEADER                                     #
  
      P<AHEADER> = BUFADDR + BLKHSIZE;  # BASE APPLICATION HEADER      #
      ABHABT[0] = APPCMD;    # COMMAND BLOCK                           #
      ABHACT[0] = CT60TRANS; # CHARACTER TYPE - TRANSPARENT            #
      ABHTLC[0] = LFCINIT;   # LENGTH OF FC/INIT/R                     #
      ABHABN[0] = 0;         # CLEAR APPLICATION BLOCK NUMBER FIELD    #
      ABHADR[0] = 0;         # CLEAR APPLICATION CONNECTION NO. FIELD  #
      ABHDBC[0] = 0;         # CLEAR DATA BLOCK CLARIFIER FIELD        #
  
#  SET UP FC/INITR/R                                                   #
  
      P<SUPMSG> = BUFADDR + BLKHSIZE + ABHSIZE; 
      PFCSFC[0] = FCINIT;    # SET FUNCTION CODE                       #
      FCACN[0] = PARAMS1;    # ACN OF INITIALIZED CONNECTION           #
  
  
#  QUEUE MESSAGE ON APPLICATION-S ACB                                  #
  
      BLINK(BUFADDR,ATACBA[AN]);   # QUEUE MSG ON APPLS-S ACB          #
      OSCHAPP(ATACBA[AN]);     # SCHEDULE APPLICATION                  #
      GOTO RJMAIN;           # RETURN TO CALLING PROGRAM               #
      END 
TERM