Retro1.org codex

*DECK LFGNLFH 
USETEXT LFGFET,LFGIOD,LFGDB,LFGPRF
      PROC LFGNLFH; 
      BEGIN                  # WRITE NLF HEADER                        #
*IF DEF,IMS 
# 
**    LFGNLFH - WRITE NLF HEADER. 
* 
*     M. E. VATCHER  81/02/23 
* 
*     LFGNLFH WRITES A 7700 TABLE AT THE BEGINNING OF THE NLF.
* 
*     PROC LFGNLFH
* 
*     ENTRY NONE. 
* 
*     EXIT  NONE. 
* 
*     METHOD
* 
*     FILL IN 7700 TABLE HEADER.  FILL IN DATE, TIME, VERSION, AND
*     LEVEL.  WRITE RECORD TO NLF.
* 
# 
*ENDIF
 
# 
****  PROC LFGNLFH - XREF LIST BEGIN. 
# 
 
      XREF
        BEGIN 
        PROC CLOCK;          # GET TIME OF DAY                         #
        PROC DATE;           # GET DATE                                #
        PROC REWIND;         # REWINDS SPECIFIED FILE                  #
       PROC RECALL;          # RETURNS CONTROL WHEN RECALL BIT IS SET  #
        PROC VERSION; 
        ITEM WFET U;         # FWA OF NLF FET                          #
        PROC WRITER;         # WRITE RECORD                            #
        PROC WRITEW;         # WRITE WORDS TO CIO BUFFER               #
        END 
 
# 
****
# 
 
*CALL NAMLEV
 
      ARRAY VERCALL [0:0] S(1); 
        BEGIN 
        ITEM VC$BC        U(00,00,12) = [ 5 ];
        ITEM VC$ZERO      U(00,12,30) = [ 0 ];
        ITEM VC$ADDR      U(00,42,18);
        END 
 
      ITEM I U; 
      ITEM OPS C(10);        # OPERATING SYSTEM VERSION                #
      ITEM STATIS C(10);
 
      VC$ADDR[0] = LOC(OPS);  # PREPARE FOR VERSION CALL               #
      P<SIOFET> = WFET; 
      FETCRI[0] = 1;         # INITIALIZE CURRENT RANDOM INDEX         #
      FETOUT[0] = FETFST[0]; # PREPARE FOR WRITE                       #
      FETIN[0] = FETFST[0]; 
 
      P<PRF$TABLE> = LOC(DIRB$WORD[0]); 
      PRF$ID[0] = PRF$IDENT;  # SET TABLE IDENTIFIER                   #
      PRF$WC[0] = O"16";  # SIZE OF PREFIX TABLE                       #
      PRF$ZERO1[0] = 0; 
      PRF$LFN[0] = "NLF    "; 
      PRF$ZERO2[0] = 0; 
      DATE(STATIS);          # GET DATE                                #
      PRF$DATE[0] = C<1,8>STATIS;  # FILL IN DATE                      #
      CLOCK(STATIS);         # GET TIME                                #
      PRF$TIME[0] = C<1,8>STATIS;  # FILL IN TIME                      #
      VERSION(VERCALL);      # GET OPERATING SYSTEM VERSION            #
      PRF$OPS[0] = OPS;      # FILL IN OS VERSION                      #
      PRF$PRNAME[0] = "LFG    ";
      PRF$PRVER[0] = C<9,3>NAMVER;
      PRF$PRLEV[0] = NAMLV[0];
      PRF$BLNK1[0] = " "; 
      PRF$BLNK2[0] = " "; 
      PRF$COMMNT[0] = " ";
      REWIND(SIOFET);        # REWIND NLF                              #
      RECALL(SIOFET); 
      WRITEW(SIOFET,DIRB,15); 
      WRITER(SIOFET);        # WRITE HEADER TO FILE AND PUT EOR MARKER #
      END TERM