*NOSEQ 
.PROC,HOSTCPY,FN=SSTVSN,FC=1,EQ=027,CI=NO/YES.
.**       HOSTCPY PERFORMS PREPROCESSING OF THE 5870/5970
.*        SYSTEM SOFTWARE TAPE (SST).  HOSTCPY ALSO IS
.*        USED TO TRANSMIT SOURCE FILES (FSL, JSL, CMD)
.*        IN EBCDIC CARDIMAGE FORMAT.
.*
.*        COPYRIGHT CONTROL DATA SYSTEMS INC.  1992.
.*
.*        PARAMETERS
.*
.*        FN     SPECIFIES THE FILE CONTAINING THE SST.
.*               IF THE FILE IS ASSIGNED TO THE CONTROL POINT,
.*                           THIS IS THE NAME OF THE FILE.
.*               IF THE FILE IS UNASSIGNED, THE PROCEDURE ASSUMES
.*                           THIS IS THE VSN OF THE TAPE AND WILL
.*                           REQUEST THE TAPE FOR PROCESSING.
.*        FC     SPECIFIES THE TOTAL NUMBER OF FILES ON THE SST.
.*        EQ     SPECIFIES THE EST ORDINAL OF THE 5870/5970 TO
.*                           RECEIVE THE FILE.  THIS PARAMETER
.*                           MUST BE SPECIFIED AS A THREE DIGIT
.*                           OCTAL NUMBER - I.E., 027.
.*        CI     IF PRESENT, DECLARES THAT THE FILE SPECIFIED BY
.*                           *FN* IS A CARDIMAGE (80 COLUMN) FILE
.*                           CONTAINING EBCDIC DATA.
.*
.*        HOSTCPY MUST BE RUN AS A SYSTEM ORIGIN JOB.
.*
$IF,(OT.NE.SYO),L005.
  $REVERT,ABORT. ** HOSTCPY MUST RUN AS SYSTEM ORIGIN **
$ENDIF,L005.
$IF,(.NOT.NUM(EQ)),L010.
  $RETURN,ZZZZDIR.
  $REVERT,ABORT. ** EST ORDINAL MUST BE NUMERIC **
$ENDIF,L010.
$IF,(.NOT.NUM(FC)),L020.
  $RETURN,ZZZZDIR.
  $REVERT,ABORT. ** FILE COUNT MUST BE NUMERIC **
$ENDIF,L020.
$IF,(.NOT.FILE(FN,AS)),L100.
  $REQUEST,SST,VSN=FN,F=L,D=PE,LB=KU.
  $REWIND,SST.
  $SKIPF,SST,FC.
  $SKIPFB,SST,1.
  $COPY,SST,FTS,,,D,1,1093.
  $UNLOAD,SST.
$ELSE,L100.
  $RENAME,FTS=FN.
$ENDIF,L100.
$HSTCOPY(ZZZZDIR)
$RETURN,ZZZZDIR.
$REVERT. ** HOSTCPY COMPLETE **
$EXIT.
$REVERT,ABORT. ** HOSTCPY FAILED **
.DATA,ZZZZDIR
EQ
.IF,$CI$ .#EQ. $YES$,CRD.
TRUE
.ELSE,CRD.
FALSE
.ENDIF,CRD.
*WEOR