*DECK NVFASWN 
USETEXT TEXTNVF 
USETEXT TXSMNVF 
PROC NVFASWN( ACNN ); 
# TITLE NVFASWN - PROCESS CR/SWH/N SM                                  #
      BEGIN  # NVFASWN #
# 
**    NVFASWN - PROCESS CR/SWH/N SMS FOR A-A. 
* 
*     P. A. MURRAY      84/05/09
* 
*     THE PURPOSE OF THIS PROCEDURE IS TO PROCESS THE CR/SWH/N SMS. 
*     THE NVF CONNECTION NUMBER IN THE PAAC ENTRY MUST BE ZEROED OUT
*     IN CASE THE APPL SHOULD FAIL BEFORE NVF RECEIVES THE CR/ACC.  THIS
*     IS NEEDED TO PREVENT NVF FROM ISSUING A CR/TRM FOR THE PAAC, SINCE
*     THE ACN WILL HAVE BEEN RELEASED.
* 
*     PROC NVFASWN ( ACNN ) 
* 
*     ENTRY:  
*       ACNN = APPLICATION CONNECTION NUMBER FROM THE CR/SWH/N. 
* 
*     EXIT: 
*       PA$NACN IS SET TO ZERO IF THE PAAC ENTRY WAS FOUND. 
# 
 
# 
****  PROC NVFASWN XREF LIST
# 
 
      XREF
        BEGIN 
        PROC ABORT;                      # ABORT NVF                   #
        PROC MESSAGE;                    # ISSUE MESSAGE TO DAYFILE    #
        END 
 
# 
****
# 
 
      ITEM ACNN         I;               # APPL CONNECTION NUMBER      #
      ITEM NENTRY       I;               # NUMBER OF PAAC ENTRIES      #
      ITEM PAC          I;               # PAAC ENTRY INDEX            #
 
 
 
# 
*     **** PROC NVFASWN ENTRY START ****
# 
 
# 
*     LOCATE THE PAAC ENTRY WITH THE SAME ACN AS IN THE CR/SWH/N SM.
# 
      NENTRY = PACLNGTH / PAACSIZ$; 
      FOR PAC = 0 STEP 1 WHILE
        ((PAC LS NENTRY) AND
         (PA$NACN[PAC] NQ ACNN))
      DO
        BEGIN 
        END 
 
# 
*     IF PAAC ENTRY NOT FOUND, MERELY RETURN WITH NO ACTION TAKEN.  AT
*     THIS POINT IT IS ASSUMED THAT THE REQUESTING APPLICATION HAS
*     FAILED AND AS A RESULT ALL IS TAKEN CARE OF ALREADY.
# 
      IF PAC EQ NENTRY
      THEN
        BEGIN 
        RETURN;              # **** RETURN ****                        #
        END 
      ELSE
# 
*     IF PAAC ENTRY FOUND, ZERO OUT THE NVF CONNECTION NUMBER.  THIS
*     PREVENTS NVF FROM ISSUING A CR/TRM FOR THIS PAAC IN CASE THE APPL 
*     SHOULD FAIL BEFORE NVF RECEIVES THE CR/ACC.  THE CR/TRM SHOULD NOT
*     BE ISSUED BECAUSE THE ACN ENTRY WILL ALREADY BE DELETED.
# 
        BEGIN 
        PA$NACN[PAC] = 0; 
        END 
 
      END # NVFASWN # 
      TERM