*DECK IPISPHO 
USETEXT TEXTIPL 
      PROC IPISPHO; 
*CALL COPYRITE          CDCNET - COPYRIGHT CONTROL DATA. 1992.
# TITLE IPISPHO - PROCESS HOST OPERATOR REQUEST SUPERVISORY MESSAGE.   #
 
      BEGIN                            # IPISPHO                       #
# 
****  IPISPHO  PROCESS HOST OPERATOR REQUEST SUPERVISORY MESSAGE
* 
*     THIS PROCEDURE PROCESSES A HOP SUPERVISORY MESSAGE.  THE
*     SUPPORTED OPTIONS ARE DEBUG AND TRACE.
* 
*     PROC IPISPHO
* 
*     ENTRY    P<APSM> = PTR TO SUPERVISORY MESSAGE (*INPBUF*). 
* 
*     EXIT     DFLAG   = TRUE OR FALSE IF DEBUG MODE CHANGE.
* 
*     METHOD   IF THE HOP REQUEST IS DEBUG ON OR OFF, *DFLAG* IS
*              UPDATED TO THE CORRECT VALUE.  IF THE HOP REQUEST
*              IS FOR TRACE, TURN DATA AND SUPERVISORY TRACING ON 
*              OR OFF *NETDBG* IS CALLED TO MAKE ANY CHANGES TO 
*              BOTH DATA AND SUPERVISORY MESSAGE TRACING.  IF THE 
*              HOP REQUEST IS TO RELEASE THE DEBUG LOG FILE, CALL 
*              *NETREL* TO RELEASE IT.
# 
 
# 
****  PROC IPISPHO - XREF LIST
# 
      XREF
        BEGIN 
        PROC NETDBG;     # TURN ON DEBUG LOGGING                       #
        PROC NETREL;     # RELEASE DEBUG LOG FILE                      #
        END 
# 
**
# 
 
      ITEM RSTAT         I;            # RETURN STATUS                 #
      ITEM SMSFC         U;            # SECONDARY FUNCTION CODE       #
 
      ARRAY NDLF2 [00:00] S(1); 
        BEGIN 
        ITEM NDL$NAM    C(00,00,04) = ["NRF2"]; 
        ITEM NDL$ZFIL   U(00,24,36) = [0];
        END 
      CONTROL EJECT;
 
# 
****  START MAIN PROCEDURE
# 
 
      SMSFC = SFC [0];
 
      IF SMSFC EQ DB
      THEN
        BEGIN                          # DEBUG ON                      #
        DFLAG = TRUE; 
        END                            # DEBUG ON                      #
 
      ELSE IF SMSFC EQ DE 
      THEN
        BEGIN                          # DEBUG OFF                     #
        DFLAG = FALSE;
        END                            # DEBUG OFF                     #
 
      ELSE IF SMSFC EQ TRACE
      THEN
        BEGIN                          # TRACE ON                      #
        NETDBG (FALSE, FALSE, RSTAT); 
        END                            # TRACE ON                      #
 
      ELSE IF SMSFC EQ NOTR 
      THEN
        BEGIN                          # TRACE OFF                     #
        NETDBG (TRUE, TRUE, RSTAT); 
        END                            # TRACE OFF                     #
 
      ELSE IF SMSFC EQ REL
      THEN
        BEGIN                          # RELEASE DEBUF LOG FILE        #
        IF (IPMC NQ 0)
        THEN
          NETREL (NDLF2, 0, 0);        # RELEASE *ZZZZZDN* FILE        #
        END                            # RELEASE DEBUG LOG FILE        #
 
      END                              # IPISPHO                       #
 
      TERM