ASCII
*WIDTH,80
*NOSEQ
.PROC,VEMEM*I
,VEMEM =(*N=#FILE)
.
.HELP
T^H^E VEMEM ^U^T^I^L^I^T^Y ^I^S ^U^S^E^D ^T^O ^H^E^L^P ^Y^O^U ^C^O^N^F^I^G^U^R^E ^Y^O^U^R ^M^A^I^N^F^R^A^M^E ^M^E^M^O^R^Y
^F^O^R ^U^S^E ^I^N ^A NOS D^U^A^L S^T^A^T^E ^E^N^V^I^R^O^N^M^E^N^T.  B^A^S^E^D ^O^N ^Y^O^U^R ^R^E^S^P^O^N^S^E^S, ^I^T
^P^R^O^V^I^D^E^S ^Y^O^U ^W^I^T^H ^T^H^E ^P^R^O^P^E^R CMRDECK ^A^N^D EQPDECK ^E^N^T^R^I^E^S ^T^O ^C^O^N^F^I^G^U^R^E
^M^E^M^O^R^Y ^F^O^R NOS ^A^N^D NOS/VE ^U^S^A^G^E.

V^A^L^U^E^S ^F^O^R M^A^I^N^F^R^A^M^E ^M^E^M^O^R^Y, NOS ^M^E^M^O^R^Y ^A^N^D NOS/VE ^M^E^M^O^R^Y, ^A^R^E ^E^N^T^E^R^E^D
^I^N M^E^G^A^B^Y^T^E^S ^A^N^D K^I^L^O^B^Y^T^E^S.  T^H^E ^F^O^R^M^A^T ^Y^O^U ^S^H^O^U^L^D ^U^S^E ^I^S:
  M^E^G^A^B^Y^T^E^S,K^I^L^O^B^Y^T^E^S
F^O^R ^E^X^A^M^P^L^E, ^T^O ^E^N^T^E^R 6.5 ^M^E^G^A^B^Y^T^E^S ^O^F NOS/VE, ^E^N^T^E^R 6,512 ^A^T ^T^H^E
^P^R^O^M^P^T ^F^O^R ^T^H^E ^M^E^G^A^B^Y^T^E ^P^O^R^T^I^O^N ^O^F NOS/VE ^M^E^M^O^R^Y.  I^F ^Y^O^U ^D^O ^N^O^T ^E^N^T^E^R
^A ^K^I^L^O^B^Y^T^E ^P^O^R^T^I^O^N, ^I^T ^W^I^L^L ^D^E^F^A^U^L^T ^T^O 0.

A^T ^S^E^V^E^R^A^L ^P^O^I^N^T^S, ^T^H^I^S ^P^R^O^C^E^D^U^R^E ^W^I^L^L ^D^I^S^P^L^A^Y ^H^O^W ^Y^O^U^R ^M^E^M^O^R^Y ^I^S
^A^L^L^O^C^A^T^E^D ^A^M^O^N^G^S^T NOS, NOS/VE ^A^N^D ^T^H^E P^A^G^E T^A^B^L^E.  T^H^E ^D^I^S^P^L^A^Y ^I^S
^I^N ^U^N^I^T^S ^O^F M^E^G^A^B^Y^T^E^S,K^I^L^O^B^Y^T^E^S.  W^H^E^N ^A^D^D^I^N^G ^U^P ^T^H^E ^N^U^M^B^E^R^S, ^N^O^T^E ^T^H^A^T
1 M^E^G^A^B^Y^T^E = 1,024 K^I^L^O^B^Y^T^E^S, ^T^H^U^S:

     0,064 (M^E^G^A^B^Y^T^E^S, K^I^L^O^B^Y^T^E^S)
   + 1,960 (M^E^G^A^B^Y^T^E^S, K^I^L^O^B^Y^T^E^S)
   = 2,000 (M^E^G^A^B^Y^T^E^S, K^I^L^O^B^Y^T^E^S)

V^A^L^U^E^S ^F^O^R U^N^I^F^I^E^D E^X^T^E^N^D^E^D M^E^M^O^R^Y (UEM), U^S^E^R A^C^C^E^S^S^I^B^L^E E^X^T^E^N^D^E^D
M^E^M^O^R^Y (UEC) ^A^N^D I^N^P^U^T O^U^T^P^U^T B^U^F^F^E^R^S (IOB) ^A^R^E ^E^N^T^E^R^E^D ^I^N ^U^N^I^T^S ^O^F
1000B O^C^T^A^L ^W^O^R^D^S.

C^O^N^S^U^L^T ^T^H^E NOS D^U^A^L S^T^A^T^E ^S^E^C^T^I^O^N ^O^F ^T^H^E NOS I^N^S^T^A^L^L^A^T^I^O^N H^A^N^D^B^O^O^K ^F^O^R
^A ^D^I^S^C^U^S^S^I^O^N ^O^N NOS ^A^N^D NOS/VE ^M^E^M^O^R^Y ^S^H^A^R^I^N^G ^A^N^D ^T^H^E
D^E^A^D^S^T^A^R^T D^E^C^K^S ^S^E^C^T^I^O^N ^O^F ^T^H^E NOS 2 A^N^A^L^Y^S^I^S H^A^N^D^B^O^O^K ^F^O^R ^I^N^F^O^R^M^A^T^I^O^N ^O^N
NOS ^M^E^M^O^R^Y ^A^L^L^O^C^A^T^I^O^N ^A^N^D ^T^E^R^M^S.

.ENDHELP
.****
.* NOTE - THESE PROCEDURES CONTAIN DISPLAY CODE (00) COLONS. THE COLONS
.*        MUST BE LEFT IN DISPLAY CODE IN ORDER FOR THE *NOTE*
.*        STATEMENTS TO WORK PROPERLY.  DO NOT CONVERT THE COLONS TO
.*        ASCII FORMAT (@AD).
.****
.IF,SL=SCREEN.$LINE.
$BEGIN(MF,VEMEM)  ** MF IS RETURNED IN R2 AND R3
$DISPLAY(R2,R3)
$BEGIN(CHOICED,VEMEM)
$BEGIN(CHOICE,VEMEM)  ** CHOICE RETURNS IN R1
$DISPLAY(R1)
$BEGIN(MAIN1,VEMEM,R2+,R3+,R1+)
.IF,SL.EQ.SCREEN.$SCREEN.
$REVERT. VEMEM COMPLETE
$EXIT. VEMEM
.IF,SL.EQ.SCREEN.$SCREEN.
$REVERT(ABORT) VEMEM FAILED
*WEOR
.PROC,CHOICED*I
,VEMEM =(*N=#FILE)
.
$NOTE.;;:I 1. C^O^N^F^I^G^U^R^E NOS/VE ^A^N^D NOS ^W^I^T^H
$NOTE.;:I    NO ^U^S^E^R ^E^X^T^E^N^D^E^D ^M^E^M^O^R^Y     (UEC=0)
$NOTE.;:I    NO ^U^N^I^F^I^E^D ^E^X^T^E^N^D^E^D ^M^E^M^O^R^Y  (UEM=0)
$NOTE.;;:I 2. C^O^N^F^I^G^U^R^E NOS/VE ^A^N^D NOS ^W^I^T^H
$NOTE.;:I       ^U^S^E^R ^E^X^T^E^N^D^E^D ^M^E^M^O^R^Y     (UEC=?)
$NOTE.;:I    NO ^U^N^I^F^I^E^D ^E^X^T^E^N^D^E^D ^M^E^M^O^R^Y  (UEM=0)
$NOTE.;;:I 3. C^O^N^F^I^G^U^R^E NOS/VE ^A^N^D NOS ^W^I^T^H
$NOTE.;:I       ^U^S^E^R ^E^X^T^E^N^D^E^D ^M^E^M^O^R^Y     (UEC=?)
$NOTE.;:I       ^U^N^I^F^I^E^D ^E^X^T^E^N^D^E^D ^M^E^M^O^R^Y  (UEM=?);
$REVERT.CHOICEDISPLAY
$EXIT. CHOICEDISPLAY
$REVERT(ABORT)CHOICEDISPLAY
*WEOR
.PROC,CHOICE*I
,CHOICE [C^H^O^O^S^E ^C^O^N^F^I^G^U^R^A^T^I^O^N ^O^P^T^I^O^N] =(1,2,3)
,VEMEM =(*N=#FILE)
.
.HELP.
 C^H^O^O^S^E ^W^H^I^C^H ^T^Y^P^E ^O^F ^M^E^M^O^R^Y ^C^O^N^F^I^G^U^R^A^T^I^O^N ^Y^O^U ^W^I^S^H ^T^O ^D^E^F^I^N^E.
T^H^E ^C^H^O^I^C^E^S ^A^R^E:
  1. NOS/VE ^A^N^D NOS ^W^I^T^H^O^U^T ^A^N^Y ^U^S^E^R ^E^X^T^E^N^D^E^D ^M^E^M^O^R^Y.
  2. NOS/VE ^A^N^D NOS ^W^I^T^H ^U^S^E^R ^E^X^T^E^N^D^E^D ^M^E^M^O^R^Y ^O^N^L^Y.
  3. NOS/VE ^A^N^D NOS ^W^I^T^H ^E^X^T^E^N^D^E^D ^M^E^M^O^R^Y, ^P^O^S^S^I^B^L^Y ^F^O^R 895 ^D^I^S^K^S,
     ^U^S^E^R^S, ^O^R ^A ^M^A^S^S ^S^T^O^R^A^G^E ^D^E^V^I^C^E.
.HELP,CHOICE,NOLIST.
 T^H^E^R^E ^A^R^E ^T^H^R^E^E ^P^O^S^S^I^B^L^E ^C^H^O^I^C^E^S.
1.  NOS/VE ^A^N^D NOS ^W^I^T^H^O^U^T ^A^N^Y ^U^N^I^F^I^E^D ^E^X^T^E^N^D^E^D ^M^E^M^O^R^Y.
    U^N^I^F^I^E^D ^E^X^T^E^N^D^E^D ^M^E^M^O^R^Y ^C^A^N ^B^E ^U^S^E^D ^O^N NOS ^F^O^R ^T^H^E ^F^O^L^L^O^W^I^N^G:
     ^A.  U^S^E^R ^A^C^C^E^S^S^I^B^L^E ^E^X^T^E^N^D^E^D ^M^E^M^O^R^Y - ^T^H^I^S ^I^S ^T^Y^P^I^C^A^L^L^Y ^U^S^E^D ^B^Y
         FORTRAN ^P^R^O^G^R^A^M^S ^F^O^R ^T^H^E ^S^T^O^R^A^G^E ^O^F ^L^A^R^G^E ^A^R^R^A^Y^S.
         R^E^F^E^R ^T^O ^T^H^E ^D^I^S^C^U^S^S^I^O^N ^O^F ^T^H^E LEVEL ^S^T^A^T^E^M^E^N^T ^I^N ^T^H^E
         FORTRAN 5 R^E^F^E^R^E^N^C^E M^A^N^U^A^L.  T^H^I^S ^T^Y^P^E ^O^F ^M^E^M^O^R^Y ^I^S
         ^R^E^F^E^R^R^E^D ^T^O ^A^S UEC.
     ^B.  E^X^T^E^N^D^E^D ^M^E^M^O^R^Y ^A^S ^A ^M^A^S^S ^S^T^O^R^A^G^E ^D^E^V^I^C^E - ^T^H^I^S ^I^S ^T^Y^P^I^C^A^L^L^Y
         ^U^S^E^D ^F^O^R ^A^L^T^E^R^N^A^T^E ^S^Y^S^T^E^M ^R^E^S^I^D^E^N^C^Y ^O^F ^F^R^E^Q^U^E^N^T^L^Y
         ^A^C^C^E^S^S^E^D ^S^Y^S^T^E^M ^R^O^U^T^I^N^E^S ^A^N^D ^F^O^R ^S^T^O^R^I^N^G ^S^E^C^O^N^D^A^R^Y ^R^O^L^L^O^U^T ^F^I^L^E^S.
         R^E^F^E^R ^T^O ^T^H^E D^E^A^D^S^T^A^R^T D^E^C^K^S ^S^E^C^T^I^O^N ^O^F ^T^H^E NOS A^N^A^L^Y^S^I^S M^A^N^U^A^L ^F^O^R
         ^D^I^S^C^U^S^S^I^O^N^S ^O^N:
         *  EQ-E^X^T^E^N^D^E^D M^E^M^O^R^Y EST ^E^N^T^R^Y,
         *  ASR-A^L^T^E^R^N^A^T^E S^Y^S^T^E^M L^I^B^R^A^R^Y D^E^V^I^C^E A^S^S^I^G^N^M^E^N^T E^N^T^R^Y,
         *  MSAL-M^A^S^S S^T^O^R^A^G^E A^L^L^O^C^A^T^I^O^N C^O^N^T^R^O^L E^N^T^R^Y,
         *  SRST (S^E^C^O^N^D^A^R^Y R^O^L^L^O^U^T T^H^R^E^S^H^O^L^D E^N^T^R^Y)
     ^C.  I^N^P^U^T/O^U^T^P^U^T ^B^U^F^F^E^R^S ^F^O^R 895 ^D^I^S^K^S. R^E^F^E^R ^T^O ^T^H^E D^E^A^D^S^T^A^R^T D^E^C^K^S
         ^S^E^C^T^I^O^N ^O^F ^T^H^E NOS A^N^A^L^Y^S^I^S M^A^N^U^A^L ^F^O^R ^A ^D^I^S^C^U^S^S^I^O^N ^O^F 895 ^D^I^S^K^S
         ^A^N^D ^T^H^E XM EQPDECK ^E^N^T^R^Y ^F^O^R ^D^E^C^L^A^R^I^N^G ^E^X^T^E^N^D^E^D ^M^E^M^O^R^Y
         ^S^P^A^C^E ^F^O^R ^B^U^F^F^E^R^S ^O^R ^U^S^E^R ^A^C^C^E^S^S.  T^H^I^S ^T^Y^P^E ^O^F ^M^E^M^O^R^Y ^I^S
         ^R^E^F^E^R^R^E^D ^T^O ^A^S IOB.

    S^E^L^E^C^T ^T^H^I^S ^C^H^O^I^C^E ^I^F ^Y^O^U ^D^O ^N^O^T ^N^E^E^D ^U^N^I^F^I^E^D ^E^X^T^E^N^D^E^D ^M^E^M^O^R^Y.

2.  NOS/VE ^A^N^D NOS ^W^I^T^H ^U^S^E^R ^A^C^C^E^S^S^I^B^L^E ^E^X^T^E^N^D^E^D ^M^E^M^O^R^Y.
    T^H^I^S ^C^H^O^I^C^E ^P^E^R^M^I^T^S ^Y^O^U ^T^O ^C^O^N^F^I^G^U^R^E ^S^O^M^E ^O^F ^Y^O^U^R NOS ^M^E^M^O^R^Y
    ^F^O^R ^A^C^C^E^S^S ^B^Y ^U^S^E^R^S.  T^H^I^S ^M^E^M^O^R^Y, ^C^A^L^L^E^D ^U^S^E^R ^A^C^C^E^S^S^I^B^L^E
    ^E^X^T^E^N^D^E^D ^M^E^M^O^R^Y (^O^R UEC), ^I^S ^T^Y^P^I^C^A^L^L^Y ^U^S^E^D ^F^O^R ^T^H^E ^S^T^O^R^A^G^E ^O^F ^L^A^R^G^E
    ^A^R^R^A^Y^S ^I^N FORTRAN ^P^R^O^G^R^A^M^S.  R^E^F^E^R ^T^O ^T^H^E ^D^I^S^C^U^S^S^I^O^N ^O^F ^T^H^E
    LEVEL ^S^T^A^T^E^M^E^N^T ^I^N ^T^H^E FORTRAN 5 R^E^F^E^R^E^N^C^E M^A^N^U^A^L.

    S^E^L^E^C^T ^T^H^I^S ^C^H^O^I^C^E ^I^F ^Y^O^U ^W^A^N^T ^T^O ^C^O^N^F^I^G^U^R^E ^S^O^M^E ^M^E^M^O^R^Y ^F^O^R
    ^U^S^E^R ^A^C^C^E^S^S^I^B^L^E ^E^X^T^E^N^D^E^D ^M^E^M^O^R^Y.

3.  NOS/VE ^A^N^D NOS ^W^I^T^H ^U^N^I^F^I^E^D ^E^X^T^E^N^D^E^D ^M^E^M^O^R^Y.  I^N
    ^A^D^D^I^T^I^O^N ^T^O ^M^E^M^O^R^Y ^F^O^R NOS/VE ^A^N^D NOS, ^U^N^I^F^I^E^D ^E^X^T^E^N^D^E^D
    ^M^E^M^O^R^Y ^I^S ^A^L^S^O ^C^O^N^F^I^G^U^R^E^D.  U^N^I^F^I^E^D ^E^X^T^E^N^D^E^D ^M^E^M^O^R^Y, ^R^E^F^E^R^R^E^D ^T^O ^A^S
    UEM, ^C^A^N ^B^E ^U^S^E^D ^O^N NOS ^F^O^R ^T^H^E ^F^O^L^L^O^W^I^N^G:
     ^A.  U^S^E^R ^A^C^C^E^S^S^I^B^L^E ^E^X^T^E^N^D^E^D ^M^E^M^O^R^Y - ^T^H^I^S ^I^S ^T^Y^P^I^C^A^L^L^Y ^U^S^E^D ^B^Y
         FORTRAN ^P^R^O^G^R^A^M^S ^F^O^R ^T^H^E ^S^T^O^R^A^G^E ^O^F ^L^A^R^G^E ^A^R^R^A^Y^S.
         R^E^F^E^R ^T^O ^T^H^E ^D^I^S^C^U^S^S^I^O^N ^O^F ^T^H^E LEVEL ^S^T^A^T^E^M^E^N^T ^I^N ^T^H^E
         FORTRAN 5 R^E^F^E^R^E^N^C^E M^A^N^U^A^L.  T^H^I^S ^T^Y^P^E ^O^F ^M^E^M^O^R^Y ^I^S
         ^R^E^F^E^R^R^E^D ^T^O ^A^S UEC.
     ^B.  E^X^T^E^N^D^E^D ^M^E^M^O^R^Y ^A^S ^A ^M^A^S^S ^S^T^O^R^A^G^E ^D^E^V^I^C^E - ^T^H^I^S ^I^S ^T^Y^P^I^C^A^L^L^Y
         ^U^S^E^D ^F^O^R ^A^L^T^E^R^N^A^T^E ^S^Y^S^T^E^M ^R^E^S^I^D^E^N^C^Y ^O^F ^F^R^E^Q^U^E^N^T^L^Y
         ^A^C^C^E^S^S^E^D ^S^Y^S^T^E^M ^R^O^U^T^I^N^E^S ^A^N^D ^F^O^R ^S^T^O^R^I^N^G ^S^E^C^O^N^D^A^R^Y ^R^O^L^L^O^U^T ^F^I^L^E^S.
         R^E^F^E^R ^T^O ^T^H^E D^E^A^D^S^T^A^R^T D^E^C^K^S ^S^E^C^T^I^O^N ^O^F ^T^H^E NOS A^N^A^L^Y^S^I^S M^A^N^U^A^L ^F^O^R
         ^D^I^S^C^U^S^S^I^O^N^S ^O^N:
         *  EQ-E^X^T^E^N^D^E^D M^E^M^O^R^Y EST ^E^N^T^R^Y,
         *  ASR-A^L^T^E^R^N^A^T^E S^Y^S^T^E^M L^I^B^R^A^R^Y D^E^V^I^C^E A^S^S^I^G^N^M^E^N^T E^N^T^R^Y,
         *  MSAL-M^A^S^S S^T^O^R^A^G^E A^L^L^O^C^A^T^I^O^N C^O^N^T^R^O^L E^N^T^R^Y,
         *  SRST (S^E^C^O^N^D^A^R^Y R^O^L^L^O^U^T T^H^R^E^S^H^O^L^D E^N^T^R^Y)
     ^C.  I^N^P^U^T/O^U^T^P^U^T ^B^U^F^F^E^R^S ^F^O^R 895 ^D^I^S^K^S. R^E^F^E^R ^T^O ^T^H^E D^E^A^D^S^T^A^R^T D^E^C^K^S
         ^S^E^C^T^I^O^N ^O^F ^T^H^E NOS A^N^A^L^Y^S^I^S M^A^N^U^A^L ^F^O^R ^A ^D^I^S^C^U^S^S^I^O^N ^O^F 895 ^D^I^S^K^S
         ^A^N^D ^T^H^E XM EQPDECK ^E^N^T^R^Y ^F^O^R ^D^E^C^L^A^R^I^N^G ^E^X^T^E^N^D^E^D ^M^E^M^O^R^Y
         ^S^P^A^C^E ^F^O^R ^B^U^F^F^E^R^S ^O^R ^U^S^E^R ^A^C^C^E^S^S.  T^H^I^S ^T^Y^P^E ^O^F ^M^E^M^O^R^Y ^I^S
         ^R^E^F^E^R^R^E^D ^T^O ^A^S IOB.

    S^E^L^E^C^T ^T^H^I^S ^C^H^O^I^C^E ^I^F ^Y^O^U ^N^E^E^D ^U^N^I^F^I^E^D ^E^X^T^E^N^D^E^D ^M^E^M^O^R^Y ^F^O^R
    ^A^N^Y ^O^F ^T^H^E ^A^B^O^V^E.  NOTE:  ^I^F ^Y^O^U ^O^N^L^Y ^N^E^E^D ^U^N^I^F^I^E^D ^E^X^T^E^N^D^E^D
    ^M^E^M^O^R^Y ^F^O^R ^J^U^S^T ^A., ^U^S^E ^C^H^O^I^C^E 2: NOS/VE ^A^N^D NOS ^W^I^T^H ^U^S^E^R
    ^A^C^C^E^S^S^I^B^L^E ^E^X^T^E^N^D^E^D ^M^E^M^O^R^Y.
.ENDHELP
.*
.IF, (CHOICE=1) ,CHOICE1.
$NOTE.;;:I A^L^L^O^C^A^T^E NOS/VE ^A^N^D NOS ^O^N^L^Y.;
.ELSE(CHOICE1)
.IF, (CHOICE=2) ,CHOICE1.
$NOTE.;;:I A^L^L^O^C^A^T^E NOS/VE ^A^N^D NOS, ^T^H^E^N
$NOTE.;:I ^A^L^L^O^C^A^T^E ^U^S^E^R ^E^X^T^E^N^D^E^D ^M^E^M^O^R^Y (UEC).;
.ELSE(CHOICE1)
$NOTE.;;:I A^L^L^O^C^A^T^E NOS/VE ^A^N^D NOS, ^T^H^E^N
$NOTE.;:I ^A^L^L^O^C^A^T^E ^U^N^I^F^I^E^D ^E^X^T^E^N^D^E^D ^M^E^M^O^R^Y (UEM).
$NOTE.;:I A^L^L^O^C^A^T^E ^U^S^E^R ^E^X^T^E^N^D^E^D ^M^E^M^O^R^Y (UEC)
$NOTE.;:I ^A^N^D 895 ^D^E^V^I^C^E ^B^U^F^F^E^R^S (IOB).;
.ENDIF(CHOICE1)
$REVERT(EX)$SET(R1=CHOICE)
$EXIT. CHOICE
$REVERT(ABORT) CHOICE FAILED
*WEOR
.PROC,MAIN1*I
,MB      =(*S3/D)
,KB      =(*S3/D)
,OPTION  =(*A)
,VEMEM   =(*N=#FILE)
.
.SET(#MF=STRD(MB*128+KB/8))  ** COMBINED TOTAL MEMORY
.SET(#PT=STRD((MF+1023)/1024+8))  ** PAGE TABLE
.IF, (OPTION = 1), MAIN1A.
.SET(#UP=STRD(2048))  ** NOS MAXIMUM WITHOUT EXTENDED MEMORY
.ELSE,MAIN1A.
.SET(#UP=STRD(16384))  ** NOS MAXIMUM WITH EXTENDED MEMORY
.ENDIF,MAIN1A.
$BEGIN(VENOS,VEMEM)  ** RETURNS R1=1=NOS, R1=2=VE
$IF, (R1=1) ,MAIN1B.
  .* CHOOSE AN AMOUNT OF NOS MEMORY
  .* (128) = LOWER BOUND = 1 MEGABYTE
  .IF, (MF-832-PT .LT. UP) ,MAIN1B1.
    .SET(#UP=STRD(MF-832-PT))  ** SET NOS MEMORY LIMIT
  .ENDIF(MAIN1B1)
  $BEGIN(NOS,VEMEM,MF,0,128,UP,OPTION,FIRST=YES)
$ELSE(MAIN1B)
  .* CHOOSE AN AMOUNT OF VE MEMORY
  .* (832) = LOWER BOUND = 6.5 MEGABYTE
  .IF, (MF-832-PT .GT. UP) ,MAIN1B2.
    .SET(#LOW=STRD(MF-UP-PT))  ** SET VE MIN BASED ON NOS MAX
  .ELSE(MAIN1B2)
    .SET(#LOW=STRD(832))
  .ENDIF(MAIN1B2)
  .SET(#UP=STRD(MF-128-PT))  ** UPPER = #MF-NOS-RESERVED
  $BEGIN(VE,VEMEM,MF,0,LOW,UP,OPTION,FIRST=YES)
$ENDIF(MAIN1B)
$REVERT. MAIN1 COMPLETE
$EXIT. MAIN1
$REVERT(ABORT) MAIN1 FAILED
*WEOR
.PROC,NOS*I
,MF      =(*A)
,NOS     =(*A)
,LOW     =(*A)
,UP      =(*A)
,OPTION  =(*A)
,FIRST   =(*N=NO,YES,NO)
,VEMEM   =(*N=#FILE)
.
.SET(#PT=STRD((MF+1023)/1024+8))  ** PAGE TABLE
.SET(#VE=STRD(MF-NOS-PT))  ** VE MEMORY
.IF, ($FIRST$ .EQ. $NO$) ,NOS0.
  $NOTE.;;:I C^U^R^R^E^N^T ^C^H^O^I^C^E^S (M^B^Y^T^E^S,K^B^Y^T^E^S):;
  $BEGIN(DISPB,VEMEM,#PT,PT)
  $BEGIN(DISPB,VEMEM,#NOS,NOS)
  $BEGIN(DISPB,VEMEM,#VE,VE)
  $BEGIN(DISPB,VEMEM,#MF,MF)
  $BEGIN(CHOOSE1,VEMEM,$#NOS$)  CHOICE RETURNS IN R1
.ELSE(NOS0)
  $SET(R1=1)
.ENDIF(NOS0)
$IF, (R1 = 1) ,NOS1.
  $BEGIN(DISRNGB,VEMEM,#NOS,LOW,UP)
  $BEGIN(NOSQ,VEMEM,,,MF,LOW,UP,OPTION)  ** NOSQ RECALLS #NOS
$ELSE(NOS1)
  .* QUIT WAS CHOSEN.
  $IF, ($OPTION$ .EQ. $1$) ,NOS2)
    $BEGIN(DECKS,VEMEM,MF,NOS,VE,#OPTION=OPTION)
  $ELSE(NOS2)
    $BEGIN(MAIN_OPTION,VEMEM,MF,NOS,VE,#OPTION=OPTION)
  $ENDIF(NOS2)
$ENDIF(NOS1)
$REVERT. #NOS
$EXIT. #NOS
$REVERT(ABORT) #NOS FAILED
*WEOR
.PROC,VE*I
,MF      =(*A)
,VE      =(*A,*N=0)
,LOW     =(*A)
,UP      =(*A)
,OPTION  =(*A)
,FIRST   =(*N=NO,YES,NO)
,VEMEM   =(*N=#FILE)
.
.SET(#PT=STRD((MF+1023)/1024+8))  ** PAGE TABLE
.SET(#NOS=STRD(MF-VE-PT))  ** NOS MEMORY
.IF, (OPTION .EQ. 1) ,VE0.
  .IF, (NOS .GT. 2048) ,VE0A.
    .SET(#NOS=STRD(2048))
  .ENDIF,VE0A.
.ELSE,VE0.
  .IF, (NOS .GT. 16384) ,VE0B.
    .SET(#NOS=STRD(16384))
  .ENDIF,VE0B.
.ENDIF,VE0.
.IF, (VE .NE. 0), VE1.
  .SET(#VE=STRD(MF-NOS-PT))  ** VE MEMORY ADJUSTED
.ENDIF,VE1.
.IF, ($FIRST$ .EQ. $NO$) ,VE2.
  $NOTE.;;:I C^U^R^R^E^N^T ^C^H^O^I^C^E^S (M^B^Y^T^E^S,K^B^Y^T^E^S):;
  $BEGIN(DISPB,VEMEM,#PT,PT)
  $BEGIN(DISPB,VEMEM,#NOS,NOS)
  $BEGIN(DISPB,VEMEM,#VE,VE)
  $BEGIN(DISPB,VEMEM,#MF,MF)
  $BEGIN(CHOOSE1,VEMEM,$#VE$)  CHOICE RETURNS IN R1
.ELSE(VE2)
  $SET(R1=1)
.ENDIF(VE2)
$IF, (R1 = 1) ,VE3.
  $BEGIN(DISRNGB,VEMEM,#VE,LOW,UP)
  $BEGIN(VEQ,VEMEM,,,MF,LOW,UP,OPTION)  ** VEQ RECALLS #VE
$ELSE(VE3)
  .* QUIT WAS CHOSEN.
  $IF, ($OPTION$ .EQ. $1$) ,VE4)
    $BEGIN(DECKS,VEMEM,MF,NOS,VE,#OPTION=OPTION)
  $ELSE(VE4)
    $BEGIN(MAIN_OPTION,VEMEM,MF,NOS,VE,#OPTION=OPTION)
  $ENDIF(VE4)
$ENDIF(VE3)
$REVERT. #VE
$EXIT. #VE
$REVERT(ABORT) #VE FAILED
*WEOR
.PROC,MAIN2*I
,MF      =(*S6/D)
,NOS     =(*A)
,VE      =(*A)
,LOW     =(*N=0)
,OPTION  =(*A)
,VEMEM   =(*N=#FILE)
.
.* CHOOSE AN AMOUNT OF UEC MEMORY
.IF,(NOS.GT.2048),MAIN2A.
  .SET(#LOW=STRD(NOS-2048))  ** LOWER BOUND = NOS-16MB FOR JOBS
.ENDIF,MAIN2A.
.SET(#UP=STRD(NOS-128))  ** UPPER BOUND = NOS-1MB FOR JOBS
$BEGIN(UEC,VEMEM,MF,NOS,VE,0,LOW,UP,OPTION,FIRST=YES)
$REVERT. MAIN2 COMPLETE
$EXIT. MAIN2
$REVERT(ABORT) MAIN2 FAILED
*WEOR
.PROC,UEC*I
,MF      =(*A)
,NOS     =(*A)
,VE      =(*A)
,UEC     =(*A)
,LOW     =(*A)
,UP      =(*A)
,OPTION  =(*A)
,FIRST   =(*N=NO,YES,NO)
,VEMEM   =(*N=#FILE)
.
.SET(#JOBS=STRD(NOS-UEC))  ** SYSTEM AND JOB MEMORY
.IF, ($FIRST$ .EQ. $NO$) ,UEC0.
  $NOTE.;;:I C^U^R^R^E^N^T ^C^H^O^I^C^E^S (O^C^T^A^L/1000B ^W^O^R^D^S):;
  $BEGIN(DISPW,VEMEM,#JOBS,JOBS)
  $BEGIN(DISPW,VEMEM,#UEC,UEC)
  $BEGIN(DISPW,VEMEM,#NOS,NOS)
  $BEGIN(CHOOSE1,VEMEM,$#UEC$)  CHOICE RETURNS IN R1
.ELSE(UEC0)
  $SET(R1=1)
.ENDIF(UEC0)
$IF, (R1 = 1) ,UEC1.
  $BEGIN(DISRNGW,VEMEM,#UEC,LOW,UP)
  $BEGIN(UECQ,VEMEM,,MF,NOS,VE,LOW,UP,OPTION)  ** UECQ RECALLS #UEC
$ELSE(UEC1)
  .* QUIT WAS CHOSEN.
  .* NOW ALLOCATE UEC AND IOB
  $BEGIN(DECKS,VEMEM,MF,NOS,VE,#UEC=UEC,#OPTION=OPTION)
$ENDIF(UEC1)
$REVERT. #UEC
$EXIT. #UEC
$REVERT(ABORT) #UEC
*WEOR
.PROC,MAIN3*I
,MF      =(*S6/D)
,NOS     =(*A)
,VE      =(*A)
,OPTION  =(*A)
,LOW     =(*N=4)
,VEMEM   =(*N=#FILE)
.
.* CHOOSE AN AMOUNT OF UEM MEMORY
.* (4) = LOWER BOUND = 4 KWORDS
.IF,(NOS.GT.(2048+LOW)),MAIN3A.
  .SET(#LOW=STRD(NOS-2048))  ** LOWER BOUND = NOS-16MB FOR JOBS
.ENDIF,MAIN3A.
.SET(#UP=STRD(NOS-128))  ** UPPER BOUND = NOS-1MB FOR JOBS
.IF, (UP .LT. 4) ,MAIN3B.
  $NOTE.;;:I I^N^S^U^F^F^I^C^I^E^N^T #NOS ^M^E^M^O^R^Y ^T^O ^A^L^L^O^C^A^T^E
  $NOTE.;:I UEM.  P^L^E^A^S^E ^R^E-^S^T^A^R^T VEMEM.;
  $REVERT.
.ELSE(MAIN3B)
$BEGIN(UEM,VEMEM,MF,NOS,VE,0,LOW,UP,OPTION,FIRST=YES)
$REVERT. MAIN3 COMPLETE
.ENDIF(MAIN3B)
$EXIT. MAIN3
$REVERT(ABORT) MAIN3 FAILED
*WEOR
.PROC,UEM*I
,MF      =(*A)
,NOS     =(*A)
,VE      =(*A)
,UEM     =(*A)
,LOW     =(*A)
,UP      =(*A)
,OPTION  =(*A)
,FIRST   =(*N=NO,YES,NO)
,VEMEM   =(*N=#FILE)
.
.SET(#JOBS=STRD(NOS-UEM))  ** SYSTEM AND JOB MEMORY
.IF, ($FIRST$ .EQ. $NO$) ,UEM0.
  $NOTE.;;:I C^U^R^R^E^N^T ^C^H^O^I^C^E^S (O^C^T^A^L/1000B ^W^O^R^D^S):;
  $BEGIN(DISPW,VEMEM,#JOBS,JOBS)
  $BEGIN(DISPW,VEMEM,#UEM,UEM)
  $BEGIN(DISPW,VEMEM,#NOS,NOS)
  $BEGIN(CHOOSE1,VEMEM,$#UEM$)CHOICE RETURNS IN R1
.ELSE(UEM0)
  $SET(R1=1)
.ENDIF(UEM0)
$IF, (R1 = 1) ,UEM1.
  $BEGIN(DISRNGW,VEMEM,#UEM,LOW,UP)
  $BEGIN(UEMQ,VEMEM,,MF,NOS,VE,LOW,UP,OPTION)  ** UEMQ RECALLS #UEM
$ELSE(UEM1)
  .* QUIT WAS CHOSEN.
  .* NOW ALLOCATE UEC AND IOB
  $BEGIN(MAIN4,VEMEM,MF,NOS,VE,UEM,#OPTION=OPTION)
$ENDIF(UEM1)
$REVERT. #UEM
$EXIT. #UEM
$REVERT(ABORT) #UEM
*WEOR
.PROC,MAIN4*I
,MF      =(*S6/D)
,NOS     =(*A)
,VE      =(*A)
,UEM     =(*A)
,OPTION  =(*A)
,VEMEM   =(*N=#FILE)
.
.* CHOOSE AN AMOUNT OF UEC/IOB MEMORY
$BEGIN(UIO,VEMEM,MF,NOS,VE,UEM,0,0,OPTION,FIRST=YES)
$REVERT. MAIN4 COMPLETE
$EXIT. MAIN4
$REVERT(ABORT) MAIN4 FAILED
*WEOR
.PROC,UIO*I
,MF      =(*A)
,NOS     =(*A)
,VE      =(*A)
,UEM     =(*A)
,IOB     =(*A)
,UEC     =(*A)
,OPTION  =(*A)
,FIRST   =(*N=NO,YES,NO)
,VEMEM   =(*N=#FILE)
.
.SET(#ASR=STRD(UEM-IOB-UEC))  ** ASR AND SECONDARY ROLLOUT
.IF, ($FIRST$ .EQ. $NO$) ,UIO0.
  $NOTE.;;:I C^U^R^R^E^N^T ^C^H^O^I^C^E^S (O^C^T^A^L/1000B ^W^O^R^D^S):;
  $BEGIN(DISPW,VEMEM,#ASR,ASR)
  $BEGIN(DISPW,VEMEM,#IOB,IOB)
  $BEGIN(DISPW,VEMEM,#UEC,UEC)
  $BEGIN(DISPW,VEMEM,#UEMT,UEM)
  $BEGIN(CHOOSE1,VEMEM,$#IOB/#UEC$)  CHOICE RETURNS IN R1
.ELSE(UIO0)
  $SET(R1=1)
.ENDIF(UIO0)
$IF, (R1 = 1) ,UIO1.
  $BEGIN(DISRNGW,VEMEM,#IOB,16,UEM)
  $BEGIN(DISRNGW,VEMEM,#UEC,0,UEM)
  $BEGIN(UIOQ,VEMEM,,,MF,NOS,VE,UEM,OPTION)  ** UIOQ RECALLS UIO
$ELSE(UIO1)
  .* QUIT WAS CHOSEN.
  $BEGIN(DECKS,VEMEM,MF,NOS,VE,UEM,IOB,UEC,#OPTION=OPTION)
$ENDIF(UIO1)
$REVERT. UIO
$EXIT. UIO
$REVERT(ABORT) UIO
*WEOR
.PROC,CHOOSE1*I
,ARG     =(*A)
,DF      =(*N=#DATA)
.
$NOTE.
$REVERT(EX)$BEGIN,DF,DF.
.DATA,DF.
.PROC,DF*I
,CHOICE [C^H^A^N^G^E ARG ^A^L^L^O^C^A^T^I^O^N (Y^E^S ^O^R N^O)] =(Y=1,YES=1,YE=1,NO=0,N=0)
.
$UNLOAD,DF.
$REVERT(EX)$SET(R1=CHOICE)
*WEOR
.PROC,VENOS*M
,CHOICE=
(1 "S^P^E^C^I^F^Y ^A^M^O^U^N^T ^O^F ^M^E^M^O^R^Y ^F^O^R NOS"
,2 "S^P^E^C^I^F^Y ^A^M^O^U^N^T ^O^F ^M^E^M^O^R^Y ^F^O^R NOS/VE")
.
.HELP
Y^O^U ^M^A^Y ^C^H^O^O^S^E ^T^O:
1) A^L^L^O^C^A^T^E ^A ^S^P^E^C^I^F^I^C ^A^M^O^U^N^T ^O^F ^Y^O^U^R ^M^A^I^N^F^R^A^M^E^S ^M^E^M^O^R^Y ^F^O^R NOS
    (^I^N^C^L^U^D^I^N^G UEM, UEC ^A^N^D/^O^R IOB ^I^F ^A^P^P^L^I^C^A^B^L^E) ^A^N^D ^G^I^V^E ^T^H^E
    ^R^E^M^A^I^N^D^E^R ^O^F ^M^E^M^O^R^Y ^T^O NOS/VE.
2)  A^L^L^O^C^A^T^E ^A ^S^P^E^C^I^F^I^C ^A^M^O^U^N^T ^O^F ^Y^O^U^R ^M^A^I^N^F^R^A^M^E^S ^M^E^M^O^R^Y ^F^O^R NOS/VE ^A^N^D
    ^G^I^V^E ^T^H^E ^R^E^M^A^I^N^D^E^R ^T^O NOS (^I^N^C^L^U^D^I^N^G UEM, UEC, ^A^N^D/^O^R IOB ^I^F
    ^A^P^P^L^I^C^A^B^L^E).
.HELP,1
B^Y ^S^E^L^E^C^T^I^N^G ^T^H^I^S ^O^P^T^I^O^N, ^Y^O^U ^W^I^L^L ^B^E ^P^R^O^M^P^T^E^D ^T^O ^S^E^L^E^C^T ^A ^S^P^E^C^I^F^I^C
^A^M^O^U^N^T ^O^F ^M^E^M^O^R^Y (^I^N ^M^E^G^A^B^Y^T^E^S) ^F^O^R NOS.  T^H^E ^R^E^M^A^I^N^D^E^R ^O^F ^Y^O^U^R ^M^E^M^O^R^Y
^W^I^L^L ^B^E ^A^L^L^O^C^A^T^E^D ^F^O^R NOS/VE.
.HELP,2
B^Y ^S^E^L^E^C^T^I^N^G ^T^H^I^S ^O^P^T^I^O^N, ^Y^O^U ^W^I^L^L ^B^E ^P^R^O^M^P^T^E^D ^T^O ^S^E^L^E^C^T ^A ^S^P^E^C^I^F^I^C
^A^M^O^U^N^T ^O^F ^M^E^M^O^R^Y (^I^N ^M^E^G^A^B^Y^T^E^S) ^F^O^R NOS/VE.  T^H^E ^R^E^M^A^I^N^D^E^R ^O^F ^Y^O^U^R
^M^E^M^O^R^Y ^W^I^L^L ^B^E ^A^L^L^O^C^A^T^E^D ^F^O^R NOS.
.ENDHELP
$REVERT(EX)$SET(R1=CHOICE)
*WEOR
.PROC,MF*I"S^P^E^C^I^F^Y ^T^H^E ^A^M^O^U^N^T ^O^F ^M^A^I^N^F^R^A^M^E ^M^E^M^O^R^Y."
,MBYTE [M^E^G^A^B^Y^T^E ^P^O^R^T^I^O^N ^O^F ^P^H^Y^S^I^C^A^L ^M^E^M^O^R^Y(8-256)] =(*S3/D)
,KBYTE [K^I^L^O^B^Y^T^E ^P^O^R^T^I^O^N ^O^F ^P^H^Y^S^I^C^A^L ^M^E^M^O^R^Y(0-960)] =(*S3/D,*N=0)
,LOW   =(*N=8)
,UP    =(*N=256)
,VEMEM =(*N=#FILE)
.
.HELP.
S^U^P^P^L^Y ^T^H^E ^A^M^O^U^N^T ^O^F ^P^H^Y^S^I^C^A^L ^M^E^M^O^R^Y (^M^E^M^O^R^Y ^T^O ^B^E ^U^S^E^D ^B^Y ^B^O^T^H
NOS ^A^N^D NOS/VE) ^O^N ^Y^O^U^R ^M^A^I^N^F^R^A^M^E.  T^H^I^S ^V^A^L^U^E ^I^S ^G^I^V^E^N ^I^N ^T^E^R^M^S
^O^F
       M^B^Y^T^E^S,K^B^Y^T^E^S
T^H^A^T ^I^S: ^I^N^T^E^G^E^R ^A^M^O^U^N^T ^I^N ^M^E^G^A^B^Y^T^E^S ^C^O^M^M^A ^F^R^A^C^T^I^O^N^A^L ^A^M^O^U^N^T ^I^N
^K^I^L^O^B^Y^T^E^S.

I^F ^Y^O^U^R ^P^H^Y^S^I^C^A^L ^M^E^M^O^R^Y ^S^I^Z^E ^I^S 16 ^M^E^G^A^B^Y^T^E^S, ^Y^O^U
^W^O^U^L^D ^E^N^T^E^R:
  16,0
.HELP,MBYTE,NOLIST.
H^O^W ^M^U^C^H ^P^H^Y^S^I^C^A^L ^M^E^M^O^R^Y ^Y^O^U ^H^A^V^E, ^I^N ^I^N^T^E^G^E^R ^M^E^G^A^B^Y^T^E^S,^K^I^L^O^B^Y^T^E^S.  F^O^R
^E^X^A^M^P^L^E, ^I^F ^Y^O^U ^H^A^V^E 16 ^M^E^G^A^B^Y^T^E^S ^O^F ^P^H^Y^S^I^C^A^L ^M^E^M^O^R^Y, ^E^N^T^E^R 16,0.

I^F ^Y^O^U ^H^A^V^E ^A ^N^O^N-^I^N^T^E^G^E^R ^M^E^G^A^B^Y^T^E ^A^M^O^U^N^T ^O^F ^P^H^Y^S^I^C^A^L ^M^E^M^O^R^Y, ^E^N^T^E^R ^T^H^E
^I^N^T^E^G^E^R ^P^O^R^T^I^O^N, ^A ^C^O^M^M^A, ^A^N^D ^T^H^E ^R^E^M^A^I^N^D^E^R ^I^N ^K^I^L^O^B^Y^T^E^S.
F^O^R ^E^X^A^M^P^L^E, ^I^F ^Y^O^U ^H^A^V^E 8.5 ^M^E^G^A^B^Y^T^E^S ^O^F ^P^H^Y^S^I^C^A^L ^M^E^M^O^R^Y, ^E^N^T^E^R:
   8,512
.HELP,KBYTE,NOLIST.
A^N^Y ^M^O^R^E ^P^H^Y^S^I^C^A^L ^M^E^M^O^R^Y ^T^H^A^T ^Y^O^U ^H^A^V^E, AFTER ^Y^O^U ^H^A^V^E ^E^X^P^R^E^S^S^E^D ^I^T ^I^N
^M^E^G^A^B^Y^T^E^S.  E^N^T^E^R ^A ^V^A^L^U^E ^F^O^R ^T^H^I^S ^O^N^L^Y ^I^F ^Y^O^U ^H^A^V^E ^A ^N^O^N-^I^N^T^E^G^E^R
^M^E^G^A^B^Y^T^E ^A^M^O^U^N^T ^O^F ^P^H^Y^S^I^C^A^L ^M^E^M^O^R^Y.  F^O^R ^E^X^A^M^P^L^E, ^I^F ^Y^O^U ^H^A^V^E 8.5
^M^E^G^A^B^Y^T^E^S ^O^F ^P^H^Y^S^I^C^A^L ^M^E^M^O^R^Y, ^Y^O^U ^W^O^U^L^D ^E^N^T^E^R:
   512
^A^T ^T^H^I^S ^P^R^O^M^P^T ^F^O^R ^T^H^E ^N^O^N-^I^N^T^E^G^E^R (.5) ^M^E^G^A^B^Y^T^E ^P^O^R^T^I^O^N ^O^F ^Y^O^U^R
^P^H^Y^S^I^C^A^L ^M^E^M^O^R^Y.

T^H^E ^F^O^L^L^O^W^I^N^G ^T^A^B^L^E ^L^I^S^T^S ^T^H^E ^K^I^L^O^B^Y^T^E ^V^A^L^U^E ^F^O^R ^F^R^A^C^T^I^O^N^S ^O^F
^M^E^G^A^B^Y^T^E^S.
    K^I^L^O^B^Y^T^E       F^R^A^C^T^I^O^N ^O^F ^A M^E^G^A^B^Y^T^E
       64                  1/16
      128                  1/8
      192                  3/16
      256                  1/4
      320                  5/16
      384                  3/8
      448                  7/16
      512                  1/2
      576                  9/16
      640                  5/8
      704                  11/16
      768                  3/4
      832                  13/16
      896                  7/8
      960                  15/16
.ENDHELP
.*
.SET(#KBYTE=STRD(((KBYTE+63)/64)*64)).
.IF, (MBYTE .LT. LOW) .OR. (MBYTE*128+KBYTE/8 .GT. UP*128) ,MF1.
  $NOTE.;;:I M^E^M^O^R^Y ^R^A^N^G^E ^I^S LOW - UP ^M^E^G^A^B^Y^T^E^S.
  $NOTE.;:I P^L^E^A^S^E ^R^E-^E^N^T^E^R.;
  $REVERT(EX)$BEGIN(MF,VEMEM)
.ENDIF(MF1)
.*  RETURN MBYTE IN R2, KBYTE IN R3.
$REVERT,EX.$SET(R2=MBYTE,R3=KBYTE)
$EXIT. MF
$REVERT(ABORT) MF
*WEOR
.PROC,VEQ*I"S^P^E^C^I^F^Y ^T^H^E ^A^M^O^U^N^T ^O^F NOS/VE ^M^E^M^O^R^Y."
,MBYTE [M^E^G^A^B^Y^T^E ^P^O^R^T^I^O^N ^O^F VE ^M^E^M^O^R^Y] =(*S1..3/D)
,KBYTE [K^I^L^O^B^Y^T^E ^P^O^R^T^I^O^N ^O^F ^M^A^I^N^F^R^A^M^E ^M^E^M^O^R^Y] =(*S3/D,*N=0)
,MF      =(*A)
,LOW     =(*A)
,UP      =(*A)
,OPTION  =(*A)
,VEMEM   =(*N=#FILE)
.
.HELP,MBYTE,NOLIST.
 H^O^W ^M^U^C^H ^M^E^M^O^R^Y NOS/VE ^I^S ^T^O ^U^S^E, ^I^N ^I^N^T^E^G^E^R
   ^M^E^G^A^B^Y^T^E^S,^K^I^L^O^B^Y^T^E^S
 F^O^R ^E^X^A^M^P^L^E, ^T^O ^S^P^E^C^I^F^Y NOS/VE ^I^S ^T^O ^U^S^E 16 ^M^E^G^A^B^Y^T^E^S ^O^F
^M^E^M^O^R^Y, ^E^N^T^E^R
   16,0
 T^O ^S^P^E^C^I^F^Y ^A ^N^O^N-^I^N^T^E^G^E^R ^M^E^G^A^B^Y^T^E ^A^M^O^U^N^T ^O^F ^M^E^M^O^R^Y,
^E^N^T^E^R ^T^H^E ^I^N^T^E^G^E^R ^P^O^R^T^I^O^N, ^A ^C^O^M^M^A, ^A^N^D ^T^H^E ^R^E^M^A^I^N^D^E^R ^I^N
^K^I^L^O^B^Y^T^E^S.
 F^O^R ^E^X^A^M^P^L^E, ^T^O ^S^P^E^C^I^F^Y 8.5 ^M^E^G^A^B^Y^T^E^S ^O^F ^M^E^M^O^R^Y, ^E^N^T^E^R
   8,512

 NOTE: ^Y^O^U ^M^U^S^T ^R^E^S^E^R^V^E ^A ^M^I^N^I^M^U^M ^O^F 6.5 ^M^E^G^A^B^Y^T^E^S ^F^O^R NOS/VE.
.HELP,KBYTE,NOLIST.
 A^N^Y ^M^O^R^E NOS/VE ^M^E^M^O^R^Y, AFTER ^Y^O^U ^H^A^V^E ^E^X^P^R^E^S^S^E^D ^I^T ^I^N
^M^E^G^A^B^Y^T^E^S.  E^N^T^E^R ^A ^V^A^L^U^E ^F^O^R ^T^H^I^S ^O^N^L^Y ^I^F ^Y^O^U ^H^A^V^E ^A
^N^O^N-^I^N^T^E^G^E^R ^M^E^G^A^B^Y^T^E ^A^M^O^U^N^T ^O^F ^M^E^M^O^R^Y ^F^O^R NOS/VE.
 F^O^R ^E^X^A^M^P^L^E, ^T^O ^S^P^E^C^I^F^Y 8.5 ^M^E^G^A^B^Y^T^E^S ^O^F ^M^E^M^O^R^Y ^F^O^R NOS/VE,
^Y^O^U ^W^O^U^L^D ^E^N^T^E^R
   512
 ^A^T ^T^H^I^S ^P^R^O^M^P^T ^F^O^R ^T^H^E ^N^O^N-^I^N^T^E^G^E^R (.5) ^M^E^G^A^B^Y^T^E ^P^O^R^T^I^O^N ^O^F
^Y^O^U^R ^M^E^M^O^R^Y ^A^M^O^U^N^T.

 T^H^E ^F^O^L^L^O^W^I^N^G ^T^A^B^L^E ^L^I^S^T^S ^T^H^E ^K^I^L^O^B^Y^T^E ^V^A^L^U^E ^F^O^R ^F^R^A^C^T^I^O^N^S ^O^F
^M^E^G^A^B^Y^T^E^S.
    K^I^L^O^B^Y^T^E       F^R^A^C^T^I^O^N ^O^F ^A M^E^G^A^B^Y^T^E
       64                  1/16
      128                  1/8
      192                  3/16
      256                  1/4
      320                  5/16
      384                  3/8
      448                  7/16
      512                  1/2
      576                  9/16
      640                  5/8
      704                  11/16
      768                  3/4
      832                  13/16
      896                  7/8
      960                  15/16
.ENDHELP
.*
.SET(#VE=STRD(MBYTE*128+((KBYTE+63)/64)*8))
.IF, (VE .GT. 0) .AND. ((VE .LT. LOW) .OR. (VE .GT. UP)) ,VE1.
  .SET(N1=STRD(LOW/128),N2=STRD(UP/128))
  $NOTE.;;:I M^E^M^O^R^Y ^R^A^N^G^E ^F^O^R #VE ^I^S N1 - N2 ^M^E^G^A^B^Y^T^E^S.
  $NOTE.;:I P^L^E^A^S^E ^R^E-^E^N^T^E^R.;
  $REVERT,EX.$BEGIN(VEQ,VEMEM,,,MF,LOW,UP,OPTION)
.ENDIF(VE1)
$REVERT(EX)$REVERT(EX)$BEGIN(#VE,VEMEM,MF,VE,LOW,UP,OPTION)
$EXIT. VEQ
$REVERT(ABORT) VEQ
*WEOR
.PROC,NOSQ*I"S^P^E^C^I^F^Y ^T^H^E ^A^M^O^U^N^T ^O^F NOS ^M^E^M^O^R^Y."
,MBYTE [M^E^G^A^B^Y^T^E ^P^O^R^T^I^O^N ^O^F NOS ^M^E^M^O^R^Y] =(*S1..3/D)
,KBYTE [K^I^L^O^B^Y^T^E ^P^O^R^T^I^O^N ^O^F ^M^A^I^N^F^R^A^M^E ^M^E^M^O^R^Y] =(*S3/D,*N=0)
,MF      =(*A)
,LOW     =(*A,*N=1)
,UP      =(*A,*N=128)
,OPTION  =(*A)
,VEMEM   =(*N=#FILE)
.
.HELP,MBYTE,NOLIST.
 H^O^W ^M^U^C^H ^M^E^M^O^R^Y NOS ^I^S ^T^O ^U^S^E, ^I^N ^I^N^T^E^G^E^R
   ^M^E^G^A^B^Y^T^E^S,^K^I^L^O^B^Y^T^E^S
 F^O^R ^E^X^A^M^P^L^E, ^T^O ^S^P^E^C^I^F^Y NOS ^I^S ^T^O ^U^S^E 16 ^M^E^G^A^B^Y^T^E^S ^O^F
^M^E^M^O^R^Y, ^E^N^T^E^R
   16,0
 T^O ^S^P^E^C^I^F^Y ^A ^N^O^N-^I^N^T^E^G^E^R ^M^E^G^A^B^Y^T^E ^A^M^O^U^N^T ^O^F ^M^E^M^O^R^Y,
^E^N^T^E^R ^T^H^E ^I^N^T^E^G^E^R ^P^O^R^T^I^O^N, ^A ^C^O^M^M^A, ^A^N^D ^T^H^E ^R^E^M^A^I^N^D^E^R ^I^N
^K^I^L^O^B^Y^T^E^S.
 F^O^R ^E^X^A^M^P^L^E, ^T^O ^S^P^E^C^I^F^Y 8.5 ^M^E^G^A^B^Y^T^E^S ^O^F ^M^E^M^O^R^Y, ^E^N^T^E^R
   8,512

 T^H^I^S ^T^A^B^L^E ^L^I^S^T^S ^E^Q^U^I^V^A^L^E^N^C^E^S ^O^F ^M^E^M^O^R^Y ^S^I^Z^E^S ^I^N ^M^E^G^A^B^Y^T^E^S,^K^I^L^O^B^Y^T^E^S,
^W^O^R^D^S ^I^N ^O^C^T^A^L, ^A^N^D ^W^O^R^D^S ^I^N ^D^E^C^I^M^A^L.
  M^E^G^A^B^Y^T^E^S,K^I^L^O^B^Y^T^E^S        W^O^R^D^S (^O^C^T^A^L)       W^O^R^D^S (^D^E^C^I^M^A^L)
          1,0                  400000             131072
          1,512                600000             196608
          2,0                 1000000             262144
          3,0                 1400000             393216
          4,0                 2000000             524288
          8,0                 4000000            1048576
         16,0                10000000            2097152
         32,0                20000000            4194304
         64,0                40000000            8388608
        128,0               100000000           16777216

 NOTE:  Y^O^U ^M^U^S^T ^R^E^S^E^R^V^E ^A ^M^I^N^I^M^U^M ^O^F 1 ^M^E^G^A^B^Y^T^E ^F^O^R NOS.
NOS ^C^A^N ^U^S^E ^A ^M^A^X^I^M^U^M ^O^F 128 ^M^E^G^A^B^Y^T^E^S.
.HELP,KBYTE,NOLIST.
 A^N^Y ^M^O^R^E NOS ^M^E^M^O^R^Y, AFTER ^Y^O^U ^H^A^V^E ^E^X^P^R^E^S^S^E^D ^I^T ^I^N
^M^E^G^A^B^Y^T^E^S.  E^N^T^E^R ^A ^V^A^L^U^E ^F^O^R ^T^H^I^S ^O^N^L^Y ^I^F ^Y^O^U ^H^A^V^E ^A
^N^O^N-^I^N^T^E^G^E^R ^M^E^G^A^B^Y^T^E ^A^M^O^U^N^T ^O^F ^M^E^M^O^R^Y ^F^O^R NOS.
 F^O^R ^E^X^A^M^P^L^E, ^T^O ^S^P^E^C^I^F^Y 8.5 ^M^E^G^A^B^Y^T^E^S ^O^F ^M^E^M^O^R^Y ^F^O^R NOS,
^Y^O^U ^W^O^U^L^D ^E^N^T^E^R
   512
 ^A^T ^T^H^I^S ^P^R^O^M^P^T ^F^O^R ^T^H^E ^N^O^N-^I^N^T^E^G^E^R (.5) ^M^E^G^A^B^Y^T^E ^P^O^R^T^I^O^N ^O^F
^Y^O^U^R ^M^E^M^O^R^Y ^A^M^O^U^N^T.

 T^H^E ^F^O^L^L^O^W^I^N^G ^T^A^B^L^E ^L^I^S^T^S ^T^H^E ^K^I^L^O^B^Y^T^E ^V^A^L^U^E ^F^O^R ^F^R^A^C^T^I^O^N^S ^O^F
^M^E^G^A^B^Y^T^E^S.
    K^I^L^O^B^Y^T^E       F^R^A^C^T^I^O^N ^O^F ^A M^E^G^A^B^Y^T^E
       64                  1/16
      128                  1/8
      192                  3/16
      256                  1/4
      320                  5/16
      384                  3/8
      448                  7/16
      512                  1/2
      576                  9/16
      640                  5/8
      704                  11/16
      768                  3/4
      832                  13/16
      896                  7/8
      960                  15/16
.ENDHELP
.SET(#NOS=STRD(MBYTE*128+((KBYTE+63)/64)*8))
.IF, (NOS .LT. LOW) .OR. (NOS .GT. UP) ,NOS2.
  .SET(N1=STRD(LOW/128),N2=STRD(UP/128))
  $NOTE.;;:I M^E^M^O^R^Y ^R^A^N^G^E ^F^O^R #NOS ^I^S N1 - N2 ^M^E^G^A^B^Y^T^E^S.
  $NOTE.;:I P^L^E^A^S^E ^R^E-^E^N^T^E^R.;
  $REVERT,EX.$BEGIN(NOSQ,VEMEM,,,MF,LOW,UP,OPTION)
.ENDIF(NOS2)
$REVERT(EX)$REVERT(EX)$BEGIN(#NOS,VEMEM,MF,NOS,LOW,UP,OPTION)
$EXIT. NOSQ
$REVERT(ABORT) NOSQ
*WEOR
.PROC,UIOQ*I"A^L^L^O^C^A^T^E I/O B^U^F^F^E^R^S ^A^N^D U^S^E^R E^X^T^E^N^D^E^D M^E^M^O^R^Y"
,IOB [O^C^T^A^L/1000B ^W^O^R^D^S ^M^E^M^O^R^Y ^F^O^R IOB] =(*S6/B)
,UEC [O^C^T^A^L/1000B ^W^O^R^D^S ^M^E^M^O^R^Y ^F^O^R UEC] =(*S6/B)
,MF      =(*A)
,NOS     =(*A)
,VE      =(*A)
,UEM   =(*A)
,OPTION  =(*A)
,VEMEM =(*N=#FILE)
.
.HELP,IOB,NOLIST.
 A^N ^O^C^T^A^L ^V^A^L^U^E ^S^P^E^C^I^F^Y^I^N^G ^T^H^E ^A^M^O^U^N^T ^O^F ^M^E^M^O^R^Y ^T^O ^B^E ^R^E^S^E^R^V^E^D
^F^O^R ^I^N^P^U^T/^O^U^T^P^U^T ^D^E^V^I^C^E ^B^U^F^F^E^R^S ^F^O^R 895-^T^Y^P^E ^D^I^S^K ^D^R^I^V^E^S.
 T^H^I^S ^O^C^T^A^L ^V^A^L^U^E ^I^S ^I^N ^U^N^I^T^S ^O^F 1000 ^O^C^T^A^L ^W^O^R^D^S.
.HELP,UEC,NOLIST.
 A^N ^O^C^T^A^L ^V^A^L^U^E ^S^P^E^C^I^F^Y^I^N^G ^T^H^E ^A^M^O^U^N^T ^O^F ^M^E^M^O^R^Y ^T^O ^B^E ^R^E^S^E^R^V^E^D
^F^O^R ^U^S^E^R ^A^C^C^E^S^S^I^B^L^E ^E^X^T^E^N^D^E^D ^M^E^M^O^R^Y.
 T^H^I^S ^O^C^T^A^L ^V^A^L^U^E ^I^S ^I^N ^U^N^I^T^S ^O^F 1000 ^O^C^T^A^L ^W^O^R^D^S.
.ENDHELP
.*
.* VALIDATE IOB
.IF, (IOB .NE. 0) ,UIOQ1.
  .SET(#IOB=STRD(IOB_B/2))
  .IF, (IOB .LT. 16) .OR. (IOB .GT. UEM) ,UIOQ1A.
    $NOTE.;;:I #IOB ^M^E^M^O^R^Y ^V^A^L^U^E ^O^U^T ^O^F ^R^A^N^G^E.
    $BEGIN(DISRNGW,VEMEM,#IOB,16,UEM)
    $BEGIN(DISRNGW,VEMEM,#UEC,0,UEM)
    $NOTE.;:I P^L^E^A^S^E ^R^E-^E^N^T^E^R.
    $REVERT,EX.$BEGIN(UIOQ,VEMEM,,,MF,NOS,VE,UEM,OPTION)
  .ENDIF(UIOQ1A)
.ENDIF(UIOQ1)
.* VALIDATE UEC
.SET(#UEC=STRD(UEC_B/2))
.IF, (UEC .GT. UEM) ,UIOQ2.
  $NOTE.;;:I #UEC ^M^E^M^O^R^Y ^V^A^L^U^E ^O^U^T ^O^F ^R^A^N^G^E.
  $BEGIN(DISRNGW,VEMEM,#IOB,16,UEM)
  $BEGIN(DISRNGW,VEMEM,#UEC,0,UEM)
  $NOTE.;:I P^L^E^A^S^E ^R^E-^E^N^T^E^R.
  $REVERT,EX.$BEGIN(UIOQ,VEMEM,,,MF,NOS,VE,UEM,OPTION)
.ENDIF(UIOQ2)
.* VALIDATE UEC+IOB
.IF, (IOB+UEC .GT. UEM) ,UIOQ3.
  $NOTE.;;:I #IOB+#UEC ^M^E^M^O^R^Y ^V^A^L^U^E ^O^U^T ^O^F ^R^A^N^G^E.
  $BEGIN(DISRNGW,VEMEM,#IOB,16,UEM)
  $BEGIN(DISRNGW,VEMEM,#UEC,0,UEM)
  $NOTE.;:I P^L^E^A^S^E ^R^E-^E^N^T^E^R.
  $REVERT,EX.$BEGIN(UIOQ,VEMEM,,,MF,NOS,VE,UEM,OPTION)
.ENDIF(UIOQ3)
$REVERT(EX)$REVERT(EX)$BEGIN(UIO,VEMEM,MF,NOS,VE,UEM,IOB,UEC,OPTION)
$EXIT. UIOQ
$REVERT(ABORT) UIOQ
*WEOR
.PROC,UECQ*I"A^L^L^O^C^A^T^E U^S^E^R A^C^C^E^S^S^I^B^L^E E^X^T^E^N^D^E^D M^E^M^O^R^Y"
,WORDS [O^C^T^A^L/1000B ^W^O^R^D^S M^E^M^O^R^Y ^F^O^R UEC] =(*S1..6/B)
,MF      =(*A)
,NOS     =(*A)
,VE      =(*A)
,LOW     =(*A)
,UP      =(*A)
,OPTION  =(*A)
,VEMEM   =(*N=#FILE)
.
.HELP,WORDS,NOLIST.
 A^N ^O^C^T^A^L ^V^A^L^U^E ^S^P^E^C^I^F^Y^I^N^G ^T^H^E ^A^M^O^U^N^T ^O^F ^M^E^M^O^R^Y ^T^O ^B^E ^R^E^S^E^R^V^E^D
^F^O^R ^U^S^E^R ^A^C^C^E^S^S^I^B^L^E ^E^X^T^E^N^D^E^D ^M^E^M^O^R^Y.
 T^H^I^S ^O^C^T^A^L ^V^A^L^U^E ^I^S ^I^N ^U^N^I^T^S ^O^F 1000 ^O^C^T^A^L ^W^O^R^D^S.
.ENDHELP
.SET(#UEC=STRD(WORDS_B/2))
.IF,((UEC .LT. LOW).OR.(UEC .GT. UP)),UEC1A.
  $NOTE.;;:I #UEC M^E^M^O^R^Y ^V^A^L^U^E ^I^S ^O^U^T ^O^F ^R^A^N^G^E.
  $BEGIN(DISRNGW,VEMEM,$#UEC$,LOW,UP)
  $NOTE.;:I P^L^E^A^S^E ^R^E-^E^N^T^E^R.
  $REVERT,EX.$BEGIN(UECQ,VEMEM,,MF,NOS,VE,LOW,UP,OPTION)
.ENDIF,UEC1A
$REVERT(EX)$REVERT(EX)$BEGIN(#UEC,VEMEM,MF,NOS,VE,UEC,LOW,UP,OPTION)
$EXIT. UECQ
$REVERT(ABORT) UECQ
*WEOR
.PROC,UEMQ*I"A^L^L^O^C^A^T^E U^N^I^F^I^E^D E^X^T^E^N^D^E^D M^E^M^O^R^Y"
,WORDS [O^C^T^A^L/1000B ^W^O^R^D^S M^E^M^O^R^Y ^F^O^R UEM] =(*S1..6/B)
,MF      =(*A)
,NOS     =(*A)
,VE      =(*A)
,LOW     =(*A)
,UP      =(*A)
,OPTION  =(*A)
,VEMEM   =(*N=#FILE)
.
.HELP,WORDS,NOLIST.
 A^N ^O^C^T^A^L ^V^A^L^U^E ^S^P^E^C^I^F^Y^I^N^G ^T^H^E ^A^M^O^U^N^T ^O^F ^M^E^M^O^R^Y ^T^O ^B^E ^R^E^S^E^R^V^E^D
^F^O^R ^U^N^I^F^I^E^D ^E^X^T^E^N^D^E^D ^M^E^M^O^R^Y.
 T^H^I^S ^O^C^T^A^L ^V^A^L^U^E ^I^S ^I^N ^U^N^I^T^S ^O^F 1000 ^O^C^T^A^L ^W^O^R^D^S.
.ENDHELP
.SET(#UEM=STRD(WORDS_B/2))
.IF,((UEM .LT. LOW).OR.(UEM .GT. UP)),UEM1A.
  $NOTE.;;:I #UEM M^E^M^O^R^Y ^V^A^L^U^E ^I^S ^O^U^T ^O^F ^R^A^N^G^E.
  $BEGIN(DISRNGW,VEMEM,#UEM,LOW,UP)
  $NOTE.;:I P^L^E^A^S^E ^R^E-^E^N^T^E^R.
  $REVERT(EX)$BEGIN(UEMQ,VEMEM,,MF,NOS,VE,LOW,UP,OPTION)
.ENDIF,UEM1A
$REVERT(EX)$REVERT(EX)$BEGIN(#UEM,VEMEM,MF,NOS,VE,UEM,LOW,UP,OPTION)
$EXIT. UEMQ
$REVERT(ABORT) UEMQ
*WEOR
.PROC,DECKS*I
,MF      =(*A)
,NOS     =(*A)
,VE      =(*N=0,*A)
,UEM     =(*N=0,*A)
,IOB     =(*N=0,*A)
,UEC     =(*N=0,*A)
,OPTION  =(*A)
,VEMEM   =(*N=#FILE)
.
.SET(#NOS=STRB(NOS*16)) ** CONVERT TO OCTAL/100B
.SET(#VE=STRB(VE*2))    ** CONVERT TO OCTAL/1000B
.SET(#UEC=STRB(UEC*2))  ** CONVERT TO OCTAL/1000B
.SET(#IOB=STRB(IOB*2))  ** CONVERT TO OCTAL/1000B
.SET(#UEM=STRB(UEM*2))  ** CONVERT TO OCTAL/1000B
$RETURN(CMREQP)
.IF, ($OPTION$ .EQ. $1$) ,DECKS1.
  .* NOS/VE, NOS, NO UEM, NO UEC
  $NOTE.;;;:I M^A^K^E ^T^H^E ^F^O^L^L^O^W^I^N^G CMR ^D^E^C^K ^E^N^T^R^I^E^S:;
  .IF, (VE .EQ. 0) ,DECKS1A.
    $BEGIN(DISVAL,VEMEM,$#VE=$, *)
  .ELSE,DECKS1A.
    $BEGIN(DISVAL,VEMEM,$MINCM=$,NOS)
    $BEGIN(DISVAL,VEMEM,$#VE=$, 0)
  .ENDIF,DECKS1A.
.ELSE(DECKS1)
.IF, (VE .EQ. 0) ,DECKS2.
  .SET(#VE=STR($*$))    ** EXCLUDE NOS/VE
.ENDIF,DECKS2.
.IF, ($OPTION$ .EQ. $2$) ,DECKS1.
  .* NOS/VE, NOS, NO UEM, YES UEC
  $NOTE.;;;:I M^A^K^E ^T^H^E ^F^O^L^L^O^W^I^N^G CMR ^D^E^C^K ^E^N^T^R^I^E^S:;
  $BEGIN(DISVAL,VEMEM,$#VE=$,VE)
  .IF, (UEC .NE. 0) ,DECKS3.
    $NOTE.;;:I M^A^K^E ^T^H^E ^F^O^L^L^O^W^I^N^G EQP ^D^E^C^K ^E^N^T^R^I^E^S:;
    $BEGIN(DISVAL,VEMEM,$XM=MCHID,0,$,UEC,$,EM$)
    $NOTE.;;:I W^H^E^R^E MCHID ^I^S ^Y^O^U^R ^M^A^C^H^I^N^E ID.
    $NOTE.;:I (CMRDECK ^E^N^T^R^Y MID.)
  .ENDIF(DECKS3)
.ELSE(DECKS1)
  .* NOS/VE, NOS, UEM, MAYBE IOB AND UEC
  $NOTE.;;;:I M^A^K^E ^T^H^E ^F^O^L^L^O^W^I^N^G CMR ^D^E^C^K ^E^N^T^R^I^E^S:;
  $BEGIN(DISVAL,VEMEM,$#VE=$,VE)
  $NOTE.;;;:I M^A^K^E ^T^H^E ^F^O^L^L^O^W^I^N^G EQP ^D^E^C^K ^E^N^T^R^I^E^S:;
  $BEGIN(DISVAL,VEMEM,$EQ5=DE,ST=ON,ET=EM,SZ=$,UEM)
  .IF, (IOB .NE. 0) .OR. (UEC .NE. 0) ,DECKS1A.
    $BEGIN(DISVAL,VEMEM,$XM=MCHID,$,IOB,$,$,UEC)
    $NOTE.;;:I W^H^E^R^E MCHID ^I^S ^Y^O^U^R ^M^A^C^H^I^N^E ID.
    $NOTE.;:I (CMRDECK ^E^N^T^R^Y MID.)
  .ENDIF(DECKS1A)
.ENDIF(DECKS1)
$NOTE.;;:I E^N^T^R^I^E^S ^P^L^A^C^E^D ^O^N ^L^O^C^A^L ^F^I^L^E CMREQP.;;
$PACK(CMREQP)
$REVERT. DECKS COMPLETE
$EXIT. DECKS
$REVERT(ABORT) DECKS
*WEOR
.PROC,DISVAL*I
,MSG1    =(*A)
,VAL1    =(*S6/B*)
,MSG2    =(*A,*N=)
,VAL2    =(*S6/B*,*N=)
.
$NOTE.;MSG1_VAL1_MSG2_VAL2.
$NOTE,CMREQP,NR.;MSG1_VAL1_MSG2_VAL2.
$REVERT. DISVAL
*WEOR
.PROC,DISRNGB*I
,WORD   =(*A)
,LOW    =(*S6/D)
,UP     =(*S6/D)
,VEMEM  =(*N=#FILE)
.
.SET(#L1=STRD(LOW/128))
.SET(#L2=STRD((LOW-L1*128)*8))
.SET(#L1=STR($  _L1$,-3),#L2=STR($00_L2$,-3))
.SET(#U1=STRD(UP/128))
.SET(#U2=STRD((UP-U1*128)*8))
.SET(#U1=STR($   _U1$,-3),#U2=STR($000_U2$,-3))
$NOTE.;;:I A^L^L^O^W^E^D ^R^A^N^G^E ^F^O^R WORD ^M^E^M^O^R^Y ^I^S:
$NOTE.;:I     (M^E^G^A^B^Y^T^E^S,K^I^L^O^B^Y^T^E^S);
$NOTE.;:I LOWER ^B^O^U^N^D ^I^S L1,L2;
$NOTE.;:I UPPER ^B^O^U^N^D ^I^S U1,U2;
$REVERT. DISRANG COMPLETE
$EXIT. DISRANG
$REVERT(ABORT) DISRANG FAILED
*WEOR
.PROC,DISPB*I
,TYPE   =(*A)
,AMOUNT =(*A)
.
.SET(#MB=STRD(AMOUNT/128))
.SET(#KB=STRD((AMOUNT-MB*128)*8))
.SET(#MB=STR($   _MB$,-3),#KB=STR($000_KB$,-3))
.IF, ($TYPE$ .EQ. $PT$) ,DISPB1.
  $NOTE.;:I              P^A^G^E T^A^B^L^E ^M^E^M^O^R^Y ^I^S MB,KB
.ELSE(DISPB1)
.IF, ($TYPE$ .EQ. $NOS$) ,DISPB1.
  $NOTE.;:I                     NOS ^M^E^M^O^R^Y ^I^S MB,KB
.ELSE(DISPB1)
.IF, ($TYPE$ .EQ. $VE$) ,DISPB1.
  $NOTE.;:I                  NOS/VE ^M^E^M^O^R^Y ^I^S MB,KB
.ELSE(DISPB1)
.IF, ($TYPE$ .EQ. $MF$) ,DISPB1.
  $NOTE.;:ITOTAL P^H^Y^S^I^C^A^L M^A^I^N^F^R^A^M^E ^M^E^M^O^R^Y ^I^S MB,KB
.ENDIF(DISPB1)
$REVERT.
*WEOR
.PROC,DISRNGW*I
,WORD    =(*A)
,LOW     =(*S6/D)
,UP      =(*S6/D)
,VEMEM   =(*N=#FILE)
.
.SET(N1=STRB(LOW*2))
.SET(N2=STRB(UP*2))
$NOTE.;;:I A^L^L^O^W^E^D ^R^A^N^G^E ^F^O^R WORD ^M^E^M^O^R^Y ^I^S:
$NOTE.;:I     (O^C^T^A^L/1000B ^W^O^R^D^S);
$NOTE.;:I          N1 - N2;
.IF, ($WORD$ .EQ. $IOB$) .$NOTE.;:I (E^N^T^E^R 0 ^F^O^R ^N^O IOB).
$REVERT. DISRNGW COMPLETE
$EXIT. DISRNGW
$REVERT(ABORT) DISRNGW FAILED
*WEOR
.PROC,DISPW*I
,TYPE   =(*A)
,AMOUNT =(*A)
.
.SET,#AMOUNT=STRB(AMOUNT*2).
.SET,#AMOUNT=STR($      AMOUNT$,-6).
.IF, ($TYPE$ .EQ. $JOBS$) ,DISPW1.
  $NOTE.;:I     SYSTEM & E^X^E^C^U^T^I^N^G J^O^B ^M^E^M^O^R^Y ^I^S AMOUNT
.ELSE(DISPW1)
.IF, ($TYPE$ .EQ. $UEM$) ,DISPW1.
  $NOTE.;:I     U^N^I^F^I^E^D E^X^T^E^N^D^E^D M^E^M^O^R^Y (UEM) ^I^S AMOUNT
.ELSE(DISPW1)
.IF, ($TYPE$ .EQ. $UEMT$) ,DISPW1.
  $NOTE.;:I     TOTAL U^N^I^F^I^E^D E^X^T^E^N^D^E^D M^E^M^O^R^Y ^I^S AMOUNT
.ELSE(DISPW1)
.IF, ($TYPE$ .EQ. $ASR$) ,DISPW1.
  $NOTE.;:I   A^L^T^E^R^N^A^T^E S^Y^S^T^E^M (ASR) ^A^N^D
  $NOTE.;:I   S^E^C^O^N^D^A^R^Y R^O^L^L^O^U^T (SRST) ^M^E^M^O^R^Y ^I^S AMOUNT
.ELSE(DISPW1)
.IF, ($TYPE$ .EQ. $IOB$) ,DISPW1.
  $NOTE.;:I   895 I^N^P^U^T ^A^N^D O^U^T^P^U^T B^U^F^F^E^R^S (IOB) AMOUNT
.ELSE(DISPW1)
.IF, ($TYPE$ .EQ. $UEC$) ,DISPW1.
  $NOTE.;:IU^S^E^R A^C^C^E^S^S^I^B^L^E E^X^T^E^N^D^E^D M^E^M^O^R^Y (UEC) AMOUNT
.ELSE(DISPW1)
.IF, ($TYPE$ .EQ. $NOS$) ,DISPW1.
  $NOTE.;:I                  TOTAL NOS ^M^E^M^O^R^Y ^I^S AMOUNT
.ENDIF(DISPW1)
$REVERT.