*DECK KDISRC
USETEXT NIPDEF
USETEXT KDIS
USETEXT KINITBF 
USETEXT PARAMS
 
 PRGM KDISRC;                # ISSUE K DISPLAY ERROR DIAGNOSTIC        #
 
 STARTIMS;
 STOPIMS; 
# 
      EXTERNAL REFERENCES 
# 
      XREF
        BEGIN 
        PROC XTRACE;         # TRACE ROUTINE CALL                      #
        LABEL RJMAIN; 
        END 
# 
      LOCAL DEFINITIONS 
# 
      DEF MAX$KERR # 12 #;   # MAXIMUM K DISPLAY ERROR DIAGNOSTCS      #
# 
      LOCAL VARIABLES 
# 
      ARRAY KERR$MSG [1:MAX$KERR] S(KERRL); 
        BEGIN 
        ITEM KERR$TEXT C(00,00,48) = [ # ERROR TEXT                    #
            "NO APPLICATION ALERT PENDING",                # 1 #
            "APPLICATION NOT SUPPORTING NAM K DISPLAY",    # 2 #
            "APPLICATION UNKNOWN",                         # 3 #
            "UNRECOGNIZED COMMAND",                        # 4 #
            "APPLICATION NAME MUST BE SPECIFIED",          # 5 #
            "ALLOW FL AND DU COMMAND ONLY",                # 6 #
            "ILLEGAL FL VALUE",                            # 7 #
            "ILLEGAL DESTINATION NODE NUMBER",             # 8 #
            "DESTINATION HOST IN BUFFER REGULATION 0",     # 9 #
            "NO H-H LOGICAL LINK TO DESTINATION",          # 10#
            "PIP TRACE OPTION NOT AVAILABLE",              # 11#
            "UNKNOWN HOST NODE",                           # 12#
                                     ]; 
        ITEM KERR$TEND U(04,48,12) = [0]; 
        END 
 
      CONTROL EJECT;
 
      BEGIN # KDISRC #
 
      CONTROL IFEQ DEBUG,1; 
      XTRACE("KDSRC");       # TRACE CALL                              #
      CONTROL FI; 
 
      P<KINITBF> = KDBP[0]+BLKHSIZE+KHDRSIZE; 
      KERROR[KLSIZE-KERRL-2] = KERR$TEXT[PARAMS1];
      KREADY[KLSIZE-2] = "READY.."; 
 
      GOTO RJMAIN;
      END # KDISRC #
      TERM