*DECK XENDRPV 
USETEXT NIPDEF
USETEXT PIT 
USETEXT PT
USETEXT BPIPBUF 
PRGM XENDRPV;                # TERMINATION IN RPV MODE                 #
  
 STARTIMS;
 #
*1DC  XENDRPV 
* 
*     1. PROC NAME           AUTHOR              DATE 
*        XENDRPV             P.C.TAM             78/07/18 
* 
*     2. FUNCTIONAL DESCRIPTION.
*        PROCESSING TERMINATION IN RPV MODE.
* 
*     3. METHOD USED. 
*        TAKE A DUMP OF NIP, LOG STATISTICS, STOP.
* 
*     4. ENTRY PARAMETERS.
*        NONE.
* 
*     5. EXIT PARAMETERS. 
*        NONE.
* 
*     6. COMDECKS CALLED AND SYMPL TEXTS USED.
*        NIPDEF    OPSIZE 
* 
*     7. ROUTINES CALLED. 
*        XTERMST             TERMINATION STATISTICS 
*        XCLOST              CLOSE ZZZZZDN FILE 
*        XDPIP               DUMP PIP TO ZZZZZPP
* 
*     8. DAYFILE MESSAGES.
*        NONE.
* 
*        THIS PROGRAM IS A PRIMARY OVERLAY LOADED BY SUBROUTINE OVLCALL.
*        WHEN EXECUTION HAS COMPLETED, A JUMP IS MADE TO LOCATION RJMAIN
*        TO RETURN TO THE CALLING PROGRAM.
* 
*        W A R N I N G - THIS ROUTINE IS LOADED WITH XCLOST,
*                        AND XTERMST.  THE SUM OF THEIR SIZES 
*                        CANNOT EXCEED THE PRIMARY
*CALL OPSIZE
* 
* 
 #
 STOPIMS; 
# 
      EXTERNAL VARIABLES
# 
      XREF
        BEGIN 
        PROC XCLOST;         # CLOSE ZZZZZDN TRACE FILE                #
        PROC XDUMP;          # DUMP FL                                 #
        PROC XDPIP;          # FORMAT PIP DUMP FILE ZZZZZPP            #
        PROC XTERMST;        # LOG STATISTICS                          #
        END 
  
# 
      INTERNAL VARIABLES
# 
      ITEM I;                          # INDUCTION VARIABLE            #
      ITEM NUMPIP;                     # NUMBER OF PIPS RUNNING        #
      CONTROL EJECT;
  
      BEGIN # XENDRPV # 
  
      NAMFAIL = TRUE;        # SET NAM FAILED FLAG                     #
# 
      DUMP FIELD LENGTH 
# 
      XDUMP;
# 
      LOG STATISTICS
# 
      CONTROL IFEQ STAT,1;
      XTERMST;
      CONTROL FI; 
# 
      CLOSE ZZZZZDN TRACE FILE
# 
      CONTROL IFEQ ZZDN,1;
      XCLOST(BPFET) ; 
      CONTROL FI ;
# 
      COUNT NUMBER OF PIPS RUNNING
# 
      NUMPIP = 0; 
      FOR I = 1 STEP 1 UNTIL MAXPIP 
      DO                               # CHECK EACH PIT ENTRY          #
        BEGIN 
        IF PITPUF[I]
           AND NOT PITC[I]
        THEN                           # PIP IS STILL RUNNING          #
          BEGIN 
          NUMPIP = NUMPIP + 1;
          END 
        END 
# 
      FRMAT PIP DUMP FILE ZZZZZPP 
# 
      XDPIP(PITDUMPA[0],NUMPIP);
  
      STOP; 
  
      END # XENDRPV # 
  
      TERM