IDENT  DSDUMP
          ENTRY  DSDUMP
          SYSCOM B1
          TITLE  DSDUMP - DIRECT SUBSEQUENT DUMPS.
*COMMENT  DSDUMP - DIRECT SUBSEQUENT DUMPS.
          COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992.
          SPACE  4
*****     DSDUMP - DIRECT SUBSEQUENT DUMPS.
*
*         A. J. KOMOR.       72/07/24.
*         J. R. HOGUE.       72/10/05.
*         W. E. MARTIN.      78/12/30.
          SPACE  4
*         COMMON TEXTS.


*CALL     COMCMAC
*CALL     COMKMAC
*CALL     COMSPRD
          SPACE  4,75
***       DSDUMP - DIRECT SUBSEQUENT DUMPS.
*
*         DSDUMP IS A PRODUCT SET INTERFACE WHICH ALLOWS THE APPLI-
*         CATION PROGRAMMER TO CHANGE ANY OF THE DEFAULT VALUES OF A
*         CMDUMP REQUEST.  THE DSDUMP DOES NOT CAUSE A DUMP IN ITSELF,
*         EXCEPT, WHEN THE SYSTEM DETECTS AN ERROR (I.E. ABORT).  ANY
*         DEFAULT VALUES ON THE DSDUMP ARE SATISFIED FROM THE GENERAL
*         DEFAULT VALUES WHICH ARE ASSEMBLED IN THE EXECUTIVE.
*
*         CALLING FORMATS -
*
*         COBOL -
*
*         ENTER DSDUMP USING FWA, LWA, EP, DB, OQ, QD.
*
*         FORTRAN EXTENDED -
*
*         CALL DSDUMP(FWA,LWA,EP,DB,OQ,QD)
*
*         FWA    BEGINNING ADDRESS, LEGAL VALUES - FWA .LT. FL.
*                IF NEGATIVE (BIT 17 SET) USE DEFAULT.
*                COBOL                COMP-1.
*                FORTRAN EXTENDED     INTEGER.
*
*         LWA    LAST WORD ADDRESS, LEGAL VALUES - FWA .LT. FL.
*                .EQ. 0 - IMPLIES NO DUMP OF FIELD LENGTH.
*                IF NEGATIVE (BIT 17 SET) USE DEFAULT.
*                COBOL                COMP-1.
*                FORTRAN EXTENDED     INTEGER.
*
*         EP     EXCHANGE PACKAGE, LEGAL VALUES -
*                .EQ. 0 - OPTION NOT DESIRED.
*                .NE. 0 - OPTION SELECTED.
*                IF NEGATIVE (BIT 59 SET) USE DEFAULT.
*                COBOL                COMP-1.
*                FORTRAN EXTENDED     INTEGER.
*
*         DB     DATA BUFFERS DUMP, LEGAL VALUES -
*                .EQ. 0 - OPTION NOT DESIRED.
*                .NE. 0 - OPTIONSELECTED.
*                IF NEGATIVE (BIT 59 SET) USE DEFAULT.
*                COBOL                COMP-1.
*                FORTRAN EXTENDED     INTEGER.
*
*         OQ     OUTPUT QUEUE, LEGAL VALUES -
*                .EQ. O - DUMP TO BATCH PRINTER.
*                .EQ. 1 - DUMP TO E/I 200.
*                .EQ 2 - DUMP TO USER PERMANENT FILE.
*                IF NEGATIVE (BIT 59 SET) USE DEFAULT.
*                COBOL                COMP-1.
*                FORTRAN EXTENDED     INTEGER.
*
*         QD     QUEUE DESTINATION, LEGAL VALUES -
*                IF PRINTER IS SPECIFIED IN PREVIOUS PARAMETER,
*                PRINTER I.D. IS SPECIFIED IN NUMERIC CHARACTERS
*                RIGHT JUSTIFIED WITHIN WORD.
*                IF NEGATIVE (BIT 17 SET) USE DEFAULT.
*
*                IF E/I 200 IS SPECIFIED IN PREVIOUS PARAMETER, THE
*                ACCOUNT NUMBER IS SPECIFIED IN DISPLAY CODED LEFT
*                JUSTIFIED CHARACTERS.  MAXIMUM LENGTH IS SEVEN
*                CHARACTERS.
*                IF NEGATIVE (BIT 59 SET) USE DEFAULT.
*
*                IF USER PERMANENT FILE IS SPECIFIED, THE PERMANENT
*                FILE NAME IS SPECIFIED IN DISPLAY CODED LEFT
*                JUSTIFIED CHARACTERS.  ANY LEGAL FILE NAME IS
*                PERMISSIBLE WITH A MAXIMUM OF SEVEN CHARACTERS.
*                IF NEGATIVE (BIT 59 SET) USE DEFAULT.
*
*
*         USES   A - 1, 2, 3, 4, 6, 7.
*                X - ALL.
*                B - 1, 3.
*
*         CALLS  ZFN.
*
*         MACROS DSDUMP.


          VFD    42/0LDSDUMP,18/DSDUMP

 DSD5     SA1    DSDB        RESTORE (A0)
          SA0    X1+

 DSDUMP   SUBR               ENTRY/RETURN
          SX6    A0          SAVE (A0)
          MX5    60-18
          SA6    DSDB
          SB1    1
          SA4    X1          READ FWA PARAMETER ADDRESS
          SA3    A1+B1       READ LWA PARAMETER ADDRESS
          BX6    -X5*X4
          SA2    X3          READ LWA
          BX2    -X5*X2
          LX2    30
          BX6    X2+X6       (X6) = LWA AND FWA
          SA1    A3+B1       READ EXCHANGE POINT PARAMETER
          SA3    A1+B1       READ DATA BASE PARAMETER ADDRESS
          SA2    X1          READ EXCHANGE PACKAGE DUMP FLAG
          SA1    X3          READ DATA BASE DUMP FLAG
          BX3    X3-X3
          SA4    A3+B1       READ OUTPUT QUEUE PARAMETER ADDRESS
          SX7    X1
          ZR     X7,DSD1     IF DATA BUFFER DUMP NOT DESIRED
          SX3    B1
          LX3    58
          PL     X1,DSD1     IF NOT DEFAULT PARAMETER
          LX3    -2
 DSD1     SX7    X2
          BX1    X1-X1
          ZR     X7,DSD2     IF EXCHANGE PACKAGE DUMP NOT DESIRED
          MX1    1
          PL     X2,DSD2     IF NOT DEFAULT PARAMETER
          LX1    -2
 DSD2     BX6    X6+X3       (X6) = LWA + FWA + DB
          SA3    A4+B1       READ SIXTH PARAMETER POINTER
          BX6    X6+X1       (X6) = LWA + FWA + DB + EP
          SA2    X4          READ OUTPUT QUEUE
          SA6    DSDA
          BX0    -X5*X2
          SA1    X3          READ QUEUE DESTINATION
          SB3    X0+
          ZR     B3,DSD3     IF DUMP IS TO LOCAL PRINTER
          RJ     ZFN         ZERO FILL NAME
          EQ     DSD4        PROCESS QUEUE DESTINATION PARAMETER

 DSD3     BX5    -X5
 DSD4     BX7    X5*X1       EXTRACT QUEUE DESTINATION
          BX7    X7+X0       (X7) = DESTINATION + QUEUE
          SA7    A6+1
          DSDUMP DSDA        ISSUE REQUEST TO EXECUTIVE
          EQ     DSD5        RESTORE (A0) AND RETURN

 DSDA     VFD    1/1,1/1,1/0,1/0,8/,18/3LLWA,12/0,18/3LFWA
          VFD    42/2LQD,18/2LOT
 DSDB     CON    0           STORAGE FOR (A0)
          SPACE  4
*         COMMON DECK.


*CALL     COMKZFN
          SPACE  4
          END