IDENT  0PT,RPFX
          TITLE  0PT - RESET PRIMARY FILE.
          PERIPH J
          BASE   MIXED
          SST
*COMMENT  0PT - RESET PRIMARY FILE.
          COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992.
 RPF      SPACE  4,10
***       RPF - RESET PRIMARY FILE.
*         P. D. FARRELL.     81/09/10.
 RPF      SPACE  4,10
***              RPF IS A LOCATION-FREE, ZERO-LEVEL OVERLAY TO
*         BE USED TO RESET THE PRIMARY FILE POINTERS IN THE JOB
*         EJT ENTRY.
 RPF      SPACE  4,10
***       CALL.
*
*         ENTRY  (FS - FS+4) = FST INFORMATION FOR NEW FILE.
*
*         EXIT   (A) = 0.
 RPF      SPACE  4,10
**        DEFINITION COMMON DECKS.


*CALL     COMPMAC
*CALL     COMPREL
*CALL     COMSZOL
          SPACE  4,10
****      DIRECT LOCATION ASSIGNMENTS.


 FS       EQU    20 - 24     FST INFORMATION (5 LOCATIONS)

****
 RPF      TITLE  MAIN ROUTINE.
 RPF      SPACE  4,10
**        RPF - MAIN ROUTINE.


          ORG    5
 RPF      SUBR               ENTRY/EXIT
          LDD    LA          RELOCATE INSTRUCTION
          RAM    RPFA

*         FORMAT *UTEM* MONITOR REQUEST.

          LDD    FS          SET NEW EST ORDINAL
          STM    RPFB+3
          LDD    FS+1        SET NEW FIRST TRACK
          STM    RPFB+4

*         SET EJT ADDRESS AND ISSUE MONITOR REQUEST.

          LDD    CP          READ EJT ORDINAL WORD
          ADK    TFSW
          CRD    CM
          SFA    EJT,CM      SET EJT ADDRESS
          STD    CM+4
          SHN    -14
          STD    CM+3
          LDN    0
          STD    CM+2
          LDN    1           SET REQUEST LENGTH
          STD    CM+1
          LDD    MA          WRITE PARAMETERS TO MESSAGE BUFFER
          CWM.   RPFB,ON
 RPFA     EQU    *-1
          MONITOR  UTEM      ISSUE MONITOR REQUEST
*         LDN    0
          LJM    RPFX        RETURN


 RPFB     VFD    1/0,5/PRFE,6/21D,6/0,42/0
 RPF      SPACE  4,10
**        EXECUTABLE COMMON DECKS.


 EJT$     EQU    1           ASSEMBLE EJT ADDRESSING (COMPGFP)
*CALL     COMPGFP
 RPF      SPACE  4,10
          RSTR               RESTORE INSTRUCTIONS
 RPF      SPACE  4,10
**        OVERFLOW TEST.


          OVERFLOW  5,ZPTL


          END