*DECK LFGSSLL 
USETEXT LFGFN 
      PROC LFGSSLL(PN,RC);
      BEGIN                  # SEND SUMMARY LISTING LINE               #
*IF DEF,IMS 
# 
**    LFGSSLL - SEND SUMMARY LISTING LINE.
* 
*     M. E. VATCHER  81/02/23 
* 
*     LFGSSLL SENDS A SUMMARY LISTING LINE TO THE OUTPUT FILE.
* 
*     PROC LFGSSLL(PN,RC) 
* 
*     ENTRY PN        PARTITION NAME
*           RC        RECORD COUNT
* 
*     EXIT  NONE. 
* 
*     METHOD
* 
*     FILL IN PARTITION NAME, INPUT FILE NAME, AND RECORD COUNT 
*     AND WRITE LINE TO OUTPUT FILE.
* 
# 
*ENDIF
  
# 
****  PROC LFGSSLL - XREF LIST BEGIN. 
# 
  
      XREF
        BEGIN 
        PROC LFGWL;          # WRITES LINE TO OUTPUT FILE              #
        ITEM OUTPUT U;       # FWA OF LIST OUTPUT FILE FET             #
        PROC WRITEC;         # WRITE LINE TO CIO BUFFER                #
        PROC WRITER;         # WRITE RECORD                            #
        FUNC XCDD C(10);     # CONVERT INTEGER TO DECIMAL DISPLAY CODE #
        FUNC XSFW C(10);     # SPACE FILL WORD                         #
        END 
  
# 
****
# 
  
*CALL LFGSTAN 
  
      ITEM PN C(6);          # PARTITION NAME                          #
      ITEM RC U;             # RECORD COUNT                            #
      ITEM TEMPC C(10); 
  
      ARRAY SLL [0:0] S(5); 
        BEGIN                # SUMMARY LISTING LINE                    #
        ITEM SLLB1 C(0,0,1) = [" "];
        ITEM SLLPNUM C(0,6,3);
        ITEM SLLB2 C(0,24,6) = [" "]; 
        ITEM SLLPNAM C(1,0,6);
        ITEM SLLB3 C(1,36,10) = [" "];
        ITEM SLLLFN C(2,36,7);
        ITEM SLLB4 C(3,18,7) = [" "]; 
        ITEM SLLREC C(4,0,4); 
        ITEM SLLZ C(4,24,36) = [ 0 ]; 
        END 
  
      CONTROL EJECT;
#                                                                      #
#                            LFGSSLL CODE BEGINS HERE                  #
#                                                                      #
      IF LISTFLG             # IF A LISTING IS REQUESTED               #
      THEN
        BEGIN 
        PARTNUM = PARTNUM + 1;         # INCREMENT PARTITION NUMBER    #
        TEMPC = XCDD(PARTNUM);
        SLLPNUM[0] = C<7,3>TEMPC;      # FILL IN PARTITION NUMBER      #
        SLLPNAM[0] = C<0,6>PN;         # FILL IN PARTITION NAME        #
        TEMPC = XSFW(FNAME[LFN]); 
        SLLLFN[0] = C<0,7>TEMPC;       # FILL IN INPUT FILE NAME       #
        TEMPC = XCDD(RC); 
        SLLREC[0] = C<6,4>TEMPC;       # FILL IN RECORD COUNT          #
        LFGWL(SLL,SUM$LST);  # WRITE LINE TO OUTPUT                    #
        END 
      RETURN;                # **** RETURN ****                        #
      END TERM