*DECK     SSTRCM
          IDENT  SSTRCM 
          ENTRY  SSTRCM 
          TITLE SSTRCM - REQUEST CENTRAL MEMORY.
*COMMENT  REQUEST CENTRAL MEMORY. 
 SSTRCM   SPACE  4,10 
***       SSTRCM - REQUEST CENTRAL MEMORY.
* 
*         S. H. FISCHER.     82/05/10.
          SPACE  4,10 
***       SSTRCM WILL ADJUST OR RETURN THE PROGRAMS CENTRAL MEMORY
*         FIELD LENGTH. THE REQUEST FOR ADDITIONAL CM 
*         CAN BE WITH OR WITHOUT RECALL SO AN INCREASE IN CM
*         CAN BE MADE AND THE PROGRAM CONTINUE WITH OTHER WORK
*         UNTIL THE MEMORY IS AVAILABLE.
          SPACE  4,10 
***       SYMPL CALLING SEQUENCE. 
* 
*         SSTRCM( M, RECALL, STAT );
* 
*                M = AMOUNT OF CENTRAL MEMORY TO REQUEST. 
*                RECALL = RECALL STATUS, IF ZERO
*                  *STAT* MUST BE CHECKED FOR COMPLETION. 
*                STAT = ADDRESS TO USE IN MAKING MEMORY REQUEST.
*                  NEW CENTRAL MEMORY FIELD LENGTH IS IN STAT LEFT SHIFT
*                  BY 30 BITS WHEN THE COMPLETE BIT IS SET. 
*                NOTE THIS ROUTINE STORES INTO STAT,
*                  IT CANNOT BE SET UP BY THE CALLER. 
 SSTRCM   SPACE  4,10 
 SSTRCM   EQ     *+1S17D
 EXIT.    EQU    *
          SA2    A1+1        X2 = ADDRESS OF RECALL FLAG
          SA1    X1          X1 = VALUE OF M
          MX4    30 
          SA3    A2+1        X3 = ADDRESS OF STAT WORD
          SX6    X1 
          LX6    30          SETUP REQUEST/STATUS WORD
          SA2    X2          X2 = RECALL FLAG 
          BX6    X4*X6
          SA6    X3 
          NZ     X2,RCM1     IF RECALL REQUESTED
 
          MEMORY CM,A6       REQUEST MEMORY 
          JP     EXIT.
 
 RCM1     MEMORY CM,A6,R     REQUEST MEMORY 
          JP     EXIT.       RETURN 
 
          END