Retro1.org codex

*DECK INIPD 
USETEXT NIPDEF
USETEXT BPIPBUF 
USETEXT DBGBUF
USETEXT MSGIDX
PRGM INIPD; 
STARTIMS; 
 #
*1DC  INIPD 
* 
*     1. PROC NAME           AUTHOR              DATE 
*        INIPD               C. BITTNER          83/04/01 
* 
*     2. FUNCTIONAL DESCRIPTION 
*        CHECK IF NRF1/NRF2 ARE LOCAL FILES.
* 
*     3. METHOD USED
*        ZERO FILL FILE NAME.  INITIALIZE THE FET.
*        CHECK IF THE FILE IS LOCAL BY CALLING FSTATUS. 
*        CALL OPITRCE TO INITIALIZE NIP DEBUG LOG FILE. 
* 
*     4. ENTRY PARAMETERS 
*        NONE 
* 
*     5. EXIT PARAMETERS
*        NONE 
* 
*     6. COMDECKS CALLED AND SYMPL TEXTS USED 
*        NIPDEF     BPIPBUF     DBGBUF     MSGIDX 
* 
*     7. ROUTINES CALLED
*        FSTATUS - CHECK IF FILE IS LOCAL 
*        ABORT - ABORT NIP
*        NXZFN - ZERO FILL FILE NAME
*        OPITRCE - INITIALIZE NIP DEBUG LOG FILE. 
*        XTRACE - TRACE PROCEDURE CALL
* 
*     8. DAYFILE MESSAGES AND OTHER IMPORTANT INFORMATION 
*        "LFN NOT FOUND"
* 
 #
STOPIMS;
 
# 
      EXTERNAL VARIABLES
# 
 XREF 
  BEGIN 
  PROC FSTATUS;              # CHECK IF FILE IS LOCAL                  #
  PROC ABORT;                # ABORT NIP                               #
  PROC OPITRCE;              # INITIALIZE NIP DEBUG LOG FILE           #
  FUNC NXZFN C(10);          # ZERO FILL NAME                          #
  PROC XTRACE;               # TRACE PROCEDURE CALL                    #
  LABEL RJMAIN;              # RETURN ADDRESS IN OVLCALL               #
  END 
 
# 
      LOCAL VARIABLES 
# 
 
      ITEM I;                # LOOP VARIABLE                           #
      ITEM J;                # LOOP VARIABLE                           #
      ITEM DTIME;            # TIME WORD                               #
      BASED ARRAY FETXX     S(1); 
        BEGIN 
        ITEM FETWORD  U(0,0,60);
        END 
 
 
      BEGIN 
 
      CONTROL IFEQ DEBUG,1; 
        XTRACE("INIPD");
      CONTROL FI; 
 
 
# 
      CHECK IF NRF1,NRF2 FILES ARE LOCAL
# 
 
      CONTROL IFEQ ZZDN,1;
      ZNRF1 = NXZFN(NRF1);  # ZERO FILL FILE NAME                      #
      ZNRF2 = NXZFN(NRF2);  # ZERO FILL FILE NAME                      #
 
      # INITIALIZE FET                                                 #
      P<FETXX> = LOC(FETLFN[0]);
      FOR J = 0 STEP 1 UNTIL FETSZ-1 DO 
        BEGIN 
        FETWORD[0] = 0; 
        END 
 
 
      FETLEN[0] = FETSZ - 5;  # FET LENGTH                             #
      FETCMPT[0] = TRUE;
      FOR I=1 STEP 1 UNTIL 2
      DO
        BEGIN 
        IF I EQ 1 
        THEN
          FETLFN[0] = ZNRF1;
        ELSE
          FETLFN[0] = ZNRF2;
        FSTATUS(BFET);  # CHECK IF FILE IS LOCAL                       #
        IF FETSTATUS[0] EQ 0
        THEN                 # FILE NOT FOUND                          #
          BEGIN 
          D28M2[0] = C<0,4>FETLFN[0]; 
          ABORT(DFMSG28,0);  # ABORT NIP                               #
          END 
        END 
 
# 
      INITIALIZE TRACE FILE 
# 
      OPITRCE(ZNRF1,0); 
 
      CONTROL FI; 
 
 
      GOTO RJMAIN;
      END 
TERM