Table of Contents

OCFL

Table Of Contents

  • [00007] OCFL CHANGE FIELD LENGTH

Source Code

OCFL.txt 
  1. *DECK     OCFL
  2.           IDENT  OCFL 
  3.           ENTRY  OCFL 
  4.           EXT    OTIME
  5.           EXT    XTRACE 
  6.           SST 
  7.           TITLE  OCFL    CHANGE FIELD LENGTH
  8. *IF DEF,IMS 
  9. *#
  10. *1DC  OCFL
  11. * 
  12. *     1. PROC NAME           AUTHOR              DATE 
  13. *        OCFL                J. J. LYON          75/04/02 
  14. * 
  15. *     2. FUNCTIONAL DESCRIPTION.
  16. *        THIS ROUTINE IS RESPONSIBLE FOR CHANGING NIP-S FIELD LENGTH. 
  17. * 
  18. *     3. METHOD USED. 
  19. *          SET UP CALL
  20. *          CALL MTR 
  21. * 
  22. *     4. ENTRY PARAMETERS.
  23. *          A1 = ADDR OF NEW FIELD LENGTH
  24. * 
  25. *     5. EXIT PARAMETERS.  NONE 
  26. * 
  27. *     6. COMDECKS CALLED. 
  28. *          INPARU  MACDEF 
  29. *          STATTAB
  30. * 
  31. *     7. ROUTINES CALLED. 
  32. *          MEMORY            COMPASS MEMORY MACRO 
  33. *          OTIME             GET SYSTEM RTIME 
  34. *          XTRACE            TRACES CALLS 
  35. * 
  36. *     8. DAYFILE MESSAGES.  NONE
  37. * 
  38. *#
  39. *ENDIF
  40. *CALL MACDEF
  41. *CALL INPARU
  42. *CALL STATTAB 
  43.  COUNT    BSSZ   1
  44.  SAVEA1   BSSZ   1
  45.  MEMRW    BSSZ   1           MEM MACRO REPLY WORD 
  46.  OCFL     BSSZ   1           ENTRY/EXIT 
  47.  
  48.  DEBUG1   IFEQ   DEBUG,1
  49.           SX6    A1 
  50.           SA6    TEMP 
  51.  
  52.  STAT1    IFEQ   STAT,1 
  53.           SA1    STIMEP      PARAMETER BLOCK FOR CALLING OTIME
  54.           RJ   OTIME         GET RTIME VALUE BEFORE CALL
  55.  STAT1    ENDIF 
  56.  
  57.           SX1    XOCFL
  58.           RJ     XTRACE 
  59.           SA1    TEMP 
  60.           SA1    X1 
  61.  DEBUG1   ELSE
  62.  
  63.  STAT1    IFEQ   STAT,1 
  64.           SX6    A1          SAVE ADDRESS OF PARAMETER BLOCK IN TEMP
  65.           SA6    TEMP 
  66.           SA1    STIMEP      PARAMETER BLOCK FOR CALLING OTIME
  67.           RJ   OTIME         GET RTIME VALUE BEFORE CALL
  68.           SA1    TEMP        RESTORE ADDRESS OF PARAMETER BLOCK IN A1 
  69.           SA1    X1 
  70.  STAT1    ENDIF 
  71.  
  72.  DEBUG1   ENDIF 
  73. * 
  74. * 
  75.           SA3    A1          A3 = FWA OF PARAM LIST 
  76.           SA2    X3          A2 = ADDR OF PARAM 1 
  77.           SX7    X2          X2 = PARAM 1   NEW FIELD LENGTH
  78. * 
  79. *                   CALL MTR
  80. * 
  81.           LX7    30 
  82.           SA7    MEMRW       REPLY WORD SET UP
  83.           MEMORY CM,MEMRW,RECALL
  84.  
  85.  STAT2    IFEQ   STAT,1 
  86.           SA1    ETIMEP      PARAMETER BLOCK FOR CALLING OTIME
  87.           RJ   OTIME         GET RTIME VALUE AFTER CALL 
  88.           SA1    STIME       STARTING RTIME VALUE 
  89.           MX0    24D         MASK FOR RTIME MILLESECOND VALUE 
  90.           BX1    -X0*X1      CLEAR SECONDS FIELD
  91.           SA2    ETIME       ENDING RTIME VALUE 
  92.           BX2    -X0*X2      CLEAR SECONDS FIELD
  93.           IX6    X2-X1       ELAPSED TIME FOR SWAPIN
  94.           SA1    ST$LFL      LARGEST TIME SPENT IN OCFL 
  95.           IX5    X1-X6       DETERMINE IF LATEST TIME INTERVAL IS LARGER
  96.           PL   X5,OCFL1      IF PREVIOUS TIME INTERVAL WAS LARGER 
  97.           SA6    ST$LFL      SAVE NEW LARGEST TIME INTERVAL 
  98.  OCFL1    SA3    ST$TFL      PREVIOUS CUMULATIVE VALUE
  99.           IX6    X3+X6       NEW CUMULATIVE VALUE 
  100.           SA6    ST$TFL 
  101.  STAT2    ENDIF 
  102.  
  103.           JP     OCFL        EXIT 
  104.  XOCFL    DATA   L* OCFL* 
  105.  TEMP     BSS    1
  106.  
  107.  STAT3    IFEQ   STAT,1 
  108.           EXT    OTIME
  109.  STIMEP   VFD    60D/STIME
  110.  ETIMEP   VFD    60D/ETIME
  111.  STIME    BSS    1           START TIME FOR COMPARING SWAPIN TIME DELAY 
  112.  ETIME    BSS    1           END TIME FOR COMPARING SWAPIN TIME DELAY 
  113.  STAT3    ENDIF 
  114.  
  115.           END