IDENT  JOURNL

          ENTRY  JOURNL
          TITLE  JOURNL - ISSUE JOURNAL MESSAGE.
*COMMENT  JOURNL - ISSUE JOURNAL MESSAGE.
          COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992.
          SPACE  4
***       JOURNL - ISSUE JOURNAL MESSAGE.
*         J.C. BOHNHOFF. 72/07/09.
          SPACE  4
*CALL,COMKMAC
*CALL     COMSPRD
          SPACE  4
***       CALL FORMAT -
*
*         FORTRAN EXTENDED
*                CALL JOURNL(TYPE,MESSAGE,LENGTH)
*         COBOL
*                ENTER JOURNL USING TYPE,MESSAGE
*
*         WHERE - TYPE= JOURNAL FILE NUMBER,
*                            COBOL - COMPUTATIONAL-1
*                            FORTRAN EXTENDED - INTEGER
*                 MESSAGE= LOCATION OF MESSAGE TO BE ISSUED.
*                 LENGTH= LENGTH OF MESSAGE EXPRESSED IN CHARACTERS.
*                            FORTRAN EXTENDED - INTEGER


 JOURNL   PS                 ENTRY/EXIT
          SA2    X1          READ TYPE
          SA3    A1+1        READ ADDRESS OF MESSAGE
          UX2    X2
          SX4    X3          MESSAGE ADDRESS
          BX6    X4-X3       CHECK COBOL CALL
          NZ     X6,JOU2     IF COBOL
          SA5    A3+1        READ LENGTH ADDRESS
          SA5    X5+         READ LENGTH
 JOU1     SX7    10          COMPUTE MESSAGE LENGTH IN WORDS
          SX5    X5+9        ROUND LENGTH UP
          LX2    36          POSITION TYPE
          IX5    X5/X7
          BX6    X2+X4       TYPE + ADDRESS
          LX5    18          POSITION MESSAGE LENGTH
          BX6    X6+X5       ADDRESS + LENGTH + TYPE
          SA6    JOUA        STORE ARGUMENT WORD
          JOURNL A6          ISSUE REQUEST
          JP     JOURNL      RETURN

 JOU2     AX3    36          EXTRACT MESSAGE LENGTH
          BX5    X3
          JP     JOU1

 JOUA     CON    0           ARGUMENT STORAGE

          END