Table of Contents

PURGREG

Table Of Contents

Source Code

PURGREG.txt 
  1. *DECK PURGREG 
  2.           IDENT  PURGREG
  3.           ENTRY  PURGREG
  4. *#
  5. *1DC  PURGREG 
  6. * 
  7. *     1. PROC NAME           AUTHOR              DATE 
  8. *        PURGREG             R. M. FARRELL       88/07/29 
  9. * 
  10. *     2. FUNCTIONAL DESCRIPTION.
  11. *        THIS ROUTINE IS CALLED WHEN IT IS NECESSARY TO FORCE A CENTRAL 
  12. *        MEMORY READ WHERE THE SYMPL COMPILER'S OPTIMIZER MAY HAVE
  13. *        OTHERWISE SUPPRESSED THE GENERATION OF ONE.  IT IS USED WHERE
  14. *        THE LOCATION BEING REFERENCED MAY HAVE BEEN UPDATED BY A PP. 
  15. * 
  16. *     3. METHOD USED. 
  17. *        THE PRESENCE OF A SUBROUTINE CALL CAUSES THE SYMPL COMPILER
  18. *        TO CONSIDER ALL REGISTER CONTENTS INVALIDATED. 
  19. *        THE CALLERS RETURN JUMP TO THIS ROUTINE IS REPLACED WITH 
  20. *        PASS INSTRUCTIONS WHEN IT IS FIRST CALLED AS THE ROUTINE 
  21. *        PERFORMS NO FUNCTION AT EXECUTION TIME.
  22. * 
  23. *     4. ENTRY PARAMETERS.  NONE. 
  24. * 
  25. *     5. EXIT PARAMETERS.   NONE. 
  26. * 
  27. *     6. COMDECKS CALLED.   NONE. 
  28. * 
  29. *     7. ROUTINES CALLED.   NONE. 
  30. * 
  31. *     8. DAYFILE MESSAGES.  NONE. 
  32. * 
  33. *#
  34.  PURGREG  EQ     *+1S17 
  35.           SA1    PURGREG     READ RETURN ADDRESS STORED BY *RJ* 
  36.           AX1    47-17       RETURN ADDRESS TO LOW ORDER 18 BITS
  37.           SX2    X1-1        ADDRESS OF WORD CONTAINING *RJ*
  38.           SA3    NOOP        READ PASS INSTRUCTION WORD 
  39.           BX6    X3          MOVE TO STORE REGISTER 
  40.           SA6    X2          REPLACE *RJ* WITH PASS 
  41.           EQ     PURGREG
  42.  
  43.  NOOP     SB0    B0+46000B   UPPER 30 BITS OF PASS WORD 
  44.           SB0    B0+46000B   LOWER 30 BITS OF PASS WORD 
  45.           END