*DECK NP$XFR
*IF DEF,XFR 
USETEXT AIPDEF
USETEXT NP$MODE 
USETEXT NP$DB 
USETEXT NP$NWL
USETEXT NP$ONAM 
USETEXT NP$STAT 
USETEXT NP$ZHDR 
USETEXT NX$ACBF 
USETEXT NX$ACBX 
 PROC NP$XFR ;
 #
*1DC  NP$XFR
* 
*     1. PROC NAME         AUTHOR               DATE
*        NP$XFR            LIEM T NGUYEN        84/03/01
* 
*     2. FUNCTIONAL DESCRIPTION 
*        VALIDATE THIS APPLICATION FOR FILE TRANSFER CAPABILITY.
* 
*     3. METHOD USED
*        SENDING AN XFR WIRKLIST TO NIP AND PROCESS RETURN. 
* 
*     4. ENTRY CONDITIONS 
*        NONE.
* 
*     5. EXIT CONDITIONS
*        NET$AWL$XFR WILL BE SET ACCORDING TO INFORMATION RETURN
*        FROM NIP.
* 
*     6. COMDECKS CALLED AND SYMPL TEXTS USED.
*        AIPDEF    NP$CRT    NP$DB     NP$LOF 
*        NP$MODE   NP$NWL    NP$ONAM   NP$STAT
*        NP$ACBF   NP$ACBX
* 
*     7. ROUTINES CALLED
*        NP$SEND - SENDS WORKLIST TO NIP
* 
 #
   BEGIN
  
#                                                                     # 
#     ROUTINES CALLED:                                                # 
#                                                                     # 
      XREF
        BEGIN 
        PROC NP$SEND;                   #SENDS NWL TO NIP VIA SSCALL  # 
        PROC NP$UCV ; 
        END #XREFS# 
  
      ARRAY TEMPPTR S(1) ;
        BEGIN 
        ITEM TEMPM B(0,56,1) ;
        ITEM TEMPD B(0,57,1) ;
        ITEM TEMPP B(0,58,1) ;
        ITEM TEMPS B(0,59,1) ;
        END 
  
  
# 
      FORMAT NETON NWL ENTRY
# 
      N$XFRAWL[0] = 1 ;                 # XFR WORKLIST OUTSTANDING     #
      NWL[NEXT]=0;           #CLEAR AND BUILD OP WORD                 # 
      NWL$OP[NEXT]= OP$XFR ;
      NWL$ID[NEXT] = AWLID;  #UNPROCESSED WORKLIST ID = AWLID (=11)   # 
      BS = XFRBSIZE ; 
  
      NP$UCV ;
  
# 
      SEND NETON XFR TO NIP 
# 
      TEMPM = SENDGETMM ; 
      TEMPS = SENDGETSM ;    # NO NEED TO PICK UP SUP MSGS             #
      TEMPD = DEFER$PRO ; 
      TEMPP = PARALLEL ;
      DEFER$PRO = FALSE ; 
      PARALLEL = FALSE ;
      SENDGETMM = FALSE ; 
      SENDGETSM = FALSE ; 
      XFRWLIST = TRUE ; 
      NP$SEND;
      SENDGETMM = TEMPM ; 
      SENDGETSM = TEMPS ; 
      DEFER$PRO = TEMPD ; 
      PARALLEL = TEMPP ;
      XFRWLIST = FALSE ;
      RETURN; 
   END
TERM
*ENDIF