IDENT  BEGIN 
          ENTRY  BEGIN
          SYSCOM B1
          TITLE  BEGIN - TRANSFER PRIMARY COMMUNICATION BLOCK.
*COMMENT  BEGIN - TRANSFER PRIMARY C.B.
          COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992.
          SPACE  4
*****     BEGIN - TRANSFER PRIMARY COMMUNICATION BLOCK.
*
*         W.E. MARTIN.       79/03/30.
          SPACE  4
*         COMMOM TEXT.
 
 
*CALL     COMCMAC
*CALL     COMKMAC
*CALL     COMSPRD
 BEGIN    SPACE  4,30
***       BEGIN - TRANSFER PRIMARY COMMUNICATION BLOCK.
*
*         *BEGIN* ALLOWS A TASK TO SPECIFY THE FWA OF IT-S
*         COMMUNICATION BLOCK AREA AND REBY FREE THE RESTRICTION ON THE
*         THE IMPLEMENTATION LANGUAGE TO RESERVE THE FIRST WORD ADDRESS
*         OF THE LOAD FOR THE TRANSACTION EXECUTIVE.  DUE TO THE EXTRA
*         OVERHEAD INCURRED WHEN THIS OPERATION IS EXECUTED, BEGIN
*         IS NOT SUGGESTED FOR GENERAL USE EXCEPT IN THOSE CASES
*         WHERE IT MUST BE USED TO ALLOW A PROGRAMMING LANGUAGE TO
*         INTERFACE TO THE TRANSACTION SUB-SYSTEM.  ALSO, THE *BEGIN*
*         FUNCTION MUST BE ISSUED AFTER EACH *CALLRTN* IN ORDER
*         TO OBTAIN THE RESULTS OF THE CALLED TASK.
*
*         CALL FORMAT -
*
*         FORTRAN EXTENDED - CALL BEGIN ( ADDR )
*
*         COBOL - ENTER BEGIN USING ADDR.
*
*         WHERE - ADDR = FIRST WORD ARDDRESS OF AN ARRAY OR DATA ITEM
*                        TO WHICH THE PRIMARY TERMINAL COMMUNICATION
*                        BLOCK IS TO BE DELIVERED.
*
*
*         USES   A - 1, 2, 6.
*                X - 0, 1, 2, 6.
*                B - 1.
*
*         MACROS ARGERR, BEGIN.
 
 
          VFD    42/0LBEGIN,18/BEGIN
 
 BEGIN    SUBR               ENTRY/EXIT
          SB1    1
          ZR     X1,BGN1     IF NO ARGUMENTS - ABORT TASK
          SX1    X1
 
*         ISSUE BEGIN REQUEST.
 
          BEGIN  X1
          EQ     BEGINX      RETURN
 
*         PROCESS ARGUMENT ERROR.
 
 BGN1     SA1    BEGIN       READ CALLING ADDRESS
          MX0    30
          LX1    30
          SA2    X1-1        READ CALLING LINE NUMBER
          BX6    -X0*X2
          SA6    BGNA
          ARGERR A6          EXIT TO EXECUTIVE
 
 BGNA     BSS    1           STORAGE FOR ARGERR PARAMETER
          SPACE  4
          END