Table of Contents

QTCLOSE

Table Of Contents

  • [00005] PROC QTCLOSE
  • [00058] PROC NETCHEK
  • [00059] PROC NETFUNC
  • [00060] PROC NETOFF

Source Code

QTCLOSE.txt 
  1. *DECK QTCLOSE 
  2. USETEXT AIPDEF
  3. USETEXT QTRMCOM 
  4. USETEXT QTRMNIT 
  5. PROC QTCLOSE; 
  6. *IF DEF,IMS 
  7.  #
  8. *1DC  QTCLOSE 
  9. * 
  10. *     1. PROC NAME           AUTHOR              DATE 
  11. *        QTCLOSE             J.C. LEE            79/01/12 
  12. * 
  13. *     2. FUNCTIONAL DESCRIPTION 
  14. *        TERMINATE ACCESS TO THE NETWORK
  15. * 
  16. *     3. METHOD USED
  17. *        SET ALL CONNECTION ENTRIES IN NIT TO NULL STATE, 
  18. *        TRANSFER LAST WORKLIST, IF IT EXISTS, BY ISSUING FORCED NETWAIT
  19. *        CALL AIP PROCEDURE NETOFF TO TERMINATE NETWORK ACCESS
  20. * 
  21. *     4. ENTRY CONDITIONS 
  22. *        NONE 
  23. * 
  24. *     5. EXIT CONDITIONS
  25. *        ALL CONNECTIONS IN -NULL- STATE, 
  26. *        NETON$STATUS IS SET TO FALSE.
  27. * 
  28. *     6. COMDECKS CALLED AND SYMPL TEXTS USED.
  29. *        AIPDEF    NP$CRT    QTRMCOM   QTRMNIT
  30. * 
  31. *     7. ROUTINES CALLED
  32. *        NETCHEK - AIP PROCEDURE TO FLUSH AIP WORKLIST, IF ANY
  33. *        NETFUNC - AIP PROCEDURE TO CHANGE NORMAL PROCESSING PROCEDURES 
  34. *        NETOFF - AIP PROCEDURE TO TERMINATE NETWORK ACCESS 
  35. * 
  36. *     8. DAYFILE MESSAGES 
  37. *        NONE 
  38. * 
  39.  #
  40. *ENDIF
  41.  
  42. # 
  43.       CONTROL DEFINITIONS 
  44. # 
  45.       CONTROL PRESET; 
  46.       CONTROL PACK; 
  47.       CONTROL DISJOINT; 
  48.       CONTROL INERT;
  49.       CONTROL FASTLOOP; 
  50.  
  51. *CALL NP$CRT
  52.  
  53. # 
  54.       ROUTINES CALLED 
  55. # 
  56.     XREF
  57.       BEGIN 
  58.       PROC NETCHEK;                     # FLUSH AIP WORKLIST, IF ANY   #
  59.       PROC NETFUNC;                     # CHANGE NORMAL PROCESSING     #
  60.       PROC NETOFF;                      # TERMINATE NETWORK ACCESS     #
  61.       END 
  62. # 
  63.       LOCAL VARIABLES 
  64. # 
  65.       ITEM M I;                         # TEMPORARY VARIABLE           #
  66.       CONTROL EJECT;
  67. # 
  68.       BEGIN QTCLOSE PROCESSING
  69. # 
  70.    BEGIN
  71.  
  72.       P<NIT> = NIT$ADDR;
  73.       FOR M=1 STEP 1 UNTIL NIT$NO$TERMS[0] DO 
  74.         BEGIN 
  75.         NIT$STATE[M] = S"NULL";         # SET ALL CONNECTIONS TO -NULL-#
  76.         END 
  77.       NETON$STATUS = FALSE;             # SET APP NOT NETTED-ON        #
  78.  
  79.                                         # FORCED NETWAIT TO TRANSFER   #
  80.       NETFUNC(3,0);                     # TELL AIP TO NOT ABORT APP IF #
  81.                                         # NAM IS NO LONGER AVAILABLE   #
  82.       NETCHEK;
  83.       NETOFF;                           # TERMINATE NETWORK ACCESS     #
  84.  
  85.       RETURN; 
  86.    END # QTCLOSE #
  87. TERM