*DECK OMSG
          IDENT  OMSG 
          ENTRY  OMSG 
          EXT    XTRACE 
          SST 
          IPARAMS 
*#
*1DC  OMSG
* 
*     1. PROC NAME           AUTHOR              DATE 
*        OMSG                J. J. LYON          75/06/02 
* 
*     2. FUNCTIONAL DESCRIPTION.
*        THIS ROUTINE IS RESPONSIBLE FOR PUTTING OUT A MESSAGE TO NIP-S 
*        DAYFILE. 
* 
*     3. METHOD USED. 
*          SET UP X6 AND X1 REGISTERS FOR MSG= ROUTINE                   NAMA527
* 
*     4. ENTRY PARAMETERS.
*          A1 = ADDR OF FWA OF MESSAGE
*          DAYFILE MESSAGE MUST END WITH 12 BITS OF ZERO IN BYTE 4       NAMA527
* 
*     5. EXIT PARAMETERS.  NONE 
* 
*     6. COMDECKS CALLED. 
*          INPARU  MACDEF 
* 
*     7. ROUTINES CALLED. 
*          MSG=              CALL PP ROUTINE MSG                         NAMA527
*          XTRACE            TRACES CALLS 
* 
*     8. DAYFILE MESSAGES.  NONE
* 
*#
*CALL MACDEF
*CALL INPARU
BLANK     VFD    12/2H  ,48/0 
MSGADDR   BSSZ   1           STORAGE WORD FOR MESSAGE ADDRESS            NAMA527
MSGFUNC   BSSZ   1
  
 OMSG     SUBR   =           ENTRY/EXIT 
          SA1    A1          GET ADDRESS OF MESSAGE                      NAMA527
          SA2    X1          FIRST WORD OF MESSAGE
          SA4    A1+1 
          SA4    X4          GET OPERATION MODE 
          BX6    X4 
          SA6    MSGFUNC
          MX0    12 
          BX3    X0*X2       UPPER 12 BITS OF MESSAGE-S FIRST WORD
          NZ     X3,OMSG1    IF IT IS NOT ZERO
          ZR     X2,OMSG1    IF IT IS ZERO
          BX3   -X0*X2       MASK OFF LOWER 48 BITS OF FIRST WORD 
          SA2    BLANK
          BX6    X2+X3
          SA6    X1          BLANK-FILLED FIRST 2 CHARACTERS OF MSG 
OMSG1     BSS    0
          IFEQ   DEBUG,1,9
          BX6    X1                                                      NAMA527
          SA6    MSGADDR     SAVE MESSAGE ADDRESS                        NAMA527
          SX6    A1 
          SA6    TEMP 
          SX1    XOMSG
          RJ     XTRACE 
          SA1    TEMP 
          SA1    X1 
          SA1    MSGADDR                                                 NAMA527
          SA4     MSGFUNC 
          MESSAGE X1,X4,R   ISSUE MACRO CALL WITH PROPER TYPE 
          EQ      OMSGX      RETURN 
 XOMSG    DATA   L* OMSG* 
 TEMP     BSS    1
          END