*DECK KNAMCOM 
USETEXT NIPDEF
USETEXT PARAMS
USETEXT KDIS
USETEXT DBGBUF
USETEXT OVERLAY 
USETEXT MSGIDX
USETEXT PIT 
USETEXT PT
PRGM KNAMCOM;                # EXECUTE K-DISPLAY NAM COMMANDS          #
STARTIMS; 
 #
*1DC  KNAMCOM 
* 
*     1. PROC NAME           AUTHOR              DATE 
*        KNAMCOM             C. BITTNER          83/04/01 
* 
*     2. FUNCTIONAL DESCRIPTION 
*        THIS PROGRAM PROCESSES THE NAM K-DISPLAY COMMANDS. 
* 
*     3. METHOD USED
*        INDEX INTO THE STATUS SWITCH TO PROCESS THE
*        VARIOUS COMMANDS.
* 
*     4. ENTRY PARAMETERS 
*        PARAMS3 - INDEX INTO THE STATUS SWITCH 
* 
*     5. EXIT PARAMETERS
*        NONE 
* 
*     6. COMDECKS CALLED AND SYMPL TEXTS USED 
*        NIPDEF     PARAMS     KDIS     DBGBUF
*        OVERLAY    MSGIDX
* 
*     7. ROUTINES CALLED
*        NNETREL - RELEASE DEBUG LOG FILE 
*        RDUMP - DUMP NIP-S FIELD LENGTH
*        XCOD - COVERT TO OCTAL DISPLAY 
*        OMSG - ISSUE DAYFILE MESSAGE 
*        XTERMST - PROCESS NIP STATISTICS 
*        XTRACE - TRACE PROCEDURE CALL
* 
*     8. DAYFILE MESSAGES AND OTHER IMPORTANT INFORMATION 
*        NONE 
* 
 #
STOPIMS;
# 
      EXTERNAL REFERENCES 
# 
      XREF
        BEGIN 
        PROC NNETREL;        # RELEASE DEBUG LOG FILE                  #
        PROC XDUMPFL;        # DUMP NIP FL                             #
        PROC XTERMST;        # PROCESS NIP STATISTICS                  #
        PROC XTRACE;         # TRACE PROCEDURE CALL                    #
        LABEL RJMAIN;        # RETURN ADDRESS IN OVLCALL               #
        END 
  
  
# 
      INTERNAL VARIABLES
# 
      SWITCH KNLAB:NCT  # STATUS SWITCH FOR K-DISPLAY COMMANDS         #
        KNDB:CMD$DB,
        KNDE:CMD$DE,
        KNDU:CMD$DU,
        KNLE:CMD$LE,
        KNRS:CMD$RS,
        KNLB:CMD$LB,
        KNLR:CMD$LR;
  
      ITEM SCRATCH;          # SCRATCH VARIABLE                        #
  
      BEGIN 
  
      CONTROL IFEQ DEBUG,1; 
        XTRACE("KNCOM");
      CONTROL FI; 
  
  
  
      GOTO KNLAB[PARAMS3];
  
  
KNDU: 
  
#     TAKE INTERNAL DUMP OF NIP                                        #
  
      XDUMPFL;               # DUMP NIP FL                             #
      GOTO KEXIT; 
  
KNDB: 
  
#     TURN ON IN-LINE DEBUG CODE                                       #
  
      CONTROL IFEQ DEBUG,1; 
      KNAMDB[0] = TRUE;      # SET FLAG TO TURN ON DEBUG               #
      CONTROL FI; 
  
      FOR SCRATCH = 1 STEP 1 UNTIL MAXPIP 
      DO                     # SET FLAG IN ALL PIT ENTRIES             #
        BEGIN 
        PITDHLT[SCRATCH] = TRUE;
        END 
      GOTO KEXIT; 
  
KNDE: 
  
#     TURN OFF IN-LINE DEBUG CODE                                      #
  
      CONTROL IFEQ DEBUG,1; 
      KNAMDB[0] = FALSE;
      CONTROL FI; 
      FOR SCRATCH = 1 STEP 1 UNTIL MAXPIP 
      DO                     # CLEAR FLAG IN ALL PIT ENTRIES           #
        BEGIN 
        PITDHLT[SCRATCH] = FALSE; 
        END 
      GOTO KEXIT; 
  
KNLE: 
  
#     END LOGGING OF NETWORK TRAFFIC IN DEBUG LOG FILE                 #
  
      CONTROL IFEQ DEBUG,1; 
        CONTROL IFEQ ZZDN,1;
        KNAMLB[0] = FALSE;   # CLEAR LOG NETW TRAFFIC FLAG             #
        CONTROL FI; 
      CONTROL FI; 
      GOTO KEXIT; 
  
KNRS: 
  
#     FLUSH AND RESET STATISTICS COUNTER
  
      SEND STATISTICS TO THE DAYFILE                                   #
      CONTROL IFEQ STAT,1;
      KNAMRS[0] = TRUE;  # SET FLUSH STATISTICS FLAG                   #
      XTERMST;               # FLUSH STATISTICS                        #
      CONTROL FI; 
      GOTO KEXIT; 
  
KNLB: 
  
#     LOG NETWORK TRAFFIC IN DEBUG LOG FILE                            #
  
      CONTROL IFEQ DEBUG,1; 
        CONTROL IFEQ ZZDN,1;
        KNAMLB[0] = TRUE;  # SET FLAG TO LOG NETW TRAFFIC              #
        CONTROL FI; 
      CONTROL FI; 
      GOTO KEXIT; 
  
KNLR: 
  
#     RELEASE DEBUG LOG FILE #
  
      CONTROL IFEQ ZZDN,1;
      IF MC NQ 0
      THEN
        NNETREL(ZNRF2,0); 
      CONTROL FI; 
      GOTO KEXIT; 
  
KNND: 
#     SET PIT HALT FLAG      #
#     TO BE IMPLEMENTED FOR V 2.3                                      #
      GOTO KEXIT; 
  
KEXIT:  
      GOTO RJMAIN;
  
      END 
TERM