IDENT  SUBMT 
          SST
          ENTRY  SUBMT
          ENTRY  BTRAN
          ENTRY  ROUTE
          SYSCOM B1
          TITLE  SUBMT - TRANSACTION SUBSYSTEM SUBMIT ROUTINES.
*COMMENT  SUBMT - SUBMIT AND BTRAN ROUTINES.
          COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992.
          SPACE  4
*****     SUBMT - TRANSACTION/BATCH AND BATCH/TRANSACTION SUBMITS.
*
*         W. E. MARTIN.      79/03/16.
          SPACE  4
*         COMMON TEXTS.
 
 
*CALL     COMCMAC
*CALL     COMKMAC
*CALL     COMSSSD
          LIST   X
*CALL     COMKTSC
          LIST   -X
 ROUTE    SPACE  4,10
***       ROUTE - PROCESS *ROUTE* COMMAND.
*
*         *ROUTE* IS USED TO PLACE FILES INTO THE INPUT OR
*         OUTPUT QUEUES.
*
*         ENTRY FORMAT -
*
*         FORTRAN EXTENDED -
*
*                CALL ROUTE(LFN,LENGTH,STAT,P1,P1V,P2,P2V,...PN,PNV)
*
*         COBOL -
*
*                ENTER ROUTE USING LFN, LENGTH, STAT, P1, P1V, P2, P2V,
*                ...PN, PNV.
*
*         WHERE LFN = FWA OF DATA TO ROUTE.
*
*               LENGTH = LENGTH OF DATA IN CM WORDS, AND ON WORD
*                        BOUNDARY.
*
*               STAT = STATUS RETURN ADDRESS.
*
*               P1...PN = *ROUTE* PARAMETERS.
*
*               P1V...PNV = *ROUTE* PARAMETER VALUES.
*
*         USES   X - 1.
*
*         MACROS SYSTEM.
 
 
          VFD    42/0LROUTE,18/ROUTE
 
 ROUTE    SUBR               ENTRY/EXIT
          SX1    A1          FWA OF PARAMETER LIST
          SYSTEM CTI,R,X1,30B  ROUTE FILE
          EQ     ROUTEX      RETURN
 SUBMT    SPACE  4,20
***       SUBMT - SUBMIT JOB TO BATCH SUB-SYSTEM.
*
*         ENTRY FORMAT -
*
*         FORTRAN EXTENDED -
*
*                CALL SUBMT(JOBADDR).
*
*         COBOL -
*
*                ENTER SUBMT USING JOBADDR.
*
*         WHERE JOBADDR = ADDRESS OF JOB DATA TO BE SUBMITTED
*                         IN CONTROL-WORD WRITE FORMAT.
*
*         MACROS SUBMT.
 
 
          VFD    42/0LSUBMT,18/SUBMT
 
 SUBMT    SUBR               ENTRY/EXIT
          SX1    X1          SET ADDRESS OF JOB DATA
          SUBMT  X1          *SUBMIT* JOB
          EQ     SUBMTX      RETURN
 BTRAN    SPACE  4,50
***       BTRAN - SUBMIT A TRANSACTION FROM A BATCH JOB.
*
*         ENTRY FORMAT -
*
*         FORTRAN EXTENDED -
*
*                CALL BTRAN ( TRAN, STATUS )
*
*         COBOL -
*
*                ENTER BTRAN USING TRAN, STATUS.
*
*         WHERE TRAN = ADDRESS OF FIRST WORD OF TRANSACTION TO
*                      SUBMIT TO *TAF* IN THE FOLLOWING FORMAT -
*
*               STATUS = ADDRESS WHERE *BTRAN* STATUS IS TO BE
*                        RETURNED ( OPTIONAL FOR COBOL ).
*
*T        42/0,18/LENGTH.
*T,       60/  TRANSACTION INPUT DATA (LIMIT 620 CHARACTERS)
*
*         LENGTH - LENGTH OF DATA PLUS HEADER IN WORDS.
*
*         DATA - THE DATA MUST BE IN A FORMAT ACCEPTABLE TO THE
*                *INITIAL* TASK.  THE 620 CHARACTER LIMIT IS A MAXIMUM,
*                AND THE SYSTEM MAY BE ASSEMBLED FOR LESS.
*
*         EXIT   (X6) = ( STATUS ).
*                WHERE STATUS EQUALS BATCH JOB STATUS CODES.
*
*         USES   A - 1, 2, 6, 7.
*                X - 0, 1, 2, 5, 6, 7.
*                B - 1.
*
*         MACROS BTRAN, RECALL.
 
 
          VFD    42/0LBTRAN,18/BTRAN
 
 BTR3     SA1    BTRA        STATUS ADDRESS
          ZR     X1,BTRANX   IF NO ADDRESS PROVIDED
          BX7    X6          SET RETURN STATUS
          SA7    X1
 
 BTRAN    SUBR               ENTRY/EXIT
          SB1    1
          BX6    X6-X6       CLEAR STATUS ADDRESS
          SA2    A1+B1
          ZR     X2,BTR1     IF NO SECOND PARAMETER
          BX6    X2          SAVE STATUS ADDRESS
 BTR1     SA6    BTRA
          SX2    X1
          BTRAN  X2          SUBMIT TRANSACTION TO TAF
          EQ     BTR3        SET RETURN STATUS
 
 BTRA     CON    0           STORAGE FOR RETURN STATUS
          SPACE  4
          END