*DECK STPHERR 
USETEXT NIPDEF
USETEXT PARAMS
PRGM STPHERR; 
STARTIMS; 
 #
*1DC  STPHERR 
* 
*     1. PROC NAME           AUTHOR              DATE 
*        STPHERR             C. BITTNER          81/07/30 
* 
*     2. FUNCTIONAL DESCRIPTION 
*        ISSUE ERROR MESSAGE FOR AN ILLEGAL STATE TABLE 
*        TRIGGER ON THE HOST SIDE.
* 
*     3. METHOD USED
*        FORMAT THE ERROR MESSAGE 
*        CONVERT THE INFORMATION TO THE PROPER DISPLAY FORMAT 
*        CALL ROUTINE OMSG TO DAYFILE THE ERROR MESSAGE 
* 
*     4. ENTRY PARAMETERS 
*        PARAMS1 - APPLICATION NUMBER 
*        PARAMS2 - APPLICATION CONNECTION NUMBER
*        PARAMS3 - TRIGGER NUMBER 
*        PARAMS4 - CURRENT STATE
*        PARAMS6 - NAME OF STATE TABLE PROCESSOR
* 
*     5. EXIT PARAMETERS
*        NONE 
* 
*     6. COMDECKS CALLED AND SYMPL TEXTS USED 
*        NIPDEF 
*        PARAMS 
*        OSSIZE 
* 
*     7. ROUTINES CALLED
*        OMSG - ISSUE NAM DAYFILE MESSAGE 
*        XTRACE - RECORD PROCEDURE CALL 
*        XCDD - CONVERT DECIMAL TO DISPLAY
* 
*     8. DAYFILE MESSAGES AND OTHER IMPORTANT INFORMATION 
*        THIS PROGRAM IS A SECONDARY OVERLAY LOADED BY
*        SUBROUTINE OVLCALL.
*        THIS PROGRAM IS CALLED BY HBSTTP AND HCSTTP. 
*        W A R N I N G - THIS PROGRAM CANNOT EXCEED THE SECONDARY 
*CALL OSSIZE
* 
 #
STOPIMS;
 
      ITEM STPROC     C(6);  # NAME OF STATE TABLE PROCESSOR           #
      ITEM AN         U;     # APPLICATION NUMBER                      #
      ITEM CN         U;     # APPLICATION CONNECTION NUMBER           #
      ITEM TRIG       U;     # STATE TABLE TRIGGER NUMBER              #
      ITEM STATE      U;     # STATE TABLE PROCESSOR STATE             #
 
# EXTERNAL VARIABLES         #
 XREF 
   BEGIN
   PROC OMSG;                # ISSUE NAM DAYFILE MESSAGE               #
   PROC XTRACE;              # RECORD PROCEDURE CALL                   #
   FUNC XCDD  C(10);         # CONVERT DECIMAL TO DISPLAY              #
   LABEL RJMAIN;             # RETURN ADDRESS IN OVLCALL               #
   END
 
# INTERNAL VARIABLES         #
      ITEM SCRATCH;          # SCRATCH VARIABLE                        #
 
      ARRAY STPMSGH P(4); 
        BEGIN 
        ITEM ERRMSGH  C(00,00,35) = 
                          ["NIP/       ERR AN=   ,CN=   ,  ,  ."];
        ITEM STPH          C(00,24,06); 
        ITEM ANH           C(01,48,03); 
        ITEM CNH           C(02,30,03); 
        ITEM TRIGGER       C(02,54,02); 
        ITEM STATEH        C(03,12,02); 
        ITEM ZERO          U(03,24,36) = [0]; 
        END 
 
      BEGIN 
 
      CONTROL IFEQ DEBUG,1; 
        XTRACE("STPHE") ; 
      CONTROL FI; 
 
      AN = PARAMS1;          # APPLICATION NUMBER                      #
      CN = PARAMS2;          # APPLICATION CONNECTION NUMBER           #
      TRIG = PARAMS3;        # TRIGGER NUMBER                          #
      STATE = PARAMS4;       # CURRENT STATE                           #
      STPROC = PARAMS6;      # NAME OF STATE TABLE PROCESSOR           #
      STPH = STPROC;         # NAME OF STATE TABLE PROCESSOR           #
      SCRATCH = XCDD(AN);    # CONVERT APPL NUM TO DISPLAY             #
      ANH = C<7,3>SCRATCH;
      SCRATCH = XCDD(CN);    # CONVERT CN TO DISPLAY                   #
      CNH = C<7,3>SCRATCH;
      SCRATCH = XCDD(TRIG);  # CONVERT TRIGGER NUM TO DISPLAY          #
      TRIGGER = C<8,2>SCRATCH;
      SCRATCH = XCDD(STATE); # CONVERT STATE NUM TO DISPLAY            #
      STATEH = C<8,2>SCRATCH; 
      OMSG(STPMSGH,0);         # DAYFILE MESSAGE                       #
      GOTO RJMAIN;           # RETURN TO CALLING PROGRAM               #
      END 
TERM