*DECK NICTEAX 
USETEXT NIPDEF
USETEXT AHEADER 
USETEXT NHEADER 
USETEXT LLCB
USETEXT PARAMS
USETEXT SUPMSG
  
PRGM NICTEAX;                # SEND ICN/TE/A RC=9-16 TO CCP            #
STARTIMS; 
 #
*1DC  NICTEAX 
* 
*     1. PROC NAME           AUTHOR              DATE 
*        NICTEAX             C. BITTNER          81/07/24 
* 
*     2. FUNCTIONAL DESCRIPTION 
*        SEND ICN/TE/A RC=9-16 TO CCP 
* 
*     3. METHOD USED
*        SET TEXT LENGTH IN APPLICATION BLOCK HEADER
*        SET UP TEXT FOR ICN/TE/A USING BUFFER FROM ICN/TE/R
*        LINK MESSAGE TO PIP OUTBOUND CHAIN 
* 
*     4. ENTRY PARAMETERS 
*        PARAMS1 - ADDRESS OF SM BUFFER (ICN/TE/R)
*        PARAMS2 - LLCB ADDRESS 
*        PARAMS3 - REASON CODE (RC=9-16)
* 
*     5. EXIT PARAMETERS
*        NONE 
* 
*     6. COMDECKS CALLED AND SYMPL TEXTS USED 
*        NIPDEF              AHEADER
*        LLCB                OSSIZE 
*        PARAMS              SUPMSG 
* 
*     7. ROUTINES CALLED
*        NFOB - LINK BUFFER TO PIP OUTBOUND CHAIN 
*        XTRACE - TRACE PROCEDURE CALL
* 
*     8. DAYFILE MESSAGES AND OTHER IMPORTANT INFORMATION 
*        THIS PROGRAM IS A SECONDARY OVERLAY LOADED BY
*        SUBROUTINE OVLCALL.
*        THIS PROGRAM IS CALLED BY NCSTTP.
*        W A R N I N G - THIS PROGRAM CANNOT EXCEED THE SECONDARY 
*CALL OSSIZE
* 
 #
STOPIMS;
  
# 
      EXTERNAL VARIABLES
# 
 XREF 
   BEGIN
   PROC NFOB;                # LINK BUFFER TO PIP OUTBOUND CHAIN       #
   PROC XTRACE;              # TRACE PROCEDURE CALL                    #
   LABEL RJMAIN;             # RETURN ADDRESS IN OVLCALL               #
   END
  
# 
      INTERNAL VARIABLES
# 
      ITEM BUFADDR;          # SM BUFFER                               #
  
  
#**********************************************************************#
  
      BEGIN 
  
      CONTROL IFEQ DEBUG,1; 
        XTRACE("ICTEX") ; 
      CONTROL FI; 
  
      BUFADDR = PARAMS1;     # SM BUFFER ICN/TE/R                      #
      P<AHEADER> = BUFADDR + BLKHSIZE;  # ADDRESS OF ABH               #
      ABHABT[0] = APPCMD;    # BLOCK TYPE                              #
      ABHACT[0] = CT8ASCII;  # CHARACTER TYPE                          #
      ABHTLC[0] = LICNTEA;   # TEXT LENGTH                             #
  
# SET UP ICN/TE/A MESSAGE    #
      P<SUPMSG> = BUFADDR + BLKHSIZE + ABHSIZE;  # ADDR OF ICN/TE/R    #
      P<SMNIP> = P<SUPMSG>; 
      EB[0] = TRUE;          # SET ERROR RESPONSE BIT                  #
      ICNR36[0] = 0;         # ZERO OUT RIGHTMOST 36 BITS              #
      ICNRTE[0] = PARAMS3;  # REASON CODE                              #
      P<LLCB> = PARAMS2;
  
# LINK MESSAGE TO PIP OUTBOUND CHAIN                                   #
      NFOB(BUFADDR,P<LLCB>);
      GOTO RJMAIN;           # RETURN TO CALLING PROGRAM               #
      END 
TERM