Table of Contents

PFHELPR

Table Of Contents

  • [00003] PFHELPR - *MAGNET* HELPER FOR TAPE ALTERNATE STORAGE.
  • [00013] *MAGNET* HELPER FOR TAPE ALTERNATE STORAGE.
  • [00045] MAIN PROGRAM.
  • [00094] END - END PROGRAM.
  • [00112] PRESET.
  • [00115] PRS - PRESET.

Source Code

PFHELPR.txt 
  1.           IDENT  PFHELPR,FWA 
  2.           ABS
  3.           TITLE  PFHELPR - *MAGNET* HELPER FOR TAPE ALTERNATE STORAGE.
  4.           SST
  5.           SYSCOM B1
  6.           ENTRY  PFHELPR
  7.           ENTRY  RFL=
  8.           ENTRY  SSJ=
  9.           SPACE  4,10
  10. *COMMENT  PFHELPR - HELPER FOR TAPE ALTERNATE STORAGE.
  11.           COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992.
  12.           SPACE  4,10
  13. ***       PFHELPR - *MAGNET* HELPER FOR TAPE ALTERNATE STORAGE.
  14. *
  15. *         W. C. WELLS.       86/01/27.
  16. *         P. C. SMITH.       87/03/27.
  17.           SPACE  4,10
  18. ***       *PFHELPR* IS CALLED BY *MAGNET* AS PART OF TAPE ALTERNATE
  19. *         STORAGE PROCESSING.  IT COPIES STAGE REQUESTS FROM THE
  20. *         STAGE REQUEST TABLE (WITHIN *MAGNET*) TO THE STAGE REQUEST
  21. *         FILE.  THIS FILE IS THEN READ BY *PFRES*.
  22.           SPACE  4,10
  23. *         SYMBOLIC COMMON DECKS.
  24.  
  25.  
  26. *CALL     COMCMAC
  27. *CALL     COMCCMD
  28. *CALL     COMSMTX
  29. *CALL     COMSSSD
  30. *CALL     COMSPFM
  31.           SPACE  4,10
  32. *         STORAGE ALLOCATION.
  33.  
  34.  
  35.           ORG    110B
  36.  FWA      BSS    0
  37.  
  38.  FBUFL    EQU    2001B
  39.  SSJ=     EQU    0
  40.  
  41.  F        BSS    0           STAGE REQUEST FILE
  42.  STRQ     FILEB  FBUF,FBUFL
  43.  
  44.  RPVB     RPVBLK END         REPRIEVE BLOCK
  45.           TITLE  MAIN PROGRAM.
  46.  PFHELPR  BSS    0           ENTRY
  47.           SB1    1
  48.           RJ     PRS
  49.           EQ     PFH2        SKIP ROLLOUT
  50.  
  51. *         CHECK FOR STAGE REQUESTS.
  52.  
  53.  PFH1     ROLLOUT  PFHC
  54.  PFH2     RJ     GSR         CHECK FOR STAGE REQUESTS
  55.           NG     B6,END      IF CANNOT READ REQUESTS
  56.           NE     B6,B1,PFH1  IF NOT ENOUGH REQUESTS TO ATTACH FILE
  57.  
  58. *         ATTACH FILE TO CLEAN UP *MAGNET*-S REQUEST TABLE.
  59.  
  60.           ATTACH F
  61.           SA1    X2
  62.           MX0    -8
  63.           AX1    10
  64.           BX1    -X0*X1
  65.           NZ     X1,PFH1     IF ERROR IN ATTACH
  66.           SKIPEI F,R
  67.           WRITE  X2,*
  68.           SB2    PFHB        INFORM MAGNET THAT FILE IS ATTACHED
  69.           RJ     SRM
  70.  
  71. *         GET STAGE REQUEST.
  72.  
  73.  PFH3     RJ     GSR         GET NEXT STAGE REQUEST
  74.           NG     B6,PFH4     IF CANNOT READ REQUESTS
  75.           ZR     B6,PFH4     IF NO REQUESTS
  76.           WRITEW F,B6,PFTBL
  77.           EQ     PFH3        GET NEXT REQUEST
  78.  
  79. *         IF NO MORE REQUESTS, RELEASE FILE AND CLEAR BIT.
  80.  
  81.  PFH4     WRITER F,R
  82.           UNLOAD F
  83.  PFH5     SB2    PFHA        INFORM *MAGNET* THAT FILE IS RELEASED
  84.           RJ     SRM
  85.           ZR     X1,PFH1     IF SUCCESSFUL
  86.           RECALL             GIVE UP CPU
  87.           EQ     PFH5        TRY AGAIN
  88.  
  89.  
  90.  PFHA     VFD    12/AIB,24/,6/0,18/1   CLEAR *FILE ATTACHED* BIT
  91.  PFHB     VFD    12/AIB,24/,6/1,18/1   SET *FILE ATTACHED* BIT
  92.  PFHC     VFD    60/60
  93.  END      SPACE  4,10
  94. **        END - END PROGRAM.
  95. *
  96.  
  97.  
  98.  END      MESSAGE  (=C*PFHELPR ABORTED.*)
  99.           ENDRUN
  100.           SPACE  4,10
  101. *         COMMON DECKS.
  102.  
  103.  
  104. *CALL     COMCCIO
  105. *CALL     COMCCPM
  106. *CALL     COMCPFM
  107. *CALL     COMCSYS
  108.           LIST   X
  109. *CALL     COMCSRI
  110.           LIST   *
  111. *CALL     COMCWTW
  112.           TITLE  PRESET.
  113.           USE    BUFFERS
  114.  PRS      SPACE  4,10
  115. **        PRS - PRESET.
  116. *
  117.  
  118.  
  119.  FBUF     BSS    0           OUTPUT BUFFER
  120.  PRS      SUBR               ENTRY/EXIT
  121.           REPRIEVE  RPVB,SET,237B  SET REPRIEVE PROCESSING
  122.           MACHID PRSA        GET MACHINE ID
  123.           SA1    PRSA
  124.           SA2    F           SET ID INTO STAGE REQUEST FILE NAME
  125.           LX1    24
  126.           BX6    X1+X2
  127.           SA6    A2
  128.           GETJN  PRSB        GET JOB NAME
  129.           SA1    PRSB
  130.           SA2    PFHA        SET JOB NAME IN *MAGNET* REQUESTS
  131.           SA3    PFHB
  132.           LX1    24-36
  133.           BX7    X1+X2
  134.           BX6    X1+X3
  135.           SA7    A2
  136.           SA6    A3
  137.           SB2    PFHA        SEND *CLEAR BIT* REQUEST TO MAGNET
  138.           RJ     SRM
  139.           EQ     PRSX        RETURN
  140.  
  141.  
  142.  PRSA     BSS    1           MACHINE ID BUFFER
  143.  PRSB     BSS    1           JOB NAME BUFFER
  144.  
  145.           BSS    FBUF+FBUFL+1-*   ALLOCATE ENOUGH SPACE FOR BUFFER
  146.           BSS    8           PREVENT LOOKAHEAD REFERENCE BEYOND FL
  147.  RFL=     END