Retro1.org codex

*DECK ISCP
          IDENT  ISCP 
          EXT    OMSG 
OPL       XTEXT  COMCMAC
 OPL      XTEXT  COMSPRD
 OPL      XTEXT  COMSSSD
          ENTRY  ISCP 
          SST 
          SYSCOM B1 
*IF DEF,IMS 
*#
*1DC  ISCP
* 
*     1. PROC NAME           AUTHOR              DATE 
*        ISCP                Y. HSIEH            77006/01 
* 
*     2. FUNCTIONAL DESCRIPTION.
*          VERIFY NIP WAS BROUGHT UP AS N.NAM AND INITIALIZE NIP AS 
*          A SYSTEM-CONTROL-POINT 
*        AND TO ADJUST THE CHARACTER CONVERSION TABLE FOR 64 CHAR. SET. 
* 
*     3. METHOD USED. 
*          USE GETSSID MACRO TO GET NIP-S QUEUE PRIORITY
*          IF NOT *NMSI*, NIP WAS INITIALIZED INCRRECTEDLY, SO ABORT. 
*          IF *NMSI*, USE CALLS MACRO TO INITIALIZE SYSTEM-CONTROL- 
*            POINT STATUS 
*          READ MACHINE CHARACTERISTIC WORD TO SEE WHETHER WE ARE 
*          RUNNING WITH 63 OR 64 CHAR. SET. 
*          IF 64 CHAR. SET, CHANGE THE CORRESPONDING DISPLAY CODE 
*          FOR ASCII CODE 3A TO 00B.
* 
*     4. ENTRY PARAMETERS.
*          NONE 
* 
*     5. EXIT PARAMETERS.  NONE 
* 
*     6. COMMON DECKS CALLED
*        SYSCOMD             SYSTEM COMMUNICATION DEFINITIONS 
* 
*     7. ROUTINES CALLED. 
*          CALLSS            REQUEST SYS-CTL-PT STATUS
          GETSSID            GET SUBSYSTEM ID MACRO 
*          OMSG              ISSUE DAYFILE MESSAGE
* 
*     8. DAYFILE MESSAGES AND OTHER IMPORTANT INFORMATION.
* 
*        *NAM INITIATED INCORRECTLY - TRY N.NAM.* 
* 
*        W A R N I N G - THIS ROUTINE IS LOAD WITH INIP, ISUPCB,
*                        IBUFFS, AND ITRACE.  THE SUM OF THEIR
*                        SIZES CANNOT EXCEED THE SIZE OF THE
*CALL OSIZE 
* 
* 
*#
*ENDIF
 
 
*              THIS COMMON BLOCK IS THE CONVERSION TABLE USED BY BCONV
*              TO CONVERT 8-BIT ASCII INBOUND DATA TO 6-BIT DISPLAY CODE
 
          USE    /COMVERT/
          BSS    7
SET63A    BSS    5
SET63B    BSS    4
          USE * 
 
*CALL SYSCOMD 
 
          IPARAMS 
 A        IFC    EQ,*"OS.NAME"*KRONOS*
*IF,-DEF,MSS
 SSWD     VFD    42/3LNAM,18/NMSI 
*ENDIF
*IF,DEF,MSS      FOR CDC INTERNAL USE ONLY
 SSWD     VFD    42/3LMSS,18/MFSI 
*ENDIF           FOR CDC INTERNAL USE ONLY
 A        ELSE
 SSID     VFD    42/5LCDCS2,18/1
 A        ENDIF 
* 
 STATUS   BSSZ   1
 SSID     BSSZ   1           SUBSYSTEM ID WORD
MSG       DIS    ,*NAM INITIATED INCORRECTLY - TRY N.NAM.*
MSGADDR   VFD    60/MSG 
          BSSZ     1
*                            RA.SSC 
          SPACE  5
 ISCP     SUBR   =           ENTRY/EXIT 
* 
* 
*         CHECK IF NAM BROUGHT UP CORRECTLY BY CHECKING ITS 
*         JOB PRIORITY
* 
          GETSSID SSID       GET SUBSYSTEM ID 
          SA1    SSID        X1 = SUBSYSTEM ID
          SB2    X1 
*IF,-DEF,MSS
          SB3    NMSI        B3 = NAM SUBSYSTEM ID
*ENDIF
*IF,DEF,MSS      FOR CDC INTERNAL USE ONLY
          SB3    MFSI        B3 = MSS SUBSYSTEM ID
*ENDIF           FOR CDC INTERNAL USE ONLY
          EQ   B2,B3,INITOK  NIP BROUGHT UP CORRECTLY 
          SA1    MSGADDR     PARAMETER LIST ADDRESS FOR OMSG
          RJ   OMSG          ISSUE DAYFILE MESSAGE
          ABORT              ABORT NIP
 
INITOK    BSS    0
          SA1    SSWD 
          BX7    X1 
          SA7    RA.SSID     STORE NAME AND ORDINAL IN LOW RA 
* 
*         REQUEST SYSTEM CONTROL POINT STATUS 
* 
          CALLSS SS.SYS,STATUS,R
* 
*         SIGN BIT OF LOW CORE WORD 67B(CSMR) IN FL = 0 IF 63 CHAR SET
*                                                   = 1 IF 64 CHAR SET
*              IF FOR 64 CHARACTER SET
*              CHANGE THE CORRESPONDING DISPLAY CODE FOR 3A TO 00B
* 
          SA2    CSMR              BIT 59 = 0 IF 63 CHARACTER SET 
          PL     X2,ISCPX    RETURN IF 63 CHAR SET
 
          MX0    6
          SA1    SET63B            THIS WORD INIT. FOR 63 CHAR SET
          BX6    -X0*X1            ASCII CODE 3A EQUIVALENT TO 00B
          SA2    SET63A            THIS WORD INIT FOR 63 CHAR SET 
          LX0    48 
          SA6    A1 
          BX6    -X0*X2            ASCII CODE 3A EQUIVALENT TO 00B
          SA6    A2                IN 64 CHAR SET 
          EQ     ISCPX       RETURN 
          END