*DECK NETSETF 
*IF,DEF,DEBUG 
USETEXT AIPDEF
USETEXT NP$DB 
USETEXT NP$LOF
*ENDIF
PROC NETSETF(FLUSH,FETADR);             # SET ZZZZZDN FLUSH BIT        #
    BEGIN 
*CALL NP$CRT
*IF DEF,IMS 
 #
*1DC  NETSETF 
* 
*     1. PROC NAME           AUTHOR              DATE 
*        NETSETF             S.KRULEVITCH        78/11/28 
* 
*     2. FUNCTIONAL DESCRIPTION 
*        THIS ROUTINE SETS THE FLUSH BIT IN THE ZZZZZDN FET FOR 
*        FLUSHING THE CIRCULAR IO BUFFER OF THE DEBUG LOG FILE AT 
*        ABNORMAL JOB STEP TERMINATION. 
* 
*     3. METHOD USED
*        INITIALIZE ZZZZZDN, IF NOT ALREADY DONE
*        FLUSH BIT SET
*        IF FLUSH IS TRUE, THEN SET UP LIST OF FILES AND CALL NP$SLOF 
*        IF FLUSH IS FALSE, THEN RETURN FET ADDRESS 
* 
*     4. ENTRY CONDITIONS 
*        FLUSH - = TRUE, SET UP FILE FLUSH ON ABNORMAL TERMINATION
*                = FALSE, RETURN FETADR 
* 
*     5. EXIT CONDITIONS
*        FETADR - = 0, IF FLUSH EQ TRUE 
*                 = DB$FET, IF FLUSH EQ FALSE 
* 
*     6. COMDECKS CALLED AND SYMPL TEXTS USED.
*        AIPDEF    NP$CRT    NP$DB     NP$LOF 
* 
*     7. ROUTINES CALLED
*        NP$SLOF - SETS LIST OF FILES FOR ABNORMAL JOB STEP TERMINATION 
*                  PROCESSING 
* 
*     8. DAYFILE MESSAGES 
*        NONE 
* 
 #
*ENDIF
# 
      FORMAL PARAMETERS 
# 
      ITEM FLUSH        B;   # IF TRUE, SET LIST OF FILES              #
      ITEM FETADR       I;   # =0 OR = DEBUG LOG FILE FET ADDRESS      #
*IF DEF,DEBUG 
# 
      EXTERNAL ROUTINES 
# 
      XREF
        BEGIN 
        PROC NP$SLOF;        # SET LIST OF FILES                       #
        END 
  
*ENDIF
#**********************************************************************#
# 
      NETSETF EXECUTION BEGINS HERE 
# 
  
      ENTRY PROC QTSETF(FLUSH,FETADR); # QTRM ENTRY PT FOR THIS PROC   #
  
      FETADR = 0;            # 0 VALUE RETURNED IF APP LOADED WITH     #
                             # NETIO                                   #
*IF DEF,DEBUG 
# 
        OPEN ZZZZZDN, IF NOT ALREADY DONE 
# 
      IF FET$LFN NQ "ZZZZZDN" 
      THEN                   # INITIALIZE DEBUG LOG FILE FET           #
        BEGIN 
        FET$LFN = "ZZZZZDN";
        FET$LN[0] = 0;       # INITIALIZE LEVEL NUMBER FIELD IN FET    #
        FET$AT[0] = 0;       # INITIALIZE ABNORMAL TERM CODE FIELD     #
        FET$CODE = 1;        # SET COMPLETION BIT                      #
        FET$LEN = 3;         # SET FET LENGTH                          #
        DB$OP = LOC(DB$BUF); # DB$OP USED AS A TEMPORARY STORE         #
        FET$FIRST = DB$OP;   # INITIALIZE CIRCULAR BUFFER POINTERS     #
        FET$IN = DB$OP; 
        FET$OUT = DB$OP;
        FET$LIMIT = DB$OP + 192;
        END                  # ZZZZZDN FET INITIALIZED                 #
  
      FET$FB[0] = TRUE;      # SET FLUSH BIT                           #
      IF FLUSH
      THEN
        BEGIN 
        LOFN1[0] = LOC(LOFN) + 1; 
        LOFFET[0] = LOC(DB$FET);
        NP$SLOF(LOFN);       # SET LIST OF FILES FOR ABNORMAL JOB STEP #
                             # TERMINATION PROCESSING BY SYSTEM        #
        END 
  
      ELSE
        FETADR = LOC(DB$FET); 
*ENDIF
      RETURN; 
   END                       # NETSETF                                 #
TERM