IDENT  WAIT
          ENTRY  WAIT
          SYSCOM B1
          TITLE  WAIT - TASK WAIT REQUEST.
*COMMENT  WAIT - TASK WAIT REQUEST.
          COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992.
 WAIT     SPACE  4,10
*****     WAIT - TASK WAIT REQUEST.
*
*         M.M. CHEN.         79/10/10.

*         COMMON DECK.
*CALL     COMKMAC

 WAIT  SPACE  4,25
***       WAIT - TASK WAIT REQUEST.
*
*         *WAIT* ALLOWS A TASK TO SUSPEND PROCESSING FOR THE AMOUNT
*         OF TIME SPECIFIED IN THE PARAMETER. THE MAXIMUM LENGTH OF
*         TIME A TASK CAN BE SUSPENDED IS 3600 SECONDS (1 HOUR).
*         IF NO PARAMETER IS SPECIFIED OR THE TIME IS GREATER THAN
*         1 HOUR OR LESS THAN ZERO, TASK WILL BE ABORTED.
*
*         CALL FORMAT -
*
*         FORTRAN -
*
*         CALL WAIT(VALUE)      WHERE VALUE IS REAL NUMBER.
*
*         COBOL -
*
*         ENTER WAIT USING VALUE.
*
*         WHERE VALUE IS COMPUTATIONAL-1.


 MAXW     EQU    3600        MAXIMUM TIME IN SECONDS FOR *WAIT*
          SPACE  4,10
**        WAIT - TASK WAIT REQUEST.
*
*         ENTRY  (A1)/(X1) = PARAMETER LIST.
*
*         USES   A - 2, 6.
*                X - 1, 2, 6.
*
*         MACROS WAIT.


          VFD    42/0LWAIT,18/WAIT

 WAIT     SUBR               ENTRY/EXIT
          ZR     X1,WAIT1    IF NO PARAMETER SPECIFIED
          SA2    X1+         GET PARAMETER WORD
          UX2,B3
          LX2    X2,B3
          SX1    MAXW        MAXIMUM VALUE
          NG     X2,WAIT1    IF TIME IS NEGATIVE
          IX1    X1-X2
          SX6    X2
          NG     X1,WAIT1    IF TIME IS GREATER THAN 1 HOUR
          SA6    WAIA        SAVE PARAMETER
          WAIT   WAIA
          EQ     WAITX       RETURN

*         ABORT TASK.

 WAIT1    ARGERR A1          ABORT TASK

 WAIA     BSSZ   1           WAIT TIME IN SECONDS
          END