*DECK LFGLHDR 
      PROC LFGLHDR(LSTNG$ID); 
      BEGIN                  # SEND PAGE ONE SUMMARY LISTING HEADER    #
  
*IF DEF,IMS 
# 
**    LFGLHDR - SEND LISTING HEADER.
* 
*     M. E. VATCHER  81/02/20 
* 
*     LFGLHDR SENDS A LISTING HEADER TO THE OUTPUT FILE.
* 
*     PROC LFGLHDR
* 
*     ENTRY  LSTNG$ID = LISTING IDENTIFIER. 
* 
*     EXIT  NONE. 
* 
*     METHOD
* 
*     SKIP TO A NEW PAGE.  FILL IN DATE, TIME, AND VERSION IN 
*     LISTING HEADER AND WRITE TO OUTPUT FILE.
* 
# 
*ENDIF
  
      ITEM LSTNG$ID I;       # LISTING IDENTIFIER                      #
  
# 
****  PROC LFGLHDR - XREF LIST BEGIN. 
# 
      XREF
        BEGIN 
        ITEM OUTPUT U;       # FWA OF OUTPUT FILE FET                  #
        PROC CLOCK;          # GET TIME OF DAY                         #
        PROC DATE;           # GET DATE                                #
        PROC WRITEC;         # WRITE LINE TO CIO BUFFER                #
        PROC WRITER;         # WRITE RECORD                            #
        FUNC XCDD C(10);     # CONVERT INTEGER TO DECIMAL DISPLAY CODE #
        END 
  
# 
****
# 
  
*CALL NAMLEV
*CALL LFGSTAN 
  
      ITEM TEMPC C(10); 
  
      WRITEC(OUTPUT,SKIPPG);
      WRITEC(OUTPUT,BLANKL);
      WRITEC(OUTPUT,BLANKL);
      IF FIRST$PAGE 
      THEN
        BEGIN                # IF THIS IS FIRST PAGE OF LISTING        #
        TEMPC = C<3,10>NAMVER[0]; 
        STANDV[0] = TEMPC;
        STANDLV[0] = NAMLV[0];
        DATE(TEMPC);
        STANDATE[0] = TEMPC;
        CLOCK(TEMPC); 
        STANDTIME[0] = TEMPC; 
        FIRST$PAGE = FALSE;  # CLEAR FIRST PAGE FLAG                   #
        END 
      IF LSTNG$ID EQ DIR$LST # IF THIS A INPUT DIRECTIVE SUMMARY       #
      THEN
        BEGIN 
        STANDH1[0] = DIR$HDR;# PUT THE HEADER TITLE                    #
        END 
      ELSE                   # MUST BE A SUMMARY LISTING               #
        BEGIN 
        STANDH1[0] = SUM$HDR;# PUT THE HEADER TITLE                    #
        END 
      TEMPC = XCDD(PAGEN);
      STANDPN[0] = C<4,6>TEMPC; # FILL IN PAGE NUMBER                  #
      WRITEC(OUTPUT,STANDH);
      WRITEC(OUTPUT,BLANKL);
      LINEN = 5;
      IF LSTNG$ID EQ SUM$LST # IF THIS IS A SUMMARY LISTING            #
      THEN
        BEGIN 
        WRITEC(OUTPUT,LISTH); 
        WRITEC(OUTPUT,BLANKL);
        LINEN = 7;           # SET LINE NUMBER                         #
        END 
      PAGEN = PAGEN + 1;     # INCREMENT PAGE COUNT                    #
      RETURN;                # **** RETURN ****                        #
      END TERM