IDENT  WAITINP 

          ENTRY  WAITINP
          TITLE  WAITINP - WAIT FOR TERMINAL INPUT.
*COMMENT  WAITINP - WAIT FOR TERMINAL INPUT.
          COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992.
          SPACE  4
***       WAITINP - REQUEST WAIT FOR TERMINAL INPUT.
*         F. R. SUTTON/J.R. HOGUE.  74/05/01.
          SPACE  4
*CALL     COMKMAC
*CALL     COMSPRD
          TRXCOM
          SPACE  4
***       CALL FORMAT -
*
*         FORTRAN EXTENDED
*                CALL WAITINP(STAT,TIME)
*         COBOL
*                ENTER WAITINP USING TIME STAT
*
*         WHERE - STAT = STATUS AFTER REQUEST
*                        < 0 IF ANOTHER TASK IS ALREADY WAITING FOR
*                            INPUT FROM THE DESIRED TERMINAL.
*                        = 0 IF REQUEST PROCESSED OK.
*                        > 0 IF THE REQUEST TIMED OUT WITH NO INPUT
*                            RECEIVED.
*                 TIME = TIME IN SECONDS BEFORE FORCED RESTART IF NO
*                        INPUT RECEIVED FROM THE TERMINAL. (OPTIONAL)


 WAITINP  PS                 ENTRY/EXIT
          SB2    X1          STATUS ADDRESS
          SA5    A1+1
          BX7    X7-X7
          ZR     X5,WAI1     IF NO TIME GIVEN
          SA5    X5
          BX7    X5
 WAI1     SA7    WAIA        STORE TIME OUT VALUE
          WAITINP WAIA       REQUEST WAIT FOR TERMINAL INPUT
          SA6    B2          STORE STATUS AFTER REQUEST
          NG     X6,WAITINP  IF TERMINAL ALREADY IN *WAITINP* STATE
          BX6    X6-X6
          SX2    1
          SA1    MSGC        FIRST WORD OF TERMINAL DATA
          BX3    X2-X1
          SA6    B2          SET STATUS WORD TO ZERO
          NZ     X3,WAITINP  IF TERMINAL INPUT RECEIVED
          BX6    X2
          SA6    B2          SET STATUS NON ZERO
          JP     WAITINP     RETURN

 WAIA     BSS    1

          END