Table of Contents

INTOT

Table Of Contents

  • [00011] INTOT. - INTERFACE FOR TOTAL TO TAF TABLES.
  • [00024] INITIALIZATION.
  • [00025] INTOT. - INITIALZE TOTAL/TRANEX INTERFACE.
  • [00080] INTERFACE ROUTINES.
  • [00082] EOQ. - ENTER OUTPUT QUEUE.
  • [00094] FAR. - FILE ATTACH ROUTINE.
  • [00105] GRA. - GET REFERENCE ADDRESS.
  • [00119] RIQ. - RETURN INPUT QUEUE.

Source Code

INTOT.txt 
  1.           IDENT  INTOT 
  2.  
  3.  
  4.           ENTRY  INTOT.
  5.           ENTRY  EOQ.        ENTER OUTPUT QUEUE
  6.           ENTRY  FAR.        FILE ATTACH ROUTINE
  7.           ENTRY  GRA.        GET REFERENCE ADDRESS
  8.           ENTRY  RIQ.        RETURN INPUT QUEUE
  9.  
  10.  
  11.           TITLE  INTOT. - INTERFACE FOR TOTAL TO TAF TABLES.
  12. *COMMENT  INTOT. - TOTAL INTERFACE TO TAF TABLES.
  13.           COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992.
  14.  INTOT.   SPACE  4,10
  15. ***       INTOT. - INTERFACE FOR TOTAL TO TRANEX.
  16. *         L. A. BOELTER 75/01/20.
  17.           SPACE  4
  18. **        INTOT. PROVIDES FOUR ENTRY POINTS THAT ARE USED BY TOTAL
  19. *         TO REFERENCE TABLES IN TRANEX.
  20. *         AN ADDITIONAL ENTRY POINT IS PROVIDED FOR USE BY
  21. *         TRANEX1 TO PASS A LIST OF ADDRESSES IN TRANEX TO
  22. *         BE PLACED IN RETURN JUMP INSTRUCTIONS TO COMPLETE
  23. *         THE TOTAL-TRANEX INTERFACE.
  24.           TITLE  INITIALIZATION.
  25. **        INTOT. - INITIALZE TOTAL/TRANEX INTERFACE.
  26. *
  27. *         ENTRY. (A1) - ADDRESS OF PARAMETER LIST.
  28. *                WORD 1 = ADDRESS OF EOQ IN TRANEX.
  29. *                     2 = ADDRESS OF FAR IN TRANEX.
  30. *                     3 = ADDRESS OF GRA IN TRANEX.
  31. *                     4 = ADDRESS OF RIQ IN TRANEX.
  32. *                (X1) = ADDRESS FOR EOQ.
  33. *
  34. *         EXIT.  (X6) = ADDRESS OF TOTAL ENTRY POINT.
  35. *
  36. *         USES   X - 0, 1, 2, 6.
  37. *                A - 1, 2, 6.
  38.  
  39.  
  40.  INTOT.   PS     0           ENTRY
  41.           MX0    18
  42.           LX0    -12
  43.  
  44. *         MODIFY THE RJ FOR EOQ.
  45.  
  46.           SA2    EOQ1
  47.           LX1    30
  48.           BX6    -X0*X2
  49.           BX6    X1+X6
  50.           SA6    A2
  51.  
  52. *         MODIFY THE RJ FOR FAR.
  53.  
  54.           SA1    A1+1        ADDRESS FOR FAR
  55.           SA2    FAR1
  56.           LX1    30
  57.           BX6    -X0*X2
  58.           BX6    X1+X6
  59.           SA6    A2
  60.  
  61. *         MODIFY THE RJ FOR GRA.
  62.  
  63.           SA1    A1+1        ADDRESS FOR GRA
  64.           SA2    GRA1
  65.           LX1    30
  66.           BX6    -X0*X2
  67.           BX6    X1+X6
  68.           SA6    A2
  69.  
  70. *         MODIFY THE RJ FOR RIQ.
  71.  
  72.           SA1    A1+1        ADDRESS FOR RIQ
  73.           SA2    RIQ1
  74.           LX1    30
  75.           BX6    -X0*X2
  76.           BX6    X1+X6
  77.           SA6    A2
  78.           SX6    =XTOTAL     TOTAL ENTRY POINT FOR TRANEX
  79.           EQ     INTOT.      RETURN TO TRANEX1
  80.           TITLE  INTERFACE ROUTINES.
  81.  EOQ.     SPACE  4,10
  82. **        EOQ. - ENTER OUTPUT QUEUE.
  83. *
  84. *         PASS CALL FROM TOTAL TO EOQ IN TRANEX.
  85. *
  86. *         CALLS  =XEOQ.
  87.  
  88.  
  89.  EOQ.     PS     0           ENTRY/EXIT
  90.  EOQ1     RJ     EOQ1        CALL EOQ
  91. *         RJ     =XEOQ       (CALL EOQ)
  92.           EQ     EOQ.        RETURN
  93.  FAR.     SPACE  4,10
  94. **        FAR. - FILE ATTACH ROUTINE.
  95. *         PASS CALL FROM TOTAL TO FAR IN TRANEX.
  96. *
  97. *         CALLS  =XFAR.
  98.  
  99.  
  100.  FAR.     PS     0           ENTRY/EXIT
  101.  FAR1     RJ     FAR1        CALL FAR
  102. *         RJ     =XFAR       (CALL FAR)
  103.           EQ     FAR.        RETURN
  104.  GRA.     SPACE  4,10
  105. **        GRA. - GET REFERENCE ADDRESS.
  106. *         PASS CALL FROM TOTAL TO GRA IN TRANEX.
  107. *
  108. *         USES   X - 6.
  109. *
  110. *         CALLS  =XGRA.
  111.  
  112.  
  113.  GRA.     PS     0           ENTRY/EXIT
  114.           SX6    B1+         SET FLAG - CALLED BY *TOTAL*
  115.  GRA1     RJ     GRA1        CALL GRA
  116. *         RJ     =XGRA       (CALL GRA)
  117.           EQ     GRA.        RETURN
  118.  RIQ.     SPACE  4,10
  119. **        RIQ. - RETURN INPUT QUEUE.
  120. *         PASS CALL FROM TOTAL TO RIQ IN TRANEX.
  121. *
  122. *         CALLS  =XRIQ.
  123.  
  124.  
  125.  RIQ.     PS     0           ENTRY/EXIT
  126.  RIQ1     RJ     RIQ1        CALL RIQ
  127. *         RJ     =XRIQ       (CALL RIQ)
  128.           EQ     RIQ.        RETURN
  129.  
  130.  
  131.           END    INTOT.