MACRO                                                          SYS00010
         SYSIPL &SYSTYPE=                                               SYS00020
         GBLC  &SY$IPL        SYSIPL INVOKED INDICATOR                  SYS00030
         LCLC  &A,&START      START TYPE FIELD                          SYS00040
.*                                                                      SYS00050
.*--------------------------------------------------------------------- SYS00060
.* MAKE SURE THAT THE SYSIPL MACRO IS ONLY INVOKED ONCE.                SYS00070
.*--------------------------------------------------------------------- SYS00080
.*                                                                      SYS00090
         AIF   ('&SY$IPL' EQ 'HERE').DUP                                SYS00100
&SY$IPL  SETC  'HERE'         INDICATE SYSIPL INVOKED                   SYS00110
.*                                                                      SYS00120
.*--------------------------------------------------------------------- SYS00130
.* MAKE SURE THAT NO POSITIONAL PARAMETERS ARE SPECIFIED.               SYS00140
.*--------------------------------------------------------------------- SYS00150
.*                                                                      SYS00160
         AIF   (N'&SYSLIST NE 0).POSI                                   SYS00170
.*                                                                      SYS00180
.*--------------------------------------------------------------------- SYS00190
.* IF NO PARAMETERS THEN SET DEFAULT.                                   SYS00200
.*--------------------------------------------------------------------- SYS00210
.*                                                                      SYS00220
         AIF   (N'&SYSTYPE EQ 0).DONE                                   SYS00230
         AIF   ('&SYSTYPE' EQ '').NULL                                  SYS00240
.*                                                                      SYS00250
.*--------------------------------------------------------------------- SYS00260
.* IF MULTIPLE PARAMETERS THEN INDICATE INVALID.                        SYS00270
.*--------------------------------------------------------------------- SYS00280
.*                                                                      SYS00290
         AIF   (N'&SYSTYPE GT 1).MULTI                                  SYS00300
.*                                                                      SYS00310
.*--------------------------------------------------------------------- SYS00320
.* IF PARAMETER IS 'WARM' THEN SET WARM AND GO TO DONE.                 SYS00330
.*--------------------------------------------------------------------- SYS00340
.*                                                                      SYS00350
&START   SETC  'CPWARM'                                                 SYS00360
         AIF   ('&SYSTYPE' EQ 'WARM').DONE                              SYS00370
.*                                                                      SYS00380
.*--------------------------------------------------------------------- SYS00390
.* IF PARAMETER IS 'CKPT' THEN SET CKPT AND GO TO DONE.                 SYS00400
.*--------------------------------------------------------------------- SYS00410
.*                                                                      SYS00420
&START   SETC  'CPCKPT'                                                 SYS00430
         AIF   ('&SYSTYPE' EQ 'CKPT').DONE                              SYS00440
.*                                                                      SYS00450
.*--------------------------------------------------------------------- SYS00460
.* IF PARAMETER IS 'FORCE' THEN SET FORCE AND GO TO DONE.               SYS00470
.*--------------------------------------------------------------------- SYS00480
.*                                                                      SYS00490
&START   SETC  'CPFORCE'                                                SYS00500
         AIF   ('&SYSTYPE' EQ 'FORCE').DONE                             SYS00510
.*                                                                      SYS00520
.*--------------------------------------------------------------------- SYS00530
.* IF PARAMETER IS 'COLD' THEN SET COLD AND GO TO DONE.                 SYS00540
.*--------------------------------------------------------------------- SYS00550
.*                                                                      SYS00560
&START   SETC  'CPCOLD'                                                 SYS00570
         AIF   ('&SYSTYPE' EQ 'COLD').DONE                              SYS00580
.*                                                                      SYS00590
.*--------------------------------------------------------------------- SYS00600
.* ISSUE INVALID PARAMETER MNOTE AND GO SET DEFAULT.                    SYS00610
.*--------------------------------------------------------------------- SYS00620
.*                                                                      SYS00630
.INVALID ANOP                                                           SYS00640
         MNOTE 12,'INVALID PARAMETER ''&SYSTYPE'', AUTO RE-IPL WILL NOT*SYS00650
                BE PERFORMED'                                           SYS00660
         AGO   .DONE                                                    SYS00670
.*                                                                      SYS00680
.*--------------------------------------------------------------------- SYS00690
.* ISSUE INVALID MACRO FORMAT MNOTE AND GO SET DEFAULT.                 SYS00700
.*--------------------------------------------------------------------- SYS00710
.*                                                                      SYS00720
.POSI    ANOP                                                           SYS00730
         MNOTE 8,'ERROR; INVALID MACRO FORMAT.'                         SYS00740
         AGO   .DONE                                                    SYS00750
.*                                                                      SYS00760
.*--------------------------------------------------------------------- SYS00770
.* ISSUE DUPLICATE SPECIFICATION MNOTE AND EXIT.                        SYS00780
.*--------------------------------------------------------------------- SYS00790
.*                                                                      SYS00800
.DUP     ANOP                                                           SYS00810
         MNOTE 8,'ERROR; SYSIPL MACRO SPECIFIED MORE THAN ONCE.'        SYS00820
.*                                                                      SYS00830
         MEXIT                                                          SYS00840
.*                                                                      SYS00850
.*--------------------------------------------------------------------- SYS00860
.* ISSUE NULL PARAMETER MNOTE AND GO SET DEFAULT.                       SYS00870
.*--------------------------------------------------------------------- SYS00880
.*                                                                      SYS00890
.NULL    ANOP                                                           SYS00900
         MNOTE 12,'MISSING PARAMETER, AUTO RE-IPL WILL NOT BE PERFORMED*SYS00910
               .'                                                       SYS00920
         AGO   .DONE                                                    SYS00930
.*                                                                      SYS00940
.*--------------------------------------------------------------------- SYS00950
.* ISSUE MULTIPLE PARAMETER MNOTE AND SET DEFAULT.                      SYS00960
.*--------------------------------------------------------------------- SYS00970
.*                                                                      SYS00980
.MULTI   ANOP                                                           SYS00990
         MNOTE 12,'MORE THAN ONE PARAMETER WAS SPECIFIED, AUTO RE-IPL W*SYS01000
               ILL NOT BE PERFORMED.'                                   SYS01010
.*                                                                      SYS01020
.*--------------------------------------------------------------------- SYS01030
.* DEFINE BYTE DMKSYSIP AND SET THE START TYPE. EXIT.                   SYS01040
.*--------------------------------------------------------------------- SYS01050
.*                                                                      SYS01060
.DONE    ANOP                                                           SYS01070
         ENTRY DMKSYSIP                                                 SYS01080
.*                                                                      SYS01090
         AIF   (K'&START EQ 0).NOSTART                                  SYS01100
DMKSYSIP DC    AL1(&START)                                              SYS01110
.*                                                                      SYS01120
         MEXIT                                                          SYS01130
.*                                                                      SYS01140
.NOSTART ANOP                                                           SYS01150
.*                                                                      SYS01160
DMKSYSIP DC    AL1(0)                                                   SYS01170
.*                                                                      SYS01180
         MEND                                                           SYS01190