*DECK     NVFLSIT 
OVERLAY(77,00)
USETEXT          TEXTSS 
USETEXT          TXSMNVF
USETEXT          TXTAPSS
PRGM NVFLSIT; 
# TITLE NVFLSIT - SEQUENCE INITIALIZATION TASKS.                       #
  
      BEGIN  # NVFLSIT #
# 
**    NVFLSIT - SEQUENCE INITIALIZATION TASKS.
* 
*     S. H. FISCHER.         81/08/26.
*     D. G. DEPEW.           82/01/04.
*     C. J. BRION            82/06/22, 83/12/12.
* 
*     THIS PROGRAM FORMS THE INITIALIZATION OVERLAY FOR NVF.
*     ITS JOB IS TO PERFORM, OR CALL ROUTINES TO PERFORM, ALL THE 
*     TASKS THAT MUST BE DONE BEFORE STARTING NORMAL OPERATIONS OF NVF. 
* 
*     PROC NVFLSIT
* 
*     ENTRY   NONE. 
* 
*     EXIT    NVF READY TO START NORMAL OPERATIONS. THIS PROGRAM
*             DOES NOT EXIT IN THE NORMAL FASHION.  IT INSTEAD MAKES A
*             JUMP TO THE EXECUTION SEQUENCER (*SSSPES*), WHICH NEVER 
*             RETURNS.
# 
  
# 
****  PROC NVFLSIT - XREF LIST BEGIN. 
# 
  
      XREF
        BEGIN 
        PROC NETDBG;
        PROC NETREL;
        PROC NETSETF; 
        PROC NVFIIPS;        # INITIALIZE PID STATUS                   #
        PROC NVFIAST;        # INITIALIZE APPLICATION STATUS TABLE     #
        PROC NVFIBOF;        # BUILD OVERLAY FILE AND DEFINITIONS      #
        PROC NVFIBOT;        # BUILD OPERATOR TABLE AND FLAGS          #
        PROC NVFIBPT;        # BUILD DEBUG AID POINTER TABLE           #
        PROC NVFIBRT;        # BUILD ROLLOUT TABLE                     #
        PROC NVFIBWD;        # BUILD WORKLIST DEFINITIONS              #
        PROC NVFIBSW;        # BUILD STATUS WORKLIST DEFINITIONS       #
        PROC NVFICSC;        # CONTROL STATEMENT CRACKER               #
        PROC NVFICTN;        # CONNECT TO NETWORK                      #
        PROC NVFIIAM;        # INITIALIZE AIP MONITOR                  #
        PROC NVFIIMT;        # INITIALIZE MANAGED TABLES               #
        PROC NVFIITR;        # INITIALIZE TIMER ROUTINES               #
        PROC NVFIIVF;        # INITIALIZE VCB FILE                     #
        PROC NVFIIVT;        # INITIALIZE VOT AND VDT FOR VCB FILE     #
        PROC NVFISUE;        # SET USER ENVIRONMENT                    #
        PROC SSSPES;         # PROGRAM EXECUTION SEQUENCER             #
        END 
  
# 
****
# 
  
  
      DEF NR$NAME # O"16220634000000000000" #;  # NETREL NAME (NRF1)   #
  
  
      ITEM STATIS;           # STATUS RETURNED BY NETDBG               #
      ITEM GETFET;           # ZZZZZDN FLUSH INDICATOR #
      ITEM DNFETADR;         # *ZZZZZDN* FET ADDRESS                   #
  
  
      P<ABH> = LOC(ABHBUF); 
      P<NVFSM> = LOC(MSGBUF); 
      P<APSM> = LOC(MSGBUF);
      TXTALEN = MSBFAPL + 1; # SET TEXT LENGTH OF BLOCK NVF CAN ACCEPT #
  
      NVFIBPT;               # BUILD DEBUG AID POINTER TABLE           #
  
      NVFICSC;               # CRACK THE CONTROL STATEMENT             #
  
      NVFIIMT;               # INITIALIZE MANAGED TABLES               #
  
      NVFIBWD;               # BUILD WORKLIST DEFINITIONS              #
  
      NVFIBSW;               # BUILD STATUS WORKLIST DEFINITIONS       #
  
      NVFIITR;               # INITIALIZE TIMER ROUTINES               #
  
      NVFIIAM;               # INITIALIZE AIP MONITOR                  #
  
      NVFIIVF;               # INITIALIZE VCB FILE                     #
  
      NVFIIVT;               # INITIALIZE VOT AND VDT FOR VCB FILE     #
  
      NVFIAST;               # INITIALIZE APPLICATION STATUS TABLE     #
  
      NVFIBRT;               # BUILD ROLLOUT TABLE                     #
  
      NVFIBOF;               # BUILD OVERLAY FILE AND DEFINITIONS      #
  
      NVFIBOT;               # BUILD HOP ACN LIST ENTRY AND SET FLAGS  #
  
      NVFIIPS;               # INITIALIZE PID STATUS                   #
  
      IF MC NQ 0             # IF TRACE FILE COUNT 0 #
      THEN
        NETREL(NR$NAME,0,0); # INIT ZZZZZDN FILE #
  
      GETFET = 0; 
      NETSETF(GETFET,DNFETADR);        # GET THE *ZZZZZDN* FET ADDRESS #
      TPA$ADDR[1] = DNFETADR;          # SAVE THE FET ADDRESS          #
  
      NVFICTN;               # CONNECT TO NETWORK, SET PARALLEL MODE   #
  
      NETDBG(FALSE,FALSE,STATIS);      # UNCONDITIONAL TURN TRACING OFF#
  
      NVFISUE;               # ESTABLISH ENVIRONMENT FOR T-A CONNS     #
  
      SSSPES;                # PROCEED TO NORMAL OPERATIONS, NO RETURN #
  
  
      END  # NVFLSIT #
  
      TERM