*DECK NPHOPMS 
USETEXT NIPDEF
USETEXT NHEADER 
USETEXT PARAMP
USETEXT SUPMSG
  
 PRGM NPHOPMS;               # PROCESS HOPN/SEND FROM ANOTHER HOST     #
  
 STARTIMS;
 STOPIMS; 
  
# 
      EXTERNAL REFERENCES 
# 
      XREF
        BEGIN 
        PROC KHOPMSG;        # ISSUE HOP ALERT MESSAGE                 #
        PROC OMSG;           # DAYFILE MESSAGE                         #
        PROC XTRACE;         # TRACE CALL                              #
        LABEL RJMAIN; 
        END 
# 
      LOCAL VARIABLES 
# 
      ARRAY HOPMSGTEXT [0:0] S(6);
        BEGIN                # HOP MESSAGE LINE FORMAT                 #
        ITEM TXT$HOPMSG C(00,00,50); # WHOLE MESSAGE                   #
        ITEM TXT$HDR1   C(00,00,05) = ["FROM "];
        ITEM TXT$SNC1   C(00,30,01); # SOURCE NODE IN DECIMAL DISPLAY  #
        ITEM TXT$SNC2   C(00,36,01);
        ITEM TXT$SNC3   C(00,42,01);
        ITEM TXT$HDR2   C(00,48,02) = [".."]; 
        ITEM TXT$TXT1   U(01,00,60); # TEXT WORDS                      #
        ITEM TXT$TXT2   U(02,00,60);
        ITEM TXT$TXT3   U(03,00,60);
        ITEM TXT$TXT4   U(04,00,60);
        ITEM TXT$TEND   U(05,00,60) = [0];
        END 
  
      ITEM SOURCEN;          # SOURCE NODE NUMBER                      #
      ITEM TEMP1;            # TEMPORARY                               #
      ITEM TEMP2;            # TEMPORARY                               #
      ITEM TEMP3;            # TEMPORARY                               #
      ITEM TIMEOFDAY;        # TIME OF DAY IN DISPLAY CODE             #
  
      CONTROL EJECT;
  
      BEGIN # NPHOPMS # 
  
      CONTROL IFEQ DEBUG,1; 
      XTRACE("NHOPM");       # TRACE CALL                              #
      CONTROL FI; 
  
      P<NHEADER> = PARAMP1+BLKHSIZE; # NETWORK HEADER FWA              #
      P<SMNIP> = P<NHEADER>+ABHSIZE;
  
      SOURCEN = SN[0];       # SOURCE NODE NUMBER                      #
      TEMP1 = SOURCEN/100;
      TXT$SNC1[0] = TEMP1 + O"33";
      TEMP2 = (SOURCEN-TEMP1*100)/10; 
      TXT$SNC2[0] = TEMP2 + O"33";
      TEMP3 = (SOURCEN-TEMP1*100-TEMP2*10); 
      TXT$SNC3[0] = TEMP3 + O"33";
      TXT$TXT1[0] = HOPMSG1[0]; 
      TXT$TXT2[0] = HOPMSG2[0]; 
      TXT$TXT3[0] = HOPMSG3[0]; 
      TXT$TXT4[0] = HOPMSG4[0]; 
      OMSG(HOPMSGTEXT,0); # DAYFILE HOP MESSAGE TEXT                   #
      KHOPMSG(LOC(HOPMSGTEXT)); # ISSUE HOP ALERT MESSAGE              #
  
      GOTO RJMAIN;
      END # NPHOPMS # 
      TERM