CMPIENT 
* /---   FILE TYPE = E
* /---   BLOCK      CMPIENT    00 000   82/01/10  14.08 
          IDENT  CMPIENT
 CMPIENT  TITLE  CMPIENT - CENTRAL MICRO PLATO ENTRY. 
*COMMENT  CMP ENTRY.
***       CMPIENT - CENTRAL MICRO PLATO ENTRY.
* 
*         THE MICRO PLATO PORTION OF THE FILE THAT WAS JUST 
*         CONDENSED IS TRANSLATED INTO AN EQUIVALENT TUTOR
*         LESSON IN FILE *S0CMPN* WHERE N = THE CONDENSOR ORDINAL.
* 
*         THE CENTRAL MICRO PLATO OVERLAY IS WRITTEN IN 
*         CYBIL.  IT IS ENTERED AT THE STANDARD CYBIL MAIN
*         PROGRAM ENTRY POINT *SW=MAIN*.  WHEN FINISHED,
*         THE OVERLAY RETURNS CONTROL TO *MPP$END* HERE 
*         WITH THE (X1) = TERMINATION CONDITION.
* 
*         CYBIL USES THE COMMON MEMORY MANAGER (CMM).  FOR
*         COMPATIBILITY WITH CMM, THE DYNAMIC AREA BASE 
*         ADDRESS (DABA) AND HIGHEST HIGH ADDRESS (HHA) ARE 
*         SET TO THE CONDENSORS RUNNING FL BEFORE THE CMP 
*         OVERLAY IS ENTERED, AND CMM IS DEACTIVATED WHEN 
*         THE OVERLAY IS EXITED.  SEE THE CMM REFERENCE 
*         MANUAL, 60499200, FOR DETAILS.
* 
*         THE CM FOR THE CYBIL CODE*S STACK AND HEAP AREAS
*         ARE ALLOCATED DYNAMICALLY.  UPON RETURN FROM THE
*         CYBIL PROGRAM, THE FL IS RESET TO ITS NORMAL VALUE. 
  
          LCC    OVERLAY(1,0,O=OVERLAY) 
          CST 
          SYSCOM  B1
  
* /---   BLOCK      CMPIENT    00 000   82/10/27  14.55 
**        CONSTANTS.
  
 DABA     EQU    LWPR        CMM DABA LOCATION
          ENTRY  CMPIF
 CMPIF    BSS    2           INPUT FILE NAME
  
          ENTRY  CMPBS
 CMPBS    BSS    1           SPACE RAMAINING IN CURRENT BLK 
          ENTRY  CMPBN
 CMPBN    BSS    1           CURRENT BLOCK NUMBER 
          ENTRY  CMPSB
 CMPSB    BSS    1           EM FWA OF SOURCE BLOCK 
          ENTRY  CMPFD
 CMPFD    BSS    1           EM FWA OF FILE DIRECTORY 
          ENTRY  CMPNB
 CMPNB    BSS    1           NUMBER OF BLOCKS IN FILE 
  
*         ENTER THE CMP OVERLAY.
  
 CMPIENT  LEVEL  CMPOV10
          SB1    1           (B1) = CONSTANT 1
  
*         INCREMENT THE USAGE COUNT.
  
          SA1    ACLSTAT
          SX0    SCCMP
          IX0    X0+X1       (X0) = STATS WORD EM FWA 
          RX1    X0 
          SX6    X1+B1
          WX6    X0 
  
*         SET THE (DABA) TO THE RUNNING FL. 
  
          SA1    CMFL        (X1) = CONDENSOR RUNNING FL
          LX1    30 
          SA2    DABA 
          MX0    -18
          BX6    X0*X2
          BX1    -X0*X1 
          BX6    X6+X1
          SA6    A2 
  
*         SET THE (HHA) TO THE RUNNING FL.
  
          SA2    HHA
          BX6    X0*X2
          BX6    X1+X6
          SA6    A2 
  
          EQ     =XSW=MAIN   ENTER MAIN CYBIL PROGRAM 
  
          ENTRY  MPP$END
  
 MPP$END  BX5    X1          SAVE TERMINATION CODE
          RJ     =XCMM.KIL   DEACTIVATE THE COMMON MEMORY MANAGER 
          CALL   S=CM,CMFL   RESET TO NORMAL FL 
          EQ     =XCMPGOX    RETURN 
  
          SUBOV  CMP11       DUMMY (1,1) SUBOVERLAY INOFRMATION WORD
  
          END