*DECK NICNTEA 
USETEXT NIPDEF
USETEXT AHEADER 
USETEXT LLCB
USETEXT NHEADER 
USETEXT PARAMS
USETEXT SUPMSG
 
PRGM NICNTEA;                # SEND ICN/TE/A RC=1-8 TO CCP             #
STARTIMS; 
 #
*1DC  NICNTEA 
* 
*     1. PROC NAME           AUTHOR              DATE 
*        NICNTEA             C. BITTNER          81/07/24 
* 
*     2. FUNCTIONAL DESCRIPTION 
*        SEND ABNORMAL RESPONSE TO TERMINAL CONNECTION REQUEST
*        (ICN/TE/A  RC=1-8) 
* 
*     3. METHOD USED
*        ALLOCATE A BUFFER FOR THE MESSAGE
*        SET UP APPLICATION BLOCK HEADER
*        SET UP TEXT FOR ICN/TE/A MESSAGE 
*        LINK MESSAGE ON PIP OUTBOUND CHAIN 
* 
*     4. ENTRY PARAMETERS 
*        PARAMS1 - REASON CODE (RC=1-8) 
*        PARAMS2 - NETWORK CONNECTION NUMBER
*        PARAMS3 - LLCB ADDRESS 
* 
*     5. EXIT PARAMETERS
*        NONE 
* 
*     6. COMDECKS CALLED AND SYMPL TEXTS USED 
*        NIPDEF              AHEADER
*        LLCB                OSSIZE 
*        PARAMS              SUPMSG 
* 
*     7. ROUTINES CALLED
*        MGETS - ALLOCATE EMPTY BUFFER
*        NFOB - LINK BUFFER ON PIP OUTBOUND CHAIN 
*        XTRACE - TRACE PROCEDURE CALL
* 
*     8. DAYFILE MESSAGES AND OTHER IMPORTANT INFORMATION 
*        THIS PROGRAM IS A SECONDARY OVERLAY LOADED BY
*        SUBROUTINE OVLCALL.
*        W A R N I N G - THIS PROGRAM CANNOT EXCEED THE SECONDARY 
*CALL OSSIZE
* 
 #
STOPIMS;
 
# 
      EXTERNAL VARIABLES
# 
 XREF 
   BEGIN
   PROC MGETS;               # ALLOCATE EMPTY BUFFER                   #
   PROC NFOB;                # LINK BUFFER TO PIP OUTBOUND CHAIN       #
   PROC XTRACE;              # TRACE PROCEDURE CALL                    #
   LABEL RJMAIN;             # RETURN ADDRESS IN OVLCALL               #
   END
 
# 
      INTERNAL VARIABLES
# 
      ITEM BUFADDR;          # SM BUFFER                               #
 
 
#**********************************************************************#
 
      BEGIN 
 
      CONTROL IFEQ DEBUG,1; 
        XTRACE("NICNT") ; 
      CONTROL FI; 
 
# GET BUFFER TO HOLD ICN/TE/A                                          #
      MGETS(LICNTER + BLKHSIZE + ABHSIZE,BUFADDR,TRUE); 
 
# SET UP APPLICATION BLOCK HEADER                                      #
      P<AHEADER> = BUFADDR + BLKHSIZE;  # ADDR TO HOLD ABH             #
      ABHABT[0] = APPCMD;    # BLOCK TYPE                              #
      ABHACT[0] = CT8ASCII;  # CHARACTER TYPE                          #
      ABHTLC[0] = LICNTEA;   # TEXT LENGTH                             #
 
# SET UP ICN/TE/A MESSAGE    #
      P<SUPMSG> = BUFADDR + BLKHSIZE + ABHSIZE;  # FWA OF TEXT         #
      P<SMNIP> = P<SUPMSG>; 
      PFCSFC[0] = ICNTEA;  # SET FUNCTION CODE                         #
      ICNCN[0] = PARAMS2;    # NETWORK CONNECTION NUMBER               #
      ICNRTE[0] = PARAMS1;   # REASON CODE                             #
      P<LLCB> = PARAMS3;
 
# LINK MESSAGE  TO PIP OUTBOUND CHAIN                                  #
      NFOB(BUFADDR,P<LLCB>);
      GOTO RJMAIN;           # RETURN TO CALLING PROGRAM               #
      END 
TERM