*DECK NICNTEN 
USETEXT NIPDEF
USETEXT AHEADER 
USETEXT NHEADER 
USETEXT LLCB
USETEXT NCNB
USETEXT PARAMS
USETEXT SUPMSG
  
PROC NICNTEN;                # SEND ICN/TE/N TO CCP                    #
STARTIMS; 
 #
*1DC  NICNTEN 
* 
*     1. PROC NAME           AUTHOR              DATE 
*        NICNTEN             C. BITTNER          81/07/24 
* 
*     2. FUNCTIONAL DESCRIPTION 
*        SEND ICN/TE/N TO CCP 
* 
*     3. METHOD USED
*        ALLOCATE A BUFFER FOR THE MESSAGE
*        SET UP APPLICATION BLOCK HEADER
*        SET UP TEXT FOR ICN/TE/N MESSAGE 
*        LINK MESSAGE TO PIP OUTBOUND CHAIN 
* 
*     4. ENTRY PARAMETERS 
*        PARAMS1 - NETWORK CONNECTION NUMBER
*        PARAMS2 - LLCB ADDRESS 
* 
*     5. EXIT PARAMETERS
*        NONE 
* 
*     6. COMDECKS CALLED AND SYMPL TEXTS USED 
*        NIPDEF              AHEADER
*        LLCB                PARAMS 
*        SUPMSG 
* 
*     7. ROUTINES CALLED
*        MGETS - ALLOCATE EMPTY BUFFER
*        NFOB - LINK BUFFER TO PIP OUTBOUND CHAIN 
*        XTRACE - TRACE PROCEDURE CALL
* 
*     8. DAYFILE MESSAGES AND OTHER IMPORTANT INFORMATION 
*        THIS PROCEDURE IS CALLED BY SECONDARY OVERLAY COMPCON
*        VIA NCSTTP.
* 
 #
STOPIMS;
  
# 
      EXTERNAL VARIABLES
# 
 XREF 
   BEGIN
   PROC MGETS;               # ALLOCATE EMPTY BUFFER                   #
   PROC NFOB;                # LINK BUFFER TO PIP OUTBOUND CHAIN       #
   PROC XTRACE;              # TRACE PROCEDURE CALL                    #
   END
  
# 
      INTERNAL VARIABLES
# 
      ITEM BUFADDR;          # SM BUFFER ADDRESS                       #
  
#**********************************************************************#
  
      BEGIN 
  
      CONTROL IFEQ DEBUG,1; 
        XTRACE("ICNTN") ; 
      CONTROL FI; 
  
# GET BUFFER TO HOLD ICN/TE/N#
      MGETS(LICNTER + BLKHSIZE + ABHSIZE,BUFADDR,TRUE); 
  
# SET UP APPLICATION BLOCK HEADER                                      #
      P<AHEADER> = BUFADDR + BLKHSIZE;  # ADDR TO HOLD ABH             #
      ABHABT[0] = APPCMD;    # BLOCK TYPE                              #
      ABHACT[0] = CT8ASCII;  # CHARACTER TYPE                          #
      ABHTLC[0] = NICNTER;   # TEXT LENGTH                             #
  
# SET UP ICN/TE/N MESSAGE    #
      P<SUPMSG> = BUFADDR + BLKHSIZE + ABHSIZE; 
      P<SMNIP> = P<SUPMSG>; 
      PFCSFC[0] = ICNTEN;    # SET FUNCTION CODE                       #
      ICNCN[0] = PARAMS1;    # NETWORK CONNECTION NUMBER               #
      P<LLCB> = PARAMS2;
  
# LINK MESSAGE TO PIP OUTBOUND CHAIN                                   #
      NFOB(BUFADDR,P<LLCB>);
      RETURN ;               # RETURN TO CALLING PROGRAM               #
      END 
TERM