IDENT  INTOT 


          ENTRY  INTOT.
          ENTRY  EOQ.        ENTER OUTPUT QUEUE
          ENTRY  FAR.        FILE ATTACH ROUTINE
          ENTRY  GRA.        GET REFERENCE ADDRESS
          ENTRY  RIQ.        RETURN INPUT QUEUE


          TITLE  INTOT. - INTERFACE FOR TOTAL TO TAF TABLES.
*COMMENT  INTOT. - TOTAL INTERFACE TO TAF TABLES.
          COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992.
 INTOT.   SPACE  4,10
***       INTOT. - INTERFACE FOR TOTAL TO TRANEX.
*         L. A. BOELTER 75/01/20.
          SPACE  4
**        INTOT. PROVIDES FOUR ENTRY POINTS THAT ARE USED BY TOTAL
*         TO REFERENCE TABLES IN TRANEX.
*         AN ADDITIONAL ENTRY POINT IS PROVIDED FOR USE BY
*         TRANEX1 TO PASS A LIST OF ADDRESSES IN TRANEX TO
*         BE PLACED IN RETURN JUMP INSTRUCTIONS TO COMPLETE
*         THE TOTAL-TRANEX INTERFACE.
          TITLE  INITIALIZATION.
**        INTOT. - INITIALZE TOTAL/TRANEX INTERFACE.
*
*         ENTRY. (A1) - ADDRESS OF PARAMETER LIST.
*                WORD 1 = ADDRESS OF EOQ IN TRANEX.
*                     2 = ADDRESS OF FAR IN TRANEX.
*                     3 = ADDRESS OF GRA IN TRANEX.
*                     4 = ADDRESS OF RIQ IN TRANEX.
*                (X1) = ADDRESS FOR EOQ.
*
*         EXIT.  (X6) = ADDRESS OF TOTAL ENTRY POINT.
*
*         USES   X - 0, 1, 2, 6.
*                A - 1, 2, 6.


 INTOT.   PS     0           ENTRY
          MX0    18
          LX0    -12

*         MODIFY THE RJ FOR EOQ.

          SA2    EOQ1
          LX1    30
          BX6    -X0*X2
          BX6    X1+X6
          SA6    A2

*         MODIFY THE RJ FOR FAR.

          SA1    A1+1        ADDRESS FOR FAR
          SA2    FAR1
          LX1    30
          BX6    -X0*X2
          BX6    X1+X6
          SA6    A2

*         MODIFY THE RJ FOR GRA.

          SA1    A1+1        ADDRESS FOR GRA
          SA2    GRA1
          LX1    30
          BX6    -X0*X2
          BX6    X1+X6
          SA6    A2

*         MODIFY THE RJ FOR RIQ.

          SA1    A1+1        ADDRESS FOR RIQ
          SA2    RIQ1
          LX1    30
          BX6    -X0*X2
          BX6    X1+X6
          SA6    A2
          SX6    =XTOTAL     TOTAL ENTRY POINT FOR TRANEX
          EQ     INTOT.      RETURN TO TRANEX1
          TITLE  INTERFACE ROUTINES.
 EOQ.     SPACE  4,10
**        EOQ. - ENTER OUTPUT QUEUE.
*
*         PASS CALL FROM TOTAL TO EOQ IN TRANEX.
*
*         CALLS  =XEOQ.


 EOQ.     PS     0           ENTRY/EXIT
 EOQ1     RJ     EOQ1        CALL EOQ
*         RJ     =XEOQ       (CALL EOQ)
          EQ     EOQ.        RETURN
 FAR.     SPACE  4,10
**        FAR. - FILE ATTACH ROUTINE.
*         PASS CALL FROM TOTAL TO FAR IN TRANEX.
*
*         CALLS  =XFAR.


 FAR.     PS     0           ENTRY/EXIT
 FAR1     RJ     FAR1        CALL FAR
*         RJ     =XFAR       (CALL FAR)
          EQ     FAR.        RETURN
 GRA.     SPACE  4,10
**        GRA. - GET REFERENCE ADDRESS.
*         PASS CALL FROM TOTAL TO GRA IN TRANEX.
*
*         USES   X - 6.
*
*         CALLS  =XGRA.


 GRA.     PS     0           ENTRY/EXIT
          SX6    B1+         SET FLAG - CALLED BY *TOTAL*
 GRA1     RJ     GRA1        CALL GRA
*         RJ     =XGRA       (CALL GRA)
          EQ     GRA.        RETURN
 RIQ.     SPACE  4,10
**        RIQ. - RETURN INPUT QUEUE.
*         PASS CALL FROM TOTAL TO RIQ IN TRANEX.
*
*         CALLS  =XRIQ.


 RIQ.     PS     0           ENTRY/EXIT
 RIQ1     RJ     RIQ1        CALL RIQ
*         RJ     =XRIQ       (CALL RIQ)
          EQ     RIQ.        RETURN


          END    INTOT.