*DECK IRECVR
          IDENT  IRECVR 
 OPL      XTEXT  COMCCMD
          ENTRY  IRECVR 
          ENTRY  RPVPBLK
          EXT    OVLCALL
          EXT    XDUMP
          EXT    SYS=                                                    NAMA668
          EXT    RCL= 
          EXT    XTRACE 
          SST 
*#
*1DC  IRECVR
* 
*     1. PROC NAME           AUTHOR              DATE 
*        IRECVR              J. J. LYON          75/10/02 
* 
*     2. FUNCTIONAL DESCRIPTION.
*        THIS ROUTINE IS RESPONSIBLE FOR INITIALIZING NIP-S RECOVERY
*        PROCEDURES.
* 
*     3. METHOD USED. 
*          CALL RPV                                                      NAMA668
* 
*     4. ENTRY PARAMETERS.  NONE
* 
*     5. EXIT  PARAMETERS.  NONE
* 
*     6. COMDECKS CALLED. 
*          INPARU  MACDEF 
* 
*     7. ROUTINES CALLED. 
*          RECOVR            COMPASS - RECOVERY- MACRO
*          SYS=              ISSUE RA+1 CALL                             NAMA668
*          XTRACE            TRACES CALLS 
* 
*     8. DAYFILE MESSAGES.  NONE
* 
*#
*CALL MACDEF
*CALL INPARU
*CALL OVLNAME 
*CALL OVERLAY 
 FLAGS    EQU    77B         TRAP ALL BUT NORMAL TERMINATION
 IRECVR   BSSZ   1           ENTRY/EXIT 
  
          IFEQ   DEBUG,1,6
          SX6    A1 
          SA6    TEMP 
          SX1    IRECN
          RJ     XTRACE 
          SA1    TEMP 
          SA1    X1 
*                CALL REPRIEVE PROCESS
          REPRIEVE RPVPBLK,SET,FLAGS
          EQ     IRECVR 
 IRECN    DATA   L*IRECV* 
 TEMP     BSS    1
          USE    /RECOVER/
 SYSADR   BSSZ   1           ADDRESS OF CALLER FOR LAST SYS= CALL 
 RCLADR   BSSZ   1           ADDRESS OF CALLER FOR LAST RCL=  CALL
* 
*                REPRIEVE PARAMETERS BLOCK
* 
 RPVPBLK  VFD    36/0,12/25,12/C
          VFD    30/0,30/RPVADDR
          BSSZ   23 
          USE    *
 RPVADDR  BSS    0
          SX6    B0 
          SA6    OVLFLAG
          SA1    SYS=        X1 = RETURN JUMP TO SYS= CALLER
          SA2    RCL=        X1 = RETURN JUMP TO RCL= CALLER
          BX6    X1 
          SA6    SYSADR      SAVE ADDRESS OF CALLER OF LAST SYS= CALL 
          BX7    X2 
          SA7    RCLADR      SAVE ADDRESS OF CALLER OF LAST RCL= CALL 
  
          RJ     XDUMP
          SX6    XENDRPVP 
          SA6    OVLNAME
          RJ     OVLCALL
  
         END