*DECK SSSPSI
USETEXT TEXTSS
      PROC SSSPSI;
# TITLE - PREPARE STATISTICS INFORMATION.                              #
 
      BEGIN # SSSPSI #
# 
**    SSSPSI - PREPARE STATISTICS INFORMATION.
* 
*     D.K. ENDO    82/09/17 
* 
*     *SSSPSI* FORMATS THE STATISTICS INFORMATION AND WRITES IT TO THE
*     NAM STATISTICS FILE (ZZZZZSN).
* 
*     SSSPSI
* 
*     ENTRY        1. VALUES IN COMMON BLOCK *STATBUF*
* 
*     EXIT         1. FORMATTED STATISTICS TO *ZZZZZSN* FILE. 
* 
# 
# 
****  PROC SSSPSI - XREF LIST BEGINS. 
# 
      XREF
        BEGIN 
        PROC NETLGS;         # SEND TEXT TO STATISTICS FILE(ZZZZZSN).  #
        FUNC XCDD C(10);     # CONVERT INTEGER TO DECIMAL DISPLAY CODE #
        END 
# 
****
# 
 
      DEF ZBP(ZNUM) # ZNUM(0) #;       # USED TO ADD ZERO BYTE TO TEXT #
 
 
      ITEM I;                # LOOP INDUCTION VARIABLE                 #
 
 
# 
      THIS ARRAY DEFINES THE TEXT FORMAT OF THE SERVICES AND SCHEDULING 
      STATISTICS. 
# 
      ARRAY STL [01:NSVT$] S(5);
        BEGIN 
        ITEM STL$MSG    C(00,00,30) = ["              SSTAQE",
                                       "              SSTETS",
                                       "              RAS(SSTATS)", 
                                       "              RAS(SSTDFL)", 
                                       "              RAS(SSTSDA)", 
                                       "              SSTRCM",
                                       "              SSTRQE",
                                       "              SSTRTS",
                                       "              SSTSDA",
                                       "              SSTWNR",
                                      ];
        ITEM STL$NUM    C(03,00,10);
        ITEM STL$ZBYT   I(04,00,60) = [ZBP(NSVT$)]; 
        END 
#                                                                      #
#                            SSSPSI CODE BEGINS HERE                   #
#                                                                      #
# 
*     FOR EACH COUNTER CONVERT THE VALUE TO DISPLAY CODE AND PUT IT INTO
*     THE TEXT. 
# 
 
      STL$NUM[SVL"AQE"] = XCDD(SVT$VAL[SVL"AQE"]);
 
      STL$NUM[SVL"ETS"] = XCDD(SVT$VAL[SVL"ETS"]);
 
      STL$NUM[SVL"RAS1"] = XCDD(SVT$VAL[SVL"RAS1"]);
 
      STL$NUM[SVL"RAS2"] = XCDD(SVT$VAL[SVL"RAS2"]);
 
      STL$NUM[SVL"RAS3"] = XCDD(SVT$VAL[SVL"RAS3"]);
 
      STL$NUM[SVL"RCM"] = XCDD(SVT$VAL[SVL"RCM"]);
 
      STL$NUM[SVL"RQE"] = XCDD(SVT$VAL[SVL"RQE"]);
 
      STL$NUM[SVL"RTS"] = XCDD(SVT$VAL[SVL"RTS"]);
 
      STL$NUM[SVL"SDA"] = XCDD(SVT$VAL[SVL"SDA"]);
 
      STL$NUM[SVL"WNR"] = XCDD(SVT$VAL[SVL"WNR"]);
 
# 
*     SEND STATISTICS TEXT OFF TO THE NAM STATISTICS FILE.
# 
 
      NETLGS(STL,NSVT$*5);
 
 
# 
*     CLEAR VALUES TO START STATISTIC GATHERING OVER AGAIN
# 
 
      FOR I=1 STEP 1 UNTIL NSVT$
      DO
        BEGIN 
        SVT$VAL[I] = 0; 
        END 
 
 
      RETURN;                # **** RETURN ****                        #
 
END # SSSPSI #
TERM