Retro1.org codex

*DECK ITRACE
          IDENT  ITRACE 
          EXT    XTRACE 
*IF DEF,IMS 
*#
*1DC  ITRACE
* 
*     1. PROC NAME           AUTHOR              DATE 
*        ITRACE              P.C.TAM             78/09/11 
* 
*     2. FUNCTIONAL DESCRIPTION.
*        INITIALIZE TRACE BUFFER BPIPBUF
* 
*     3. METHOD USED. 
*        CREATE HEADER ENTRY FOR NIP TRACE FILE IN CIO BUFFER.
* 
*     4. ENTRY PARAMETER. 
*        (A1)                ADDRESS OF THE ADDRESS OF FET
* 
*     5. EXIT PARAMETER.
*        NONE.
* 
*     6. COMMON DECKS CALLED. 
*        CYBERDEFS INPARU MACDEF BPIPBUF
* 
*     7. ROUTINES CALLED. 
*        CLOCK               GET CLOCK TIME MACRO.
*        DATE                GET DATE MACRO.
*        RTIME               GET REAL TIME MACRO. 
*        XTRACE              TRACE CALLER 
* 
*     8. DAYFILE MESSAGES.
*        NONE.
* 
*        W A R N I N G - THIS ROUTINE IS LOADED TOGETHER WITH 
*                        INIP, ISCP, ISUPCB, AND IBUFFS.  THE SUM OF
*                        THEIR SIZES CANNOT EXCEED THE SIZE OF THE
*CALL OSIZE 
* 
* 
*#
*ENDIF
*CALL MACDEF
*CALL CYBERDEFS 
*CALL INPARU
 
 ITR1     IFEQ   ZZDN,1 
          ENTRY  ITRACE 
 
 ITRACE   SUBR   =           ENTRY/EXIT 
 
          SX6    X1          ADDRESS OF FET 
          SA6    TEMP 
          IFEQ   DEBUG,1,4
          SX1    XITRACE
          RJ     XTRACE 
          SA1    TEMP 
          SA2    X1+2              (X2)=IN POINTER
          SA3    BRAND       CREATE HEADER FOR FILE 
          BX6    X3 
          SA6    X2 
          SX7    X2+1 
          RTIME  X7          DEADSTART ELAPSED TIME 
          SX7    X2+2        THIRD WORD OF 4 WORD HEADER
          CLOCK  X7          CLOCK TIME 
          SX7    X2+3        FOURTH WORD OF 4 WORD HEADER 
          DATE   X7          DATE 
          SX7    X7+1        NEXT FREE WORD IN CIO BUFFER 
          SA1    TEMP        WORD CONTAINING FWA OF FET 
          SA2    X1+2        A2 = IN POINTER WORD IN FET
          SA7    A2          RESET IN POINTER IN FET PASS HEADER ENTRY
          EQ     ITRACEX     RETURN 
 
 BRAND    DATA   L*NIP* 
 XITRACE  DATA   L*ITRAC* 
 TEMP     BSS    1
 ITR1     ENDIF 
 
          END