*DECK NETLOG
USETEXT AIPDEF
USETEXT NP$DB 
USETEXT NP$NWL
USETEXT NP$MODE 
USETEXT NP$STAT 
PROC NETLOG(ADDR, SIZE, FORMAT);  # LOG MSG TO DEBUG LOG FILE          #
*IF DEF,IMS 
 #
*1DC  NETLOG
* 
*     1. PROC NAME           AUTHOR              DATE 
*        NETLOG              P.C.TAM             80/03/05 
* 
*     2. FUNCTIONAL DESCRIPTION.
*        THIS ROUTINE IS CALLED TO LOG MESSAGES INTO THE DEBUG LOG FILE 
* 
*     3. METHOD USED
*        CALLS NP$DBG WITH LOC$TA SET TO ADDR, DB$SIZE TO SIZE, AND 
*        DB$FORMAT TO FORMAT. 
* 
*     4. ENTRY PARAMETERS 
*        ADDR                ADDRESS OF TEXT TO BE LOGGED 
*        SIZE                SIZE OF THE MESSAGE
*        FORMAT              1 FOR FORMATTED MESSAGE
*                            0 FOR UNFORMATTED MESSAGE
* 
*     5. EXIT PARAMETERS
*        NONE 
* 
*     6. COMDECKS AND SYMPL TEXTS 
*        AIPDEF    NP$DB
* 
*     7. ROUTINES CALLED
*        NP$DBG              LOG DEBUG FILE 
*        NP$ERR              ABORT WITH ERROR MESSAGES
* 
*     8. DAYFILE MESSAGES 
*        NONE 
* 
 #
*ENDIF
*CALL NP$CRT
# 
      ROUTINES CALLED 
# 
      XREF
        BEGIN 
        PROC NP$DBG;         # WRITE MSG TO DEBUG LOG FILE             #
        PROC NP$ERR;         # ABORT WITH ERROR MESSAGES               #
        PROC NP$SN ;
        END 
# 
      INPUT PARAMETERS
# 
      ITEM
        ADDR,                # ADDRESS OF TEXT TO BE LOGGED            #
        SIZE,                # SIZE OF TEXT BLOCK                      #
        FORMAT;              # FORMAT FLAG                             #
# 
      INTERNAL PARAMETERS 
# 
# ******************************************************************** #
      BEGIN 
  
      ENTRY PROC QTLOG(ADDR,SIZE,FORMAT);  # QTRM ENTRY POINT          #
  
        NP$SN(TYPE"LOG") ;
*IF DEF,DEBUG 
  
      IF ACCEPTED 
      THEN
        BEGIN                # APPLICATION NETS ON ALREADY             #
        LOC$TA = LOC(ADDR) ;
        DB$SIZE = SIZE;      # SIZE OF TEXT MESSAGE                    #
        DB$FORMAT = FORMAT;  # FORMAT FLAG                             #
        DB$OP = OP$LOG;      # NETLOG CALL                             #
        P<CALLADR> = LOC(NETLOG);# LOCATION OF THE CALL                #
        DB$CALL = CALLADDR[0];
        NP$DBG; 
        END 
      ELSE
        NP$ERR("35");        # NETLOG WITHOUT NETON                    #
  
*ENDIF
      END 
TERM