*DECK     CSESIM
USETEXT TEXTCS
USETEXT TEXTSS
USETEXT TXTAPSS 
      PROC CSESIM;
# TITLE - SEND IDLING-DOWN MESSAGE.                                    #
      BEGIN 
# 
**    CSESIM - SEND IDLING-DOWN MESSAGE.
* 
*     D.K. ENDO    82/03/18 
* 
*     THIS PROCEDURE SENDS A MESSAGE REQUEST ALL THE CONNECTED OPERATORS
*     TO TERMINATE THEIR CONNECTION.
* 
*     PROC CSESIM 
* 
*     ENTRY        1. SHUT/INSD SM
* 
*     EXIT         1. ENTRY IN OPERATOR RESPONSE QUEUE WITH AN AUDIENCE 
*                       GROUP OF ONE(HOP AND ALL NOP-S).
* 
# 
# 
****  PROC CSESIM - XREF LIST BEGINS. 
# 
      XREF
        BEGIN 
        PROC SSTAQE;         # ADD QUEUE ENTRY                         #
        END 
# 
****
# 
      DEF TRM$TXTL # 50 #;   # CHAR COUNT OF -PLEASE TERMINATE- TEXT   #
# 
      THIS ARRAY DEFINES THE -PLEASE TERMINATE CONNECTION- MESSAGE THAT 
      IS SENT TO ALL OPERATOR WHEN THIS PROC IS INVOKED.
# 
      ARRAY TRM$TXT [00:00] S(5); 
        BEGIN 
        ITEM TRM$MSG    C(00,00,47) = 
         ["CS SHUTDOWN INITIATED, PLEASE TERMINATE CONNECT"]; 
        ITEM TRM$ZBYT   U(04,42,18) = [ 0 ];
        END 
      CONTROL EJECT;
#                                                                      #
#                            CSESIM CODE BEGINS HERE                   #
#                                                                      #
# 
*     SEND A -PLEASE TERMINATE- MESSAGE THE OPERATOR RESPONSE QUEUE WITH
*     THE AUDIENCE GROUP SET TO ONE(HOP AND ALL NOP-S). 
# 
      WCB$WORD[1] = 0;
      WCB$WC[1] = 2 + (TRM$TXTL / 10);
      ABHWORD[1] = TRM$TXTL;
      ABHADR[1] = AUDGR1$;
      SSTAQE(P<ORQ>,WCBUF[1],ABH[1],TRM$TXT[0]);
      RETURN;                # **** RETURN ****                        #
      END # CSESIM #
      TERM