ASCII
*NOSEQ
*WIDTH 132
.PROC,PDU*I,
I  [P^A^N^E^L ^D^E^F^I^N^I^T^I^O^N ^F^I^L^E]=(*F),
L  [L^I^S^T^I^N^G ^F^I^L^E (OUTPUT)]=(*N=OUTPUT,*F),
C  [C^A^P^S^U^L^E ^F^I^L^E (CAPSULE)]=(*N=CAPSULE,*F),
LIB[P^A^N^E^L ^L^I^B^R^A^R^Y ^F^I^L^E (PANELIB)]=(*N=PANELIB,*F),
REC[R^E^C^O^R^D ^N^A^M^E ^O^F ^P^A^N^E^L ^D^E^F^I^N^I^T^I^O^N ^F^I^L^E]=(*N=,*F,*),
RW[R^E^W^I^N^D ^P^A^N^E^L ^D^E^F^I^N^I^T^I^O^N ^F^I^L^E]=(*K=YES,YES,Y=YES,NO,N=NO,*N=YES).
.HELP
C^O^M^P^I^L^E ^A ^P^A^N^E^L ^D^E^F^I^N^I^T^I^O^N.
.HELP,I,NOLIST

   T^H^E ^P^A^N^E^L ^D^E^F^I^N^I^T^I^O^N ^F^I^L^E ^I^S ^A 6/12 ASCII ^T^E^X^T ^F^I^L^E ^W^H^I^C^H ^D^E^F^I^N^E^S ^O^N^E
^O^R ^M^O^R^E ^P^A^N^E^L^S.  M^U^L^T^I^P^L^E ^D^E^F^I^N^I^T^I^O^N^S ^A^R^E ^S^E^P^A^R^A^T^E^D ^B^Y ^A^N ^E^N^D ^O^F ^R^E^C^O^R^D.
F^O^R ^E^X^A^M^P^L^E:

      ^0"P^A^N^E^L ^W^I^T^H ^A ^S^I^N^G^L^E ^V^A^R^I^A^B^L^E" ^V^A^R ^J^U^S^T^O^N^E^2
      T^H^I^S ^I^S ^I^T@D __________

   D^E^F^A^U^L^T@D N^O^N^E - ^Y^O^U ^M^U^S^T ^S^P^E^C^I^F^Y ^A ^F^I^L^E ^N^A^M^E.
.HELP,L,NOLIST

   T^H^E ^L^I^S^T^I^N^G ^F^I^L^E ^I^S ^A ^C^O^P^Y ^O^F ^T^H^E ^P^A^N^E^L ^D^E^F^I^N^I^T^I^O^N ^F^I^L^E ^W^I^T^H ^E^R^R^O^R
^M^E^S^S^A^G^E^S, ^I^F ^A^N^Y, ^I^N^T^E^R^S^P^E^R^S^E^D.

   D^E^F^A^U^L^T@D  OUTPUT
.HELP,C,NOLIST

  T^H^E ^C^A^P^S^U^L^E ^F^I^L^E ^W^I^L^L ^C^O^N^T^A^I^N ^T^H^E ^C^O^M^P^I^L^E^D ^P^A^N^E^L ^I^N CAP ^F^O^R^M^A^T.

  C=0 ^M^E^A^N^S ^C^H^E^C^K ^T^H^E ^P^A^N^E^L ^F^O^R ^E^R^R^O^R^S ^B^U^T ^D^O^N'^T ^G^E^N^E^R^A^T^E ^A ^C^A^P^S^U^L^E.

   D^E^F^A^U^L^T@D CAPSULE
.HELP,LIB,NOLIST

   S^P^E^C^I^F^Y ^N^A^M^E ^O^F ^L^I^B^R^A^R^Y ^F^I^L^E ^T^O ^C^O^N^T^A^I^N ^T^H^E ^P^A^N^E^L ^C^A^P^S^U^L^E.

   LIB=0 ^M^E^A^N^S ^D^O^N'^T LIBEDIT ^A^N^Y ^L^I^B^R^A^R^Y.

   D^E^F^A^U^L^T@D PANELIB
.HELP,REC,NOLIST

   S^P^E^C^I^F^Y ^T^H^E ^S^E^L^E^C^T^E^D ^R^E^C^O^R^D ^N^A^M^E ^T^O ^B^E ^P^R^O^C^E^S^S^E^D ^W^I^T^H^I^N ^T^H^E ^P^A^N^E^L
   ^D^E^F^I^N^I^T^I^O^N ^F^I^L^E.  I^F ^A ^V^A^L^U^E ^I^S ^S^P^E^C^I^F^I^E^D, ^T^H^E ^R^E^C^O^R^D ^T^O ^B^E ^S^E^L^E^C^T^E^D
   ^M^U^S^T ^H^A^V^E ^A^S ^T^H^E ^F^I^R^S^T ^L^I^N^E ^O^F ^T^H^E ^R^E^C^O^R^D ^A^N ^I^D^E^N^T^I^F^I^E^R ^M^A^T^C^H^I^N^G ^T^H^E
   ^S^P^E^C^I^F^I^E^D ^V^A^L^U^E.  F^O^R ^E^X^A^M^P^L^E:

      ONEVAR
      ^0"P^A^N^E^L ^W^I^T^H ^A ^S^I^N^G^L^E ^V^A^R^I^A^B^L^E" ^V^A^R ^J^U^S^T^O^N^E^2
      T^H^I^S ^I^S ^I^T:  __________
      (EOR)
      TWOVARS
      ^0"P^A^N^E^L ^W^I^T^H ^T^W^O ^V^A^R^I^A^B^L^E^S" ^V^A^R ^F^I^R^S^T ^V^A^R ^S^E^C^O^N^D^2
      T^H^E^S^E ^A^R^E ^T^H^E ^V^A^R^I^A^B^L^E^S:  __________  __________

   S^P^E^C^I^F^Y * ^T^O ^P^R^O^C^E^S^S ^A^L^L ^R^E^C^O^R^D^S ^F^R^O^M ^T^H^E ^P^A^N^E^L ^D^E^F^I^N^I^T^I^O^N ^F^I^L^E.

   D^E^F^A^U^L^T:  P^R^O^C^E^S^S ^O^N^E ^P^A^N^E^L ^D^E^F^I^N^I^T^I^O^N ^R^E^C^O^R^D ^R^E^G^A^R^D^L^E^S^S ^O^F ^N^A^M^E.
.HELP,RW,NOLIST

   S^P^E^C^I^F^Y NO ^O^R N ^T^O ^P^R^E^V^E^N^T ^R^E^W^I^N^D ^O^F ^T^H^E ^P^A^N^E^L ^D^E^F^I^N^I^T^I^O^N ^F^I^L^E
   ^A^N^D ^L^I^S^T^I^N^G ^F^I^L^E ^B^E^F^O^R^E ^A^N^D ^A^F^T^E^R ^P^R^O^C^E^S^S^I^N^G.
   S^P^E^C^I^F^Y YES ^O^R Y ^T^O ^R^E^W^I^N^D ^T^H^E ^P^A^N^E^L ^D^E^F^I^N^I^T^I^O^N ^F^I^L^E ^A^N^D ^L^I^S^T^I^N^G
   ^F^I^L^E ^B^E^F^O^R^E ^A^N^D ^A^F^T^E^R ^P^R^O^C^E^S^S^I^N^G.

   D^E^F^A^U^L^T: T^H^E ^P^A^N^E^L ^D^E^F^I^N^I^T^I^O^N ^A^N^D ^L^I^S^T^I^N^G ^F^I^L^E^S ^W^I^L^L ^B^E ^R^E^W^O^U^N^D.
.ENDHELP
 .IF($RW$.NE.$NO$,REWIND)
   .IF($L$.NE.$0$.AND.$L$.NE.$OUTPUT$)REWIND(L)
   REWIND(I)
 .ENDIF(REWIND)
 RENAME(ZZZZSF3=I)
 RETURN(ZZZZSF0,ZZZZSF1,ZZZZSF2,C)
 .IF($REC$.NE.$$.AND.$REC$.NE.$*$,MULTI)
   GTR(ZZZZSF3,I)REC
 .ELSE(MULTI)
   COPYBR(ZZZZSF3,I)
   .IF($REC$.EQ.$*$,MULTI)
     WHILE(.NOT.(FILE(ZZZZSF3,EOF).OR.FILE(ZZZZSF3,EOI)),NEXTREC)
 .ENDIF(MULTI)
 $PANEL(#I=I,#L=ZZZZSF2,#C=ZZZZSF0)
 .IF($L$.NE.$0$)COPYBR(ZZZZSF2,L)
 .IF($C$.NE.$0$,LOAD)
   COMPASS,#I=ZZZZSF0,#L=0,B=ZZZZSF1,S=0.
   LOAD(ZZZZSF1)
   NOGO(C)
 .ENDIF(LOAD)
 RETURN(ZZZZSF0,ZZZZSF1,ZZZZSF2)
 .IF($REC$.EQ.$*$,MULTI)
   COPYBR(ZZZZSF3,I)
   ENDW(NEXTREC)
 .ENDIF(MULTI)
 .IF($C$.NE.$0$.AND.$LIB$.NE.$0$,STORE)
   .IF(.NOT.FILE(LIB,AS),NOTAS)
     $ULIB(#C,C,LIB)
   .ELSE(NOTAS)
     $ULIB(#R,C,LIB)
   .ENDIF(NOTAS)
 .ENDIF(STORE)
 RENAME(I=ZZZZSF3)
 .IF($RW$.NE.$NO$,REWIND)
   .IF($L$.NE.$0$.AND.$L$.NE.$OUTPUT$)REWIND(L)
   REWIND(I)
 .ENDIF(REWIND)
 REVERT,NOLIST.
 EXIT.
 RENAME(I=ZZZZSF3)
 .IF($RW$.NE.$NO$,REWIND)
   .IF($L$.NE.$0$.AND.$L$.NE.$OUTPUT$)REWIND(L)
   REWIND(I)
 .ENDIF(REWIND)
 .IF($L$.NE.$0$)COPYBR(ZZZZSF2,L)
 RETURN(ZZZZSF0,ZZZZSF1,ZZZZSF2)
 REVERT,ABORT.
*WEOR